Подтвердить что ты не робот

Простые методы программирования/трюки в Mathematica для создания графики для математической книги?

Я попытался использовать его. И это действительно приятно для некоторых сюжетов, но когда о создании, например, треугольника, я нашел это довольно сложным. Я понял, как рисовать треугольник, но как добавить эти угловые метки, эти кривые линии?

И так как я начинаю заниматься этой работой, написав книгу, может кто-нибудь порекомендовать меня, что является наилучшим способом достижения хорошей графики, например, как на рисунке ниже. Какие программы лучше всего использовать. enter image description here

Спасибо за любые предложения и рекомендации.

4b9b3361

ОТВЕТЫ

Ответ 1

Вот простой/основной способ сделать первый:

Graphics[{

 (* The dashed circle segment *)
 {
  Dashing[{.04, .01}], 
  Darker[Orange], 
  AbsoluteThickness[2], 
  Circle[{0, 0}, 1, {1, 2 \[Pi]}]
 },

 (* The solid circle segment *)
 {
  Orange, 
  AbsoluteThickness[2], 
  Circle[{0, 0}, 1, {0, 1}]
 },

 (* The radial lines and the small circle segment *)
 Line[{{0, 0}, {1, 0}}],
 Line[{{0, 0}, {Cos[1], Sin[1]}}],
 Circle[{0, 0}, .2, {0, 1}],

 (* Various text labels *)
 {
  Text[Style["\[Theta]", 24], .3 {Cos[.5], Sin[.5]}], 
  Text[Style["s", 24], 1.1 {Cos[.5], Sin[.5]}], 
  Text[Style["r", 24], {.5, -.1}]
 }
}]

Mathematica graphics

Следующее - это то же самое, но завернутое в Manipulate и параметризованное на угол alpha:

Manipulate[
 Graphics[{
  {Dashing[{.04, .01}], Darker[Orange], AbsoluteThickness[2], 
  Circle[{0, 0}, 1, {\[Alpha], 2 \[Pi]}]},
  {Orange, AbsoluteThickness[2], Circle[{0, 0}, 1, {0, \[Alpha]}]},
  Line[{{0, 0}, {1, 0}}],
  Line[{{0, 0}, {Cos[\[Alpha]], Sin[\[Alpha]]}}],
  Circle[{0, 0}, .2, {0, \[Alpha]}],
  {Text[Style["\[Theta]", 
  24], .3 {Cos[\[Alpha]/2], Sin[\[Alpha]/2]}], 
  Text[Style["s", 24], 1.1 {Cos[\[Alpha]/2], Sin[\[Alpha]/2]}], 
  Text[Style["r", 24], {.5, -.1}]}
 }],
{{\[Alpha], 1}, 0, 2 \[Pi]}]

Если вы переместите ползунок, содержимое изменится соответствующим образом:

Mathematica graphics

Ответ 2

Изменить Вы также можете получить вдохновение из проекта Демонстрации. Это демонстрации, связанные с треугольниками. После быстрого просмотра, я думаю, вы должны увидеть демонстрации, связанные с геометрией, с помощью Джей Варендорф. Он сделал много из них, и они используют структурированный набор связанных с геометрией функций, которые вы, скорее всего, сможете повторно использовать.

Здесь функция angleArc, чтобы вы начали. Это всего лишь небольшой пример вспомогательной функции, которую вы могли бы использовать, там было много возможностей для улучшения.

angleArc[Polygon[vertices_List, ___], r_, i_] :=
 Module[{a, b, c, phi1, phi2},
  {a, b, c} = Take[RotateLeft[vertices, i-2], 3];
  {phi1, phi2} = [email protected][{ArcTan @@ (a - b), ArcTan @@ (c - b)}];
  If[phi2 - phi1 > Pi, phi1 += 2 Pi];
  Circle[b, r, {phi2, phi1}]
 ]

poly = Polygon[{{0, 0}, {1, 2}, {2, 1}}];

Graphics[{EdgeForm[Thick], FaceForm[None], poly, 
  Table[angleArc[poly, .2, i], {i, Length[poly[[1]]]}]}]

Mathematica graphics

Manipulate[
 With[{poly = Polygon[{a, b, c}]},
  Graphics[
   {EdgeForm[Thick], FaceForm[None], poly, 
    Table[angleArc[poly, .2, i], {i, Length[poly[[1]]]}]},
   PlotRange -> 2 {{-1, 1}, {-1, 1}}, Frame -> True
   ]
  ],
 {{a, {0, 0}}, Locator}, {{b, {1, 0}}, Locator}, {{c, {0, 1}}, Locator}
 ]

Mathematica graphics

Ответ 3

Один превосходный продукт, поддерживаемый Wolfram, Geometrica. Это не дешевое дополнение по цене 495 долларов, но оно будет создавать диаграммы, подобные вашим, намного проще, чем делать их в raw MMA Mathematica. Это в основном очень большое расширение подхода Szabolcs в комментариях - библиотека функций для рисования материала.

Ответ 4

Мне нравится Mathematica много. Но есть больше вариантов геометрического рисования.

Здесь у вас есть пятиминутный эскиз, сделанный с Геометрические выражения (используется очень низкое разрешение):

enter image description here

Вычисления геометрии делают некоторые хорошие плоские вычисления геометрии и могут экспортировать результаты в Mma онлайн.

Ответ 5

Да, встроенные графические инструменты Mathematica немного изворотливы в местах, и есть некоторые досадные упущения. Но там есть хороший набор базовых графических элементов, и, с другой стороны, вы всего лишь на несколько нажатий клавиш от математических инструментов, необходимых для устранения некоторых недостатков графического редактора. Нужна дуга? Просто вычислите его ниже и скопируйте/вставьте его. Невозможно сделать это с помощью Adobe Illustrator! Там широкий доступ к уравнениям и греческим символам тоже. Это может быть полезно, когда вам больше нечего делать.

Здесь первый - это не совсем неприемлемо...:)

mathematica built-in graphics