XSLT - удаление пробелов из шаблона

Ответ 1

В XSLT пустое пространство сохраняется по умолчанию, так как оно может быть очень релевантным.

Лучший способ предотвратить нежелательное белое пространство на выходе - не создавать его в первую очередь. Не выполнять:

<xsl:template match="foo">
  foo
</xsl:template>

потому что "\n··foo\n", с точки зрения процессора. Скорее сделайте

<xsl:template match="foo">
  <xsl:text>foo</xsl:text>
</xsl:template>

Белое пространство в таблице стилей игнорируется, если оно происходит только между XML-элементами. Проще говоря: никогда не используйте "голый" текст в любом месте вашего XSLT-кода, всегда прилагайте его к элементу.

Кроме того, используя неспецифический:

<xsl:apply-templates />

является проблематичным, поскольку правило XSLT по умолчанию для текстовых узлов говорит "скопировать их на выход". Это относится и к узлам "только для белого пространства". Например:

<xml>
  <data> value </data>
</xml>

содержит три текстовых узла:

• "\n··" (сразу после <xml>)
• "·value·"
• "\n" (прямо перед </xml>)

Чтобы избежать того, что # 1 и # 3 прокрались в вывод (что является наиболее распространенной причиной нежелательных пробелов), вы можете переопределить правило по умолчанию для текстовых узлов, объявив пустой шаблон:

<xsl:template match="text()" />

Все текстовые узлы теперь отключены, и текстовый вывод должен быть явно создан:

<xsl:value-of select="data" />

Чтобы удалить пустое пространство из значения, вы можете использовать функцию normalize-space() XSLT:

<xsl:value-of select="normalize-space(data)" />

Но осторожно, так как функция нормализует любое белое пространство, найденное в строке, например. "·value··1·" станет "value·1".

Кроме того, вы можете использовать элементы <xsl:strip-space> и <xsl:preserve-space>, хотя обычно это необязательно (и, лично, я предпочитаю явное управление белым пространством, как указано выше).

Ответ 2

По умолчанию шаблоны XSLT имеют набор <xsl:preserve-space>, который будет содержать пробелы в вашем выходе. Вы можете добавить <xsl:strip-space elements="*">, чтобы сообщить об этом где удалить пробелы.

Вам также может потребоваться включить директиву normalize-space, например:

<xsl:template match="text()"><xsl:value-of select="normalize-space(.)"/></xsl:template> 

Вот пример для сохранения/полосы пространства из W3 Schools.

Ответ 3

Что касается удаления вкладок, но сохранение отдельных строк, я попытался использовать следующий подход XSLT 1.0, и он работает довольно хорошо. Использование вами версии 1.0 или 2.0 во многом зависит от используемой вами платформы. Похоже, что технология .NET по-прежнему зависит от XSLT 1.0, и поэтому вы ограничены чрезвычайно грязными шаблонами (см. Ниже). Если вы используете Java или что-то еще, обратитесь к гораздо более понятному подходу XSLT 2.0, указанному в самом низу.

Эти примеры предназначены для вас, чтобы удовлетворить ваши конкретные потребности. В качестве примера я использую вкладки, но это должно быть достаточно общим, чтобы быть расширяемым.

XML:

<?xml version="1.0" encoding="UTF-8"?>
<text>
        adslfjksdaf

                dsalkfjdsaflkj

            lkasdfjlsdkfaj
</text>

... и шаблон XSLT 1.0 (требуется, если вы используете .NET):

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet  
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">   
 <xsl:template name="search-and-replace">
   <xsl:param name="input"/>
   <xsl:param name="search-string"/>
   <xsl:param name="replace-string"/>
   <xsl:choose>
    <xsl:when test="$search-string and 
                    contains($input,$search-string)">
       <xsl:value-of
           select="substring-before($input,$search-string)"/>
       <xsl:value-of select="$replace-string"/>
       <xsl:call-template name="search-and-replace">
         <xsl:with-param name="input"
               select="substring-after($input,$search-string)"/>
         <xsl:with-param name="search-string"
               select="$search-string"/>
         <xsl:with-param name="replace-string"
               select="$replace-string"/>
       </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$input"/>
    </xsl:otherwise>
   </xsl:choose>
  </xsl:template>                
  <xsl:template match="text">
   <xsl:call-template name="search-and-replace">
     <xsl:with-param name="input" select="text()" />
     <xsl:with-param name="search-string" select="'&#x9;'" />
     <xsl:with-param name="replace-string" select="''" />
   </xsl:call-template>    
  </xsl:template>
</xsl:stylesheet>

XSLT 2.0 делает это тривиальным с помощью функции replace:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:xs="http://www.w3.org/2001/XMLSchema"
      exclude-result-prefixes="xs"
      version="2.0">
 <xsl:template match="text">
  <xsl:value-of select="replace(text(), '&#x9;', '')" />
 </xsl:template>
</xsl:stylesheet>

Ответ 4

   <xsl:choose>
    <xsl:when test="@TYPE">
     <xsl:value-of select="@TYPE" />,
    </xsl:when>
    <xsl:otherwise>Home </xsl:otherwise>
   </xsl:choose>
   <xsl:value-of select="STREET" />,
   <xsl:value-of select="CITY" />,
   <xsl:value-of select="STATE" />,
   <xsl:value-of select="ZIP" />,

Это делает пробелы после каждой запятой значительными, и поэтому она заканчивается на выходе. Если вы закроете каждую запятую в <xsl:text>, проблема исчезнет.

Также избавьтесь от этого disable-output-escaping. Здесь ничего не происходит, поскольку вы не выводите XML.

Ответ 5

Добавьте один шаблон в свой xslt

<xsl:template match="text()"/>

Ответ 6

Мой предыдущий ответ неверен, все запятые должны выводиться через тег 'text'

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/PHONEBOOK">
        <xsl:for-each select="LISTING">
            <xsl:value-of select="RELATION" /><xsl:text>, </xsl:text>
            <xsl:value-of select="FIRST" /><xsl:text>, </xsl:text>
            <xsl:value-of select="LAST" /><xsl:text>, </xsl:text>

                <xsl:for-each select="ADDRESS">
                    <xsl:choose>
                        <xsl:when test="@TYPE">
                            <xsl:value-of select="@TYPE" /><xsl:text>,</xsl:text>
                        </xsl:when>
                        <xsl:otherwise><xsl:text>Home </xsl:text></xsl:otherwise>
                    </xsl:choose>
                <xsl:value-of select="STREET/text()" /><xsl:text>,</xsl:text>
                    <xsl:value-of select="CITY/text()" /><xsl:text>,</xsl:text>
                    <xsl:value-of select="STATE/text()" /><xsl:text>,</xsl:text>
                    <xsl:value-of select="ZIP/text()" /><xsl:text>,</xsl:text>
                </xsl:for-each>

            <xsl:for-each select="PHONE">
                <xsl:choose>
                    <xsl:when test="@TYPE">
                        <xsl:value-of select="@TYPE" />  
                    </xsl:when>
                    <xsl:otherwise><xsl:text>Home </xsl:text></xsl:otherwise>
                </xsl:choose>
                <xsl:value-of select="."  /><xsl:text  >, </xsl:text>
            </xsl:for-each>

            <xsl:if test="EMAIL">
                <xsl:for-each select="EMAIL">
                    <xsl:choose>
                        <xsl:when test="@TYPE">
                            <xsl:value-of select="@TYPE" /><xsl:text  > </xsl:text> 
                        </xsl:when>
                        <xsl:otherwise><xsl:text  >Personal </xsl:text></xsl:otherwise>
                    </xsl:choose>
                    <xsl:value-of select="."  /><xsl:text  >, </xsl:text>
                </xsl:for-each>
            </xsl:if>
            <xsl:text>&#10;&#13;</xsl:text>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="text()|@*">
        <xsl:text>-</xsl:text>
    </xsl:template>

</xsl:stylesheet>

Ответ 7

Измените код, который мы использовали для форматирования необработанного XML файла, удалив ниже строки, удалит лишние пробелы, добавленные в экспортированное excel.

При форматировании с помощью системы с отступом свойств добавляются лишние пробелы.

Строки комментариев, связанные с форматированием xml, как показано ниже, и попробуйте.

xmlWriter.Formatting = System.Xml.Formatting.Indented;

Ответ 8

Создайте правило шаблона:

<xsl:template name="strip-space">
    <xsl:param name="data"/>
    <xsl:value-of select="normalize-space($data)"/>
</xsl:template>

Теперь требуется удалить лишние пробелы:

<xsl:template match="my-element">
    <xsl:call-template name="strip-space">
        <xsl:with-param name="data">
            <xsl:apply-templates/>
        </xsl:with-param>
    </xsl:call-template>
</xsl:template>

Например, рассмотрим приведенный ниже фрагмент XML:

<?xml version="1.0" encoding="UTF-8"?>
<test>
    <my-element>
        <e1>some text</e1> <e2>some other text</e2> <e3>some other text</e3>
    </my-element>
</test>

И если кому-то нравится конвертировать его в текст ниже:

{test{my-element{e1some text} {e2some other text} {e3some other text}}}

Теперь идет таблица стилей:

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" />

    <xsl:template match="/">
        <xsl:apply-templates mode="t1"/>
        <xsl:text>&#xa;</xsl:text>
        <xsl:apply-templates mode="t2"/>
    </xsl:template>

    <xsl:template match="*" mode="t1">
        <xsl:text>{</xsl:text>
        <xsl:value-of select="local-name()"/>
        <xsl:call-template name="strip-space">
            <xsl:with-param name="data">
                <xsl:apply-templates mode="t1"/>
            </xsl:with-param>
        </xsl:call-template>
        <xsl:text>}</xsl:text>
    </xsl:template>

    <xsl:template match="*" mode="t2">
        <xsl:text>{</xsl:text>
        <xsl:value-of select="local-name()"/>
        <xsl:value-of select="."/>
        <xsl:text>}</xsl:text>
    </xsl:template>

    <xsl:template name="strip-space">
        <xsl:param name="data"/>
        <xsl:value-of select="normalize-space($data)"/>
    </xsl:template>

</xsl:stylesheet>

После применения таблицы стилей создается:

{test{my-element{e1some text} {e2some other text} {e3some other text}}}

{test

        some text some other text some other text

}

В выходных данных описано, как @mode="t1" (подход <xsl:value-of select="."/>) отличается от @mode="t2" (подход xsl:call-template). Надеюсь, это кому-нибудь поможет.