Я новичок в Thrust. Я вижу, что все презентации и примеры Thrust содержат только хост-код.
Я хотел бы знать, могу ли я передать device_vector в свое собственное ядро? Как? Если да, каковы операции, разрешенные на нем внутри кода ядра/устройства?
Я новичок в Thrust. Я вижу, что все презентации и примеры Thrust содержат только хост-код.
Я хотел бы знать, могу ли я передать device_vector в свое собственное ядро? Как? Если да, каковы операции, разрешенные на нем внутри кода ядра/устройства?
Thrust является чисто абстракцией стороны. Он не может использоваться внутри ядер. Вы можете передать память устройства, инкапсулированную внутри thrust:: device_vector, в ваше собственное ядро следующим образом:
thrust::device_vector< Foo > fooVector;
// Do something thrust-y with fooVector
Foo* fooArray = thrust::raw_pointer_cast( &fooVector[0] );
// Pass raw array and its size to kernel
someKernelCall<<< x, y >>>( fooArray, fooVector.size() );
и вы также можете использовать память устройства, не распределенную по осям в алгоритмах тяги, создавая экземпляр thrust:: device_ptr с помощью указателя памяти устройства cuda.
Отредактировано спустя четыре с половиной года, чтобы добавить, что в соответствии с ответом @JackOLantern, thrust 1.8 добавляет последовательную политику выполнения, которая означает, что вы можете запускать однопоточные версии алограмм осязания на устройстве. Обратите внимание, что по-прежнему невозможно напрямую передать вектор тягового устройства в ядро, а векторы устройств не могут быть непосредственно использованы в коде устройства. Также обратите внимание, что динамический parallelism не поддерживается, поэтому вы не можете выполнять параллельное принудительное выполнение с запуском ядра в виде дочерней сетки (хотя это было бы очень интересной функцией).
Я хотел бы дать обновленный ответ на этот вопрос.
Начиная с Thrust 1.8, примитивы CUDA Thrust могут быть объединены с политикой выполнения thrust::seq
для последовательного запуска в одном потоке CUDA (или последовательно в пределах одного потока ЦП). Ниже приведен пример.
Если вы хотите выполнить параллельное выполнение в потоке, вы можете использовать CUB, который предлагает процедуры восстановления, которые могут быть вызваны изнутри threadblock, при условии, что ваша карта активирует динамический parallelism.
Вот пример с Thrust
#include <stdio.h>
#include <thrust/reduce.h>
#include <thrust/execution_policy.h>
/********************/
/* CUDA ERROR CHECK */
/********************/
#define gpuErrchk(ans) { gpuAssert((ans), __FILE__, __LINE__); }
inline void gpuAssert(cudaError_t code, char *file, int line, bool abort=true)
{
if (code != cudaSuccess)
{
fprintf(stderr,"GPUassert: %s %s %d\n", cudaGetErrorString(code), file, line);
if (abort) exit(code);
}
}
__global__ void test(float *d_A, int N) {
float sum = thrust::reduce(thrust::seq, d_A, d_A + N);
printf("Device side result = %f\n", sum);
}
int main() {
const int N = 16;
float *h_A = (float*)malloc(N * sizeof(float));
float sum = 0.f;
for (int i=0; i<N; i++) {
h_A[i] = i;
sum = sum + h_A[i];
}
printf("Host side result = %f\n", sum);
float *d_A; gpuErrchk(cudaMalloc((void**)&d_A, N * sizeof(float)));
gpuErrchk(cudaMemcpy(d_A, h_A, N * sizeof(float), cudaMemcpyHostToDevice));
test<<<1,1>>>(d_A, N);
}
Это обновление моего предыдущего ответа.
Начиная с Thrust 1.8.1, примитивы CUDA Thrust могут быть объединены с политикой выполнения thrust::device
для параллельной работы в одном потоке CUDA с использованием CUDA dynamic parallelism. Ниже приведен пример.
#include <stdio.h>
#include <thrust/reduce.h>
#include <thrust/execution_policy.h>
#include "TimingGPU.cuh"
#include "Utilities.cuh"
#define BLOCKSIZE_1D 256
#define BLOCKSIZE_2D_X 32
#define BLOCKSIZE_2D_Y 32
/*************************/
/* TEST KERNEL FUNCTIONS */
/*************************/
__global__ void test1(const float * __restrict__ d_data, float * __restrict__ d_results, const int Nrows, const int Ncols) {
const unsigned int tid = threadIdx.x + blockDim.x * blockIdx.x;
if (tid < Nrows) d_results[tid] = thrust::reduce(thrust::seq, d_data + tid * Ncols, d_data + (tid + 1) * Ncols);
}
__global__ void test2(const float * __restrict__ d_data, float * __restrict__ d_results, const int Nrows, const int Ncols) {
const unsigned int tid = threadIdx.x + blockDim.x * blockIdx.x;
if (tid < Nrows) d_results[tid] = thrust::reduce(thrust::device, d_data + tid * Ncols, d_data + (tid + 1) * Ncols);
}
/********/
/* MAIN */
/********/
int main() {
const int Nrows = 64;
const int Ncols = 2048;
gpuErrchk(cudaFree(0));
// size_t DevQueue;
// gpuErrchk(cudaDeviceGetLimit(&DevQueue, cudaLimitDevRuntimePendingLaunchCount));
// DevQueue *= 128;
// gpuErrchk(cudaDeviceSetLimit(cudaLimitDevRuntimePendingLaunchCount, DevQueue));
float *h_data = (float *)malloc(Nrows * Ncols * sizeof(float));
float *h_results = (float *)malloc(Nrows * sizeof(float));
float *h_results1 = (float *)malloc(Nrows * sizeof(float));
float *h_results2 = (float *)malloc(Nrows * sizeof(float));
float sum = 0.f;
for (int i=0; i<Nrows; i++) {
h_results[i] = 0.f;
for (int j=0; j<Ncols; j++) {
h_data[i*Ncols+j] = i;
h_results[i] = h_results[i] + h_data[i*Ncols+j];
}
}
TimingGPU timerGPU;
float *d_data; gpuErrchk(cudaMalloc((void**)&d_data, Nrows * Ncols * sizeof(float)));
float *d_results1; gpuErrchk(cudaMalloc((void**)&d_results1, Nrows * sizeof(float)));
float *d_results2; gpuErrchk(cudaMalloc((void**)&d_results2, Nrows * sizeof(float)));
gpuErrchk(cudaMemcpy(d_data, h_data, Nrows * Ncols * sizeof(float), cudaMemcpyHostToDevice));
timerGPU.StartCounter();
test1<<<iDivUp(Nrows, BLOCKSIZE_1D), BLOCKSIZE_1D>>>(d_data, d_results1, Nrows, Ncols);
gpuErrchk(cudaPeekAtLastError());
gpuErrchk(cudaDeviceSynchronize());
printf("Timing approach nr. 1 = %f\n", timerGPU.GetCounter());
gpuErrchk(cudaMemcpy(h_results1, d_results1, Nrows * sizeof(float), cudaMemcpyDeviceToHost));
for (int i=0; i<Nrows; i++) {
if (h_results1[i] != h_results[i]) {
printf("Approach nr. 1; Error at i = %i; h_results1 = %f; h_results = %f", i, h_results1[i], h_results[i]);
return 0;
}
}
timerGPU.StartCounter();
test2<<<iDivUp(Nrows, BLOCKSIZE_1D), BLOCKSIZE_1D>>>(d_data, d_results1, Nrows, Ncols);
gpuErrchk(cudaPeekAtLastError());
gpuErrchk(cudaDeviceSynchronize());
printf("Timing approach nr. 2 = %f\n", timerGPU.GetCounter());
gpuErrchk(cudaMemcpy(h_results1, d_results1, Nrows * sizeof(float), cudaMemcpyDeviceToHost));
for (int i=0; i<Nrows; i++) {
if (h_results1[i] != h_results[i]) {
printf("Approach nr. 2; Error at i = %i; h_results1 = %f; h_results = %f", i, h_results1[i], h_results[i]);
return 0;
}
}
printf("Test passed!\n");
}
В приведенном выше примере выполняется сокращение строк матрицы в том же смысле, что и Сокращение строк матрицы с CUDA, но это делается иначе, чем выше, путем вызова примитивов CUDA Thrust непосредственно из написанных пользователем ядер. Кроме того, приведенный выше пример служит для сравнения производительности тех же операций, когда выполняется с двумя политиками выполнения, а именно thrust::seq
и thrust::device
. Ниже приведены некоторые графики, показывающие разницу в производительности.
Производительность была оценена на Kepler K20c и на Maxwell GeForce GTX 850M.
Если вы хотите использовать данные, выделенные/обработанные нажатием да, вы можете просто получить необработанный указатель выделенных данных.
int * raw_ptr = thrust::raw_pointer_cast(dev_ptr);
если вы хотите выделить векторы тяги в ядре, я никогда не пробовал, но я не думаю, что это сработает а также если он работает, я не думаю, что он принесет какую-либо выгоду.