Для небольшой дискуссии в сообществе, какие основные макросы Visual Studio вы используете?
Я только начал узнавать о них и хочу услышать, что некоторые из вас не могут жить без.
Для небольшой дискуссии в сообществе, какие основные макросы Visual Studio вы используете?
Я только начал узнавать о них и хочу услышать, что некоторые из вас не могут жить без.
Я использовал много макросов в VS 2002/2003. Одним из примеров может быть создание региона. Мне всегда нравятся мои классы, которые можно разделить на следующие регионы: "Частные члены", "Публичные свойства", "Публичные методы" и "Частные методы". Итак, у меня есть макрос, сопоставленный с ярлыком, который создает эти регионы в любом новом файле класса.
Поддержка рефакторинга в VS 2005/2008 (и возможность добавления общих фрагментов кода), а также использование Addins, таких как DXCore и SlickEdit, позволяют мне работать, не создавая слишком много макросов.
Я добавляю кнопки на панели инструментов для следующих трех макросов. Каждый из них будет отображать выделенный текст в любом файле и google (или MSDN-it, или проверку орфографии). Создайте отличный значок для панели инструментов для дополнительных стилей.
Private Const BROWSER_PATH As String = "C:\Program Files\Mozilla Firefox\firefox.exe"
Sub SearchGoogle()
Dim cmd As String
cmd = String.Format("{0} http://www.google.com/search?hl-en&q={1}", BROWSER_PATH, DTE.ActiveDocument.Selection.Text)
Shell(cmd, AppWinStyle.NormalFocus)
End Sub
Sub SearchMSDN()
Dim cmd As String
cmd = String.Format("{0} http://www.google.com/search?hl-en&q={1}+site%3Amsdn.microsoft.com", BROWSER_PATH, DTE.ActiveDocument.Selection.Text)
Shell(cmd, AppWinStyle.NormalFocus)
End Sub
Sub SpellCheck()
Dim cmd As String
cmd = String.Format("{0} http://www.spellcheck.net/cgi-bin/spell.exe?action=CHECKWORD&string={1}", BROWSER_PATH, DTE.ActiveDocument.Selection.Text)
Shell(cmd, AppWinStyle.NormalFocus)
End Sub
Показывать продолжительность сборки в окне вывода
Поместите этот код в свой модуль EnvironmentEvents. Это будет записывать продолжительность непосредственно в окно сборки для любых действий над решением (строить, перестраивать, очищать, развертывать).
Вы можете изменить функцию IsBuild, чтобы указать действия, которые вы хотите просмотреть.
Dim buildStart As Date
Private Function IsBuild(ByVal scope As EnvDTE.vsBuildScope, ByVal action As EnvDTE.vsBuildAction) As Boolean
Return scope = vsBuildScope.vsBuildScopeSolution
End Function
Private Sub BuildEvents_OnBuildBegin(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildBegin
If (IsBuild(Scope, Action)) Then
buildStart = Date.Now
End If
End Sub
Private Sub BuildEvents_OnBuildDone(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildDone
If (IsBuild(Scope, Action)) Then
Dim buildTime = Date.Now - buildStart
WriteToBuildWindow(String.Format("Build time: {0}", buildTime.ToString))
End If
End Sub
Private Sub WriteToBuildWindow(ByVal message As String)
Dim win As Window = DTE.Windows.Item(EnvDTE.Constants.vsWindowKindOutput)
Dim ow As OutputWindow = CType(win.Object, OutputWindow)
For Each owPane As OutputWindowPane In ow.OutputWindowPanes
If (owPane.Name.Equals("Build")) Then
owPane.OutputString(message)
Exit For
End If
Next
End Sub
Показывать начальную страницу после закрытия решения (но не открывать Visual Studio)
Поместите этот код в свой модуль EnvironmentEvents:
Private Sub SolutionEvents_AfterClosing() Handles SolutionEvents.AfterClosing
DTE.ExecuteCommand("View.StartPage")
End Sub
Скрыть начальную страницу после открытия решения
Поместите этот код в свой модуль EnvironmentEvents:
Private Sub SolutionEvents_Opened() Handles SolutionEvents.Opened
Dim startPageGuid As String = "{387CB18D-6153-4156-9257-9AC3F9207BBE}"
Dim startPage As EnvDTE.Window = DTE.Windows.Item(startPageGuid)
If startPage IsNot Nothing Then startPage.Close()
End Sub
Эти два вместе заставят вашу стартовую страницу спрятаться при открытии решения. Когда вы закрываете решение, возвращается начальная страница.
Я часто использую следующие малоизвестные ярлыки:
Очертание: свернуть к определениям, но расширить области
Вы работаете в одном из тех магазинов, которые настаивают на регионах вокруг всего, так что, когда вы ругаетесь в определениях, вы не видите никакого кода?
Что вам действительно нужно, так это макрос коллапса-определения-но-расширения-области, как этот:
Sub CollapseToDefinitionsButExpandAllRegions()
DTE.ExecuteCommand("Edit.CollapsetoDefinitions")
DTE.SuppressUI = True
Dim objSelection As TextSelection = DTE.ActiveDocument.Selection
objSelection.StartOfDocument()
Do While objSelection.FindText("#region",
vsFindOptions.vsFindOptionsMatchInHiddenText)
Loop
objSelection.StartOfDocument()
DTE.SuppressUI = False
End Sub
Поместите это в обычный макромодуль, назначьте его горячей клавише, и ваш код вернется.
(Кроме того, если вы работаете с некоторыми действительно вредными людьми, которые помещают регионы внутри методов, это, к сожалению, расширит эти методы. Если кто-нибудь знает способ написать это, чтобы избежать этого, не стесняйтесь редактировать.)
Вставьте GUID, отлично подходит для работы WiX, добавьте в меню как кнопку или как ключевой ярлык.
Sub InsertGuid()
Dim objTextSelection As TextSelection
objTextSelection = CType(DTE.ActiveDocument.Selection(), EnvDTE.TextSelection)
objTextSelection.Text = System.Guid.NewGuid.ToString.ToUpper(New System.Globalization.CultureInfo("en", False))
End Sub
Организуйте использование всех файлов .cs в решении - Оригинальный автор: djpark.
Sub OrganizeSolution()
Dim sol As Solution = DTE.Solution
For i As Integer = 1 To sol.Projects.Count
OrganizeProject(sol.Projects.Item(i))
Next
End Sub
Private Sub OrganizeProject(ByVal proj As Project)
For i As Integer = 1 To proj.ProjectItems.Count
OrganizeProjectItem(proj.ProjectItems.Item(i))
Next
End Sub
Private Sub OrganizeProjectItem(ByVal projectItem As ProjectItem)
Dim fileIsOpen As Boolean = False
If projectItem.Kind = Constants.vsProjectItemKindPhysicalFile Then
'If this is a c# file
If projectItem.Name.LastIndexOf(".cs") = projectItem.Name.Length - 3 Then
'Set flag to true if file is already open
fileIsOpen = projectItem.IsOpen
Dim window As Window = projectItem.Open(Constants.vsViewKindCode)
window.Activate()
projectItem.Document.DTE.ExecuteCommand("Edit.RemoveAndSort")
'Only close the file if it was not already open
If Not fileIsOpen Then
window.Close(vsSaveChanges.vsSaveChangesYes)
End If
End If
End If
'Be sure to apply RemoveAndSort on all of the ProjectItems.
If Not projectItem.ProjectItems Is Nothing Then
For i As Integer = 1 To projectItem.ProjectItems.Count
OrganizeProjectItem(projectItem.ProjectItems.Item(i))
Next
End If
'Apply RemoveAndSort on a SubProject if it exists.
If Not projectItem.SubProject Is Nothing Then
OrganizeProject(projectItem.SubProject)
End If
End Sub
Свернуть все узлы панели решений, очень полезно особенно для больших проектов:
Public Module CollapseAllNodes
Sub RunCollapseAllNodes()
Dim UIHSolutionExplorer As UIHierarchy
UIHSolutionExplorer = DTE.Windows.Item(Constants.vsext_wk_SProjectWindow).Object()
' Check if there is any open solution
If (UIHSolutionExplorer.UIHierarchyItems.Count = 0) Then
Return
End If
' Get the top node (the name of the solution)
Dim UIHSolutionRootNode As UIHierarchyItem
UIHSolutionRootNode = UIHSolutionExplorer.UIHierarchyItems.Item(1)
CloseRecursif(UIHSolutionRootNode)
' Select the solution node, or else when you click
' on the solution windows scrollbar, it will synchronize the open document
' with the tree and pop out the corresponding node which is probably not
' what you want.
UIHSolutionRootNode.Select(vsUISelectionType.vsUISelectionTypeSelect)
End Sub
Function CloseRecursif(ByRef element)
For Each UIHChild In element.UIHierarchyItems()
CloseRecursif(UIHChild)
If (UIHChild.UIHierarchyItems.Expanded = True) Then
UIHChild.UIHierarchyItems.Expanded = False
End If
Next
End Function
End Module
Я использую макросы Jeff FormatToHtml, если я собираюсь вставить пример кода в сообщение в блоге или по электронной почте.
Я работаю с двумя мониторами, и я нахожу, что макет переключения Sharon макета (с 1 монитора на 2 монитора) полностью бесценен. Когда вам нужно ссылаться на веб-страницу или другую программу при наборе кода, Ctrl-Alt-1, чтобы переключиться на макет одного монитора для окон вашей Visual Studio. Как только вы закончите, Ctrl-Alt-2 переключится на ваш макет монитора и вернет все ваши окна. Отлично!
http://www.invisible-city.com/sharon/2008/06/workstation-hack-visual-studio-on-2.html
Не макрос сам по себе, но полезный:
Public Sub WriteToOutputWindow(ByVal pane as String, ByVal Msg As String)
Dim owPane As OutputWindowPane
Dim win As Window = DTE.Windows.Item(EnvDTE.Constants.vsWindowKindOutput)
Dim ow As OutputWindow = win.Object
Try
owPane = ow.OutputWindowPanes.Item(pane)
Catch
owPane = ow.OutputWindowPanes.Add(pane)
End Try
If Not owPane Is Nothing Then
owPane.Activate()
owPane.OutputString(Msg & vbCrLf)
End If
End Sub
Я сопоставил ctrl-shift-G с макросом, который генерирует GUID в формате реестра - это полезно для редактирования IDL
В настоящее время я работаю над двумя разными проектами с разными стандартами кодирования, которые используют вкладки для начинающих строк, а другой - пробелы. Этот макрос будет переключаться между тем, какой стандарт используется на основе того, какая среда в данный момент активна:
Public Sub ToggleTabs()
If DTE.ActiveDocument.Language = "CSharp" Then
Dim currentSetting As Boolean = DTE.Properties("TextEditor", "CSharp").Item("InsertTabs").Value
DTE.Properties("TextEditor", "CSharp").Item("InsertTabs").Value = Not currentSetting
End If
If DTE.ActiveDocument.Language = "SQL" Then
Dim currentSQLSetting As Boolean = DTE.Properties("TextEditor", "SQL").Item("InsertTabs").Value
DTE.Properties("TextEditor", "SQL").Item("InsertTabs").Value = Not currentSQLSetting
End If
If DTE.ActiveDocument.Language = "HTML" Then
Dim currentHTMLSetting As Boolean = DTE.Properties("TextEditor", "HTML").Item("InsertTabs").Value
DTE.Properties("TextEditor", "HTML").Item("InsertTabs").Value = Not currentHTMLSetting
End If
If DTE.ActiveDocument.Language = "JScript" Then
Dim currentJScriptSetting As Boolean = DTE.Properties("TextEditor", "JScript").Item("InsertTabs").Value
DTE.Properties("TextEditor", "JScript").Item("InsertTabs").Value = Not currentJScriptSetting
End If
End Sub
Я не мог позволить этому вопросу без упоминания этот. У него даже есть видео, чтобы показать, как его устанавливать и использовать. Этот макрос просто позволяет создавать вложенные файлы в проводнике решений (например, resources.resx).
Изменить: обновлена ссылка