Как запустить VBScript в 32-разрядном режиме на 64-битной машине?

У меня есть текстовый файл, который заканчивается на .vbs, который я написал в:

Set Conn = CreateObject("ADODB.Connection")
Conn.Provider = "Microsoft.ACE.OLEDB.12.0"
Conn.Properties("Data Source") = "C:\dummy.accdb"
Conn.Properties("Jet OLEDB:Database Password") = "pass"
Conn.Open
Conn.Close
Set Conn = Nothing

Когда я выполняю это на 32-разрядной машине Windows, она запускается и заканчивается без какого-либо понятия (ожидается).
Когда я выполняю это на 64-разрядной машине Windows, он получает ошибку

Поставщик не найден. Он может быть неправильно установлен.

Но он установлен. Я думаю, что корень проблемы в том, что поставщик 32-разрядный провайдер, насколько я знаю, он не существует как 64-разрядный.

Если я запустил VBScript через IIS на своей 64-разрядной машине (в качестве файла ASP), я могу выбрать, что он должен работать в 32-битном режиме. Затем он может найти поставщика.

Как я могу найти поставщика в Windows 64-bit? Могу ли я сообщить CScript (который выполняет текстовый файл .vbs) для запуска в 32-битном режиме?

Ответ 1

следовать http://support.microsoft.com/kb/896456

Чтобы запустить 32-разрядную командную строку, выполните следующие действия:

* Click Start, click Run, type %windir%\SysWoW64\cmd.exe, and then click OK.

Затем введите

cscript vbscriptfile.vbs

Ответ 2

' C:\Windows\System32\WScript.exe = WScript.exe
Dim ScriptHost : ScriptHost = Mid(WScript.FullName, InStrRev(WScript.FullName, "\") + 1, Len(WScript.FullName))

Dim oWs : Set oWs = CreateObject("WScript.Shell")
Dim oProcEnv : Set oProcEnv = oWs.Environment("Process")

' Am I running 64-bit version of WScript.exe/Cscript.exe? So, call script again in x86 script host and then exit.
If InStr(LCase(WScript.FullName), LCase(oProcEnv("windir") & "\System32\")) And oProcEnv("PROCESSOR_ARCHITECTURE") = "AMD64" Then
    ' rebuild arguments
    If Not WScript.Arguments.Count = 0 Then
        Dim sArg, Arg
        sArg = ""
        For Each Arg In Wscript.Arguments
              sArg = sArg & " " & """" & Arg & """"
        Next
    End If

    Dim sCmd : sCmd = """" &  oProcEnv("windir") & "\SysWOW64\" & ScriptHost & """" & " """ & WScript.ScriptFullName & """" & sArg
    WScript.Echo "Call " & sCmd
    oWs.Run sCmd
    WScript.Quit
End If

Ответ 3

Если у вас есть контроль над запуском исполняемого файла cscript, запустите версию X:\windows\syswow64\cscript.exe, которая является 32-разрядной версией.

Ответ 4

   ' ***************
   ' *** 64bit check
   ' ***************
   ' check to see if we are on 64bit OS -> re-run this script with 32bit cscript
   Function RestartWithCScript32(extraargs)
   Dim strCMD, iCount
   strCMD = r32wShell.ExpandEnvironmentStrings("%SYSTEMROOT%") & "\SysWOW64\cscript.exe"
   If NOT r32fso.FileExists(strCMD) Then strCMD = "cscript.exe" ' This may not work if we can't find the SysWOW64 Version
   strCMD = strCMD & Chr(32) & Wscript.ScriptFullName & Chr(32)
   If Wscript.Arguments.Count > 0 Then
    For iCount = 0 To WScript.Arguments.Count - 1
     if Instr(Wscript.Arguments(iCount), " ") = 0 Then ' add unspaced args
      strCMD = strCMD & " " & Wscript.Arguments(iCount) & " "
     Else
      If Instr("/-\", Left(Wscript.Arguments(iCount), 1)) > 0 Then ' quote spaced args
       If InStr(WScript.Arguments(iCount),"=") > 0 Then
        strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), "=") + 1) & """ "
       ElseIf Instr(WScript.Arguments(iCount),":") > 0 Then
        strCMD = strCMD & " " & Left(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") ) & """" & Mid(Wscript.Arguments(iCount), Instr(Wscript.Arguments(iCount), ":") + 1) & """ "
       Else
        strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
       End If
      Else
       strCMD = strCMD & " """ & Wscript.Arguments(iCount) & """ "
      End If
     End If
    Next
   End If
   r32wShell.Run strCMD & " " & extraargs, 0, False
   End Function

   Dim r32wShell, r32env1, r32env2, r32iCount
   Dim r32fso
   SET r32fso = CreateObject("Scripting.FileSystemObject")
   Set r32wShell = WScript.CreateObject("WScript.Shell")
   r32env1 = r32wShell.ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%")
   If r32env1 <> "x86" Then ' not running in x86 mode
    For r32iCount = 0 To WScript.Arguments.Count - 1
     r32env2 = r32env2 & WScript.Arguments(r32iCount) & VbCrLf
    Next
    If InStr(r32env2,"restart32") = 0 Then RestartWithCScript32 "restart32" Else MsgBox "Cannot find 32bit version of cscript.exe or unknown OS type " & r32env1
    Set r32wShell = Nothing
    WScript.Quit
   End If
   Set r32wShell = Nothing
   Set r32fso = Nothing
   ' *******************
   ' *** END 64bit check
   ' *******************

Поместите вышеуказанный код в начало вашего script, а последующий код будет работать в 32-битном режиме с доступом к 32-битным ODBC-драйверам. Источник.

Ответ 5

В пусковой программе script вы можете принудительно ее использовать, она позволяет сохранить один и тот же script и тот же запуск для обеих архитектур

:: For 32 bits architecture, this line is sufficent (32bits is the only cscript available)
set CSCRIPT="cscript.exe"
:: Detect windows 64bits and use the expected cscript (SysWOW64 contains 32bits executable)
if exist "C:\Windows\SysWOW64\cscript.exe" set CSCRIPT="C:\Windows\SysWOW64\cscript.exe"
%CSCRIPT% yourscript.vbs

Ответ 6

Альтернативный метод для запуска 32-разрядных скриптов на 64-разрядной машине: % windir%\syswow64\cscript.exe vbscriptfile.vbs

Ответ 7

Мы можем заставить vbscript всегда работать с 32-битным режимом, изменив "system32" на "sysWOW64" по умолчанию по ключу "Computer\HKLM\SOFTWARE]\Classes\VBSFile\Shell\Open\Command