Ответ 1

Не совсем. Способ DBMS_OUTPUT заключается в следующем: ваш блок PL/SQL выполняется на сервере базы данных без взаимодействия с клиентом. Поэтому, когда вы вызываете PUT_LINE, он просто помещает этот текст в буфер в памяти на сервере. Когда ваш блок PL/SQL завершается, управление возвращается клиенту (в этом случае я предполагаю SQLPlus); в этот момент клиент получает текст из буфера, вызывая GET_LINE и отображая его.

Таким образом, единственный способ сделать вывод в файле журнала чаще всего состоит в том, чтобы разбить большой блок PL/SQL на несколько меньших блоков, поэтому управление возвращается клиенту чаще. Это может быть непрактично в зависимости от того, что делает ваш код.

Другими альтернативами является использование UTL_FILE для записи в текстовый файл, который можно очистить, когда захотите, или использовать процедуру автономной транзакции для вставки операторов отладки в таблицу базы данных и фиксации после каждого из них.

Ответ 2

Две альтернативы:

• Вы можете вставить свои данные регистрации в таблицу регистрации, используя автономную транзакцию. Вы можете запросить эту таблицу журналов в другом SQLPLUS/Toad/sql-разработчике и т.д. Сеансе. Вы должны использовать автономную транзакцию, чтобы можно было зафиксировать ведение журнала, не мешая обработке транзакций в вашем основном sql script.

• Другой альтернативой является использование конвейерной функции, которая возвращает вашу информацию о регистрации. См. Здесь для примера: http://berxblog.blogspot.com/2009/01/pipelined-function-vs-dbmsoutput.html Когда вы используете конвейерную функцию, вам не нужно использовать другой SQLPLUS/Toad/sql developer и т.д... сеанс.

Ответ 3

Если это возможно, вы должны заменить вызовы dbms_output.put_line своей собственной функцией.

Вот код этой функции WRITE_LOG - если вы хотите иметь возможность выбирать между 2 решениями для ведения журналов:

записывать журналы в таблицу в автономной транзакции

CREATE OR REPLACE PROCEDURE to_dbg_table(p_log varchar2)
  -- table mode: 
  -- requires
  -- CREATE TABLE dbg (u varchar2(200)   --- username
  --                 , d timestamp       --- date
  --                 , l varchar2(4000)  --- log 
  -- );
AS
   pragma autonomous_transaction;
BEGIN
  insert into dbg(u, d, l) values (user, sysdate, p_log);
  commit;
END to_dbg_table;
/

или напишите непосредственно на сервер БД, на котором размещена ваша база данных

При этом используется каталог Oracle TMP_DIR

CREATE OR REPLACE PROCEDURE to_dbg_file(p_fname varchar2, p_log varchar2)
  -- file mode: 
  -- requires
--- CREATE OR REPLACE DIRECTORY TMP_DIR as '/directory/where/oracle/can/write/on/DB_server/';
AS
  l_file utl_file.file_type;
BEGIN
  l_file := utl_file.fopen('TMP_DIR', p_fname, 'A');
  utl_file.put_line(l_file, p_log);
  utl_file.fflush(l_file);
  utl_file.fclose(l_file);
END to_dbg_file;
/

WRITE_LOG

Затем процедура WRITE_LOG, которая может переключаться между двумя вариантами использования или быть деактивирована во избежание потери производительности (g_DEBUG:=FALSE).

CREATE OR REPLACE PROCEDURE write_log(p_log varchar2) AS
  -- g_DEBUG can be set as a package variable defaulted to FALSE
  -- then change it when debugging is required
  g_DEBUG boolean := true;
  -- the log file name can be set with several methods...
  g_logfname varchar2(32767) := 'my_output.log';
  -- choose between 2 logging solutions:
  -- file mode: 
  g_TYPE varchar2(7):= 'file';
  -- table mode: 
  --g_TYPE varchar2(7):= 'table';
  -----------------------------------------------------------------
BEGIN
  if g_DEBUG then
    if g_TYPE='file' then
      to_dbg_file(g_logfname, p_log);
    elsif g_TYPE='table' then
      to_dbg_table(p_log);
    end if;
  end if;  
END write_log;
/

А вот как проверить выше:

1) Запустите это (файловый режим) из вашего SQLPLUS:

BEGIN
  write_log('this is a test');
  for i in 1..100 loop
    DBMS_LOCK.sleep(1);
    write_log('iter=' || i);
  end loop;
  write_log('test complete');
END;
/

2) на сервере базы данных откройте оболочку и

    tail -f -n500 /directory/where/oracle/can/write/on/DB_server/my_output.log

Ответ 4

буфер DBMS_OUTPUT читается при вызове процедуры DBMS_OUTPUT.get_line. Если ваше клиентское приложение SQL * Plus, это означает, что он будет очищаться только после завершения процедуры.

Вы можете применить метод, описанный в this SO, чтобы записать буфер DBMS_OUTPUT в файл.

Ответ 5

Установите метаданные сеанса MODULE и/или ACTION, используя dbms_application_info().
Монитор с OEM, например:

Module: ArchiveData
Action: xxx of xxxx

Ответ 6

Если у вас есть доступ к системной оболочке из среды PL/SQL, вы можете вызвать netcat:

 BEGIN RUN_SHELL('echo "'||p_msg||'" | nc '||p_host||' '||p_port||' -w 5'); END;

p_msg - это сообщение журнала v_host - это хост, на котором выполняется скрипт Python, который считывает данные из сокета на порту v_port.

Я использовал этот дизайн, когда писал aplogr для мониторинга оболочки в реальном времени и журналов pl/sql.