Создание строк JSON из переменных Groovy в конвейере Jenkins

Ответ 1

JSON - это формат, который использует человекочитаемый текст для передачи объектов данных, состоящих из пар атрибутных значений и типов данных массива. Таким образом, в общем случае json является форматированным текстом.

В groovy объект json - это просто последовательность карт/массивов.

разбор json с использованием JsonSlurperClassic

//use JsonSlurperClassic because it produces HashMap that could be serialized by pipeline
import groovy.json.JsonSlurperClassic

node{
    def json = readFile(file:'message2.json')
    def data = new JsonSlurperClassic().parseText(json)
    echo "color: ${data.attachments[0].color}"
}

синтаксический анализ json с использованием конвейера

node{
    def data = readJSON file:'message2.json'
    echo "color: ${data.attachments[0].color}"
}

построение json из кода и запись в файл

import groovy.json.JsonOutput
node{
    //to create json declare a sequence of maps/arrays in groovy
    //here is the data according to your sample
    def data = [
        attachments:[
            [
                fallback: "New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
                pretext : "New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
                color   : "#D00000",
                fields  :[
                    [
                        title: "Notes",
                        value: "This is much easier than I thought it would be.",
                        short: false
                    ]
                ]
            ]
        ]
    ]
    //two alternatives to write

    //native pipeline step:
    writeJSON(file: 'message1.json', json: data)

    //but if writeJSON not supported by your version:
    //convert maps/arrays to json formatted string
    def json = JsonOutput.toJson(data)
    //if you need pretty print (multiline) json
    json = JsonOutput.prettyPrint(json)

    //put string into the file:
    writeFile(file:'message2.json', text: json)

}

Ответ 2

Нашел этот вопрос, пока я пытался что-то сделать (я полагал) должен быть прост в использовании, но не был обращен другим ответом. Если у вас уже есть JSON, загружаемый как строка внутри переменной, как вы можете преобразовать его в собственный объект? Очевидно, вы могли бы сделать new JsonSlurperClassic().parseText(json) , как предлагает другой ответ, но в Дженкинсе есть собственный способ:

node () {
  def myJson = '{"version":"1.0.0"}';
  def myObject = readJSON text: myJson;
  echo myObject.version;
}

Надеюсь, это поможет кому-то.

Изменить: Как объясняется в комментариях, "native" не совсем точен.

Ответ 3

Это вернет значение "version" из файла jsonFile:

def getVersion(jsonFile){

  def fileContent = readFile "${jsonFile}"
  Map jsonContent = (Map) new JsonSlurper().parseText(fileContent)
  version = jsonContent.get("version")

  return version

}

Ответ 4

Если вы застряли в установке с использованием песочниц и плагина Jenkins Script Security без возможности добавления занесенных в белый список классов/методов, я нашел только один способ:

def slackSendOnRestrictedContext(params) {

    if (params.attachments != null) {
        // Soooo ugly but no other choice with restrictions of Jenkins Script Pipeline Security plugin ^^
        def paramsAsJson = JsonOutput.toJson(params)
        def paramsAsJsonFromReadJson = readJSON text: paramsAsJson
        params.attachments = paramsAsJsonFromReadJson.attachments.toString()
    }

    slackSend (params)
}