Мне нужно отлаживать в pl/sql, чтобы указать время процедур, я хочу использовать:
SELECT systimestamp FROM dual INTO time_db;
DBMS_OUTPUT.PUT_LINE('time before procedure ' || time_db);
но я не понимаю, к чему идет вывод, и как я могу перенаправить его в файл журнала, который будет содержать все данные, которые я хочу собрать?
DBMS_OUTPUT - не лучший инструмент для отладки, поскольку большинство сред не используют его изначально. Если вы хотите захватить вывод DBMS_OUTPUT, однако, вы просто будете использовать процедуру DBMS_OUTPUT.get_line.
Вот небольшой пример:
SQL> create directory tmp as '/tmp/';
Directory created
SQL> CREATE OR REPLACE PROCEDURE write_log AS
2 l_line VARCHAR2(255);
3 l_done NUMBER;
4 l_file utl_file.file_type;
5 BEGIN
6 l_file := utl_file.fopen('TMP', 'foo.log', 'A');
7 LOOP
8 EXIT WHEN l_done = 1;
9 dbms_output.get_line(l_line, l_done);
10 utl_file.put_line(l_file, l_line);
11 END LOOP;
12 utl_file.fflush(l_file);
13 utl_file.fclose(l_file);
14 END write_log;
15 /
Procedure created
SQL> BEGIN
2 dbms_output.enable(100000);
3 -- write something to DBMS_OUTPUT
4 dbms_output.put_line('this is a test');
5 -- write the content of the buffer to a file
6 write_log;
7 END;
8 /
PL/SQL procedure successfully completed
SQL> host cat /tmp/foo.log
this is a test
Как альтернатива написанию файла, как насчет записи в таблицу? Вместо вызова DBMS_OUTPUT.PUT_LINE вы можете вызвать свою собственную процедуру DEBUG.OUTPUT примерно так:
procedure output (p_text varchar2) is
pragma autonomous_transaction;
begin
if g_debugging then
insert into debug_messages (username, datetime, text)
values (user, sysdate, p_text);
commit;
end if;
end;
Использование автономной транзакции позволяет сохранять отладочные сообщения, созданные из транзакций, которые откатываются (например, после возникновения исключения), как это было бы, если вы использовали файл.
Логическая переменная g_debugging представляет собой переменную пакета, которая по умолчанию имеет значение false и устанавливается значение true, когда требуется отладочный вывод.
Конечно, вам нужно управлять этой таблицей, чтобы она не росла вечно! Один из способов - это работа, выполняемая каждую ночь/неделю и удаление любых отладочных сообщений, которые являются "старыми".
использование set serveroutput on;
например:
set serveroutput on;
DECLARE
x NUMBER;
BEGIN
x := 72600;
dbms_output.put_line('The variable X = '); dbms_output.put_line(x);
END;
Если вы просто тестируете PL/SQL в SQL Plus, вы можете направить его в файл следующим образом:
spool output.txt
set serveroutput on
begin
SELECT systimestamp FROM dual INTO time_db;
DBMS_OUTPUT.PUT_LINE('time before procedure ' || time_db);
end;
/
spool off
IDE, такие как Toad и SQL Developer, могут захватывать вывод другими способами, но я не знаком с тем, как.
В дополнение к ответу Тони, если вы хотите узнать, где ваша программа PL/SQL тратит время, также стоит проверить this части документации Oracle PL/SQL.
Использование UTL_FILE вместо DBMS_OUTPUT перенаправляет вывод в файл:
В качестве примечания, помните, что весь этот вывод создается на стороне сервера.
Используя DBMS_OUTPUT, текст генерируется на сервере, пока он выполняет ваш запрос и сохраняется в буфере. Затем он перенаправляется в клиентское приложение, когда сервер завершает поиск данных запроса. То есть вы получаете эту информацию только после завершения запроса.
С UTL_FILE вся зарегистрированная информация будет сохранена в файле на сервере. Когда выполнение закончится, вам нужно будет перейти к этому файлу, чтобы получить информацию.
Надеюсь, что это поможет.
Возможность записи файла непосредственно на сервер БД, на котором размещена ваша база данных, и которая будет изменяться вместе с выполнением вашей программы PL/SQL.
В этом случае используется каталог Oracle TMP_DIR; вы должны объявить его и создать следующую процедуру:
CREATE OR REPLACE PROCEDURE write_log(p_log varchar2)
-- file mode; thisrequires
--- CREATE OR REPLACE DIRECTORY TMP_DIR as '/directory/where/oracle/can/write/on/DB_server/';
AS
l_file utl_file.file_type;
BEGIN
l_file := utl_file.fopen('TMP_DIR', 'my_output.log', 'A');
utl_file.put_line(l_file, p_log);
utl_file.fflush(l_file);
utl_file.fclose(l_file);
END write_log;
/
Вот как это использовать:
1) Запустите это с вашего клиента SQL * PLUS:
BEGIN
write_log('this is a test');
for i in 1..100 loop
DBMS_LOCK.sleep(1);
write_log('iter=' || i);
end loop;
write_log('test complete');
END;
/
2) на сервере базы данных, откройте оболочку и
tail -f -n500 /directory/where/oracle/can/write/on/DB_server/my_output.log
Старый поток, но есть и другая альтернатива.
Так как 9i вы можете использовать функцию конвейерной таблицы.
Сначала создайте тип как таблицу varchar:
CREATE TYPE t_string_max IS TABLE OF VARCHAR2(32767);
Во-вторых, оберните свой код в объявлении функции конвейерной функции:
CREATE FUNCTION fn_foo (bar VARCHAR2) -- your params
RETURN t_string_max PIPELINED IS
-- your vars
BEGIN
-- your code
END;
/
Заменить все DBMS_OUTPUT.PUT_LINE для PIPE ROW.
Наконец, назовите его следующим образом:
SELECT * FROM TABLE(fn_foo('param'));
Надеюсь, что это поможет.
Попробуйте следующее:
SELECT systimestamp INTO time_db FROM dual ;
DBMS_OUTPUT.PUT_LINE('time before procedure ' || time_db);