Подтвердить что ты не робот

Типы линий Gnuplot

Как рисовать различные типы строк в gnuplot? Мне нужно рисовать разные цвета. Мой script объединяет несколько файлов, и я думаю, поэтому строки не тире. Только два из четырех разбиты. благодаря Фелипе

#!/usr/bin/gnuplot

set grid
set title 'Estado dos arquivos no BTRIM com peers de comportamento condicionado'
set xlabel 'Tempo discreto'
set ylabel 'Quantidade de arquivos'
set style line 1 lc rgb '#0060ad' lt 1 lw 2 pi -1 ps 1.0
set style line 2 lc rgb '#dd181f' lt 9 lw 2 pi -1 ps 1.0
set style line 3 lc rgb '#29c524' lt 6 lw 2 pi -1 ps 1.0
set style line 4 lc rgb '#7D72F9' lt 7 lw 2 pi -1 ps 1.0
set style line 5 lc rgb '#000000' lt 8 lw 2 pi -1 ps 1.0

set termoption dashed
#set pointintervalbox 0
#set boxwidth 0.1
#set style fill solid

plot '<paste ../00/StatisticNormal.txt ../01/StatisticNormal.txt ../02/StatisticNormal.txt  ../03/StatisticNormal.txt ../04/StatisticNormal.txt ../05/StatisticNormal.txt ../06/StatisticNormal.txt ../07/StatisticNormal.txt ../08/StatisticNormal.txt ../09/StatisticNormal.txt' smooth unique with line ls 1 title 'Normais', \
'<paste ../00/StatisticVogue.txt ../01/StatisticVogue.txt ../02/StatisticVogue.txt ../03/StatisticVogue.txt ../04/StatisticVogue.txt ../05/StatisticVogue.txt ../06/StatisticVogue.txt ../07/StatisticVogue.txt ../08/StatisticVogue.txt ../09/StatisticVogue.txt' smooth unique with line ls 2 title 'na Moda', \
'<paste ../00/StatisticPopular.txt ../01/StatisticPopular.txt ../02/StatisticPopular.txt ../03/StatisticPopular.txt ../04/StatisticPopular.txt ../05/StatisticPopular.txt ../06/StatisticPopular.txt ../07/StatisticPopular.txt ../08/StatisticPopular.txt ../09/StatisticPopular.txt' smooth unique with line ls 3 title 'Populares', \
'<paste ../00/StatisticRarity.txt ../01/StatisticRarity.txt ../02/StatisticRarity.txt ../03/StatisticRarity.txt ../04/StatisticRarity.txt ../05/StatisticRarity.txt ../06/StatisticRarity.txt ../07/StatisticRarity.txt ../08/StatisticRarity.txt ../09/StatisticRarity.txt' smooth unique with line ls 4 title 'Raros'

pause -1
4b9b3361

ОТВЕТЫ

Ответ 1

До версии 4.6

Тип тире linestyle задается параметром linetype, который также выбирает цвет линии, если вы явно не установите другой с linecolor.

Однако поддержка пунктирных линий зависит от выбранного терминала:

  • Некоторые терминалы не поддерживают пунктирные линии, например png (использует libgd)
  • Другие терминалы, например pngcairo, поддерживают пунктирные линии, но по умолчанию отключены. Чтобы включить его, используйте set termoption dashed или set terminal pngcairo dashed ....
  • Точные штриховые рисунки различаются между терминалами. Чтобы увидеть определенный linetype, используйте команду test:

Запуск

set terminal pngcairo dashed
set output 'test.png'
test
set output

дает:

enter image description here

тогда как терминал postscript показывает разные шаблоны тире:

set terminal postscript eps color colortext
set output 'test.eps'
test
set output

enter image description here

Версия 5.0

Начиная с версии 5.0, вводятся следующие изменения, относящиеся к типам линий, тире и цветам линий:

  • Был введен новый параметр dashtype:

    Чтобы получить предопределенные тире, используйте, например,

    plot x dashtype 2

    Вы также можете указать пользовательские шаблоны тире, например

    plot x dashtype (3,5,10,5),\
     2*x dashtype '.-_'

  • Параметры терминала dashed и solid игнорируются. По умолчанию все строки являются сплошными. Чтобы изменить их на пунктирные линии, используйте, например,

    set for [i=1:8] linetype i dashtype i

  • Изменен набор цветов линий по умолчанию. Вы можете выбрать между тремя различными наборами цветов с помощью set colorsequence default|podo|classic:

enter image description here