Как скопировать файл из моего проекта в выходной каталог с помощью qmake?
Я собираюсь в Linux, но в будущем я скомпилирую его на Mac и Windows.
Как скопировать файл из моего проекта в выходной каталог с помощью qmake?
Я собираюсь в Linux, но в будущем я скомпилирую его на Mac и Windows.
Вот пример из одного из наших проектов. Он показывает, как копировать файлы в DESTDIR
для Windows и Linux.
linux-g++{
#...
EXTRA_BINFILES += \
$${THIRDPARTY_PATH}/gstreamer-0.10/linux/plugins/libgstrtp.so \
$${THIRDPARTY_PATH}/gstreamer-0.10/linux/plugins/libgstvideo4linux2.so
for(FILE,EXTRA_BINFILES){
QMAKE_POST_LINK += $$quote(cp $${FILE} $${DESTDIR}$$escape_expand(\n\t))
}
}
win32 {
#...
EXTRA_BINFILES += \
$${THIRDPARTY_PATH}/glib-2.0/win32/bin/libglib-2.0.dll \
$${THIRDPARTY_PATH}/glib-2.0/win32/bin/libgmodule-2.0.dll
EXTRA_BINFILES_WIN = $${EXTRA_BINFILES}
EXTRA_BINFILES_WIN ~= s,/,\\,g
DESTDIR_WIN = $${DESTDIR}
DESTDIR_WIN ~= s,/,\\,g
for(FILE,EXTRA_BINFILES_WIN){
QMAKE_POST_LINK +=$$quote(cmd /c copy /y $${FILE} $${DESTDIR_WIN}$$escape_expand(\n\t))
}
}
Вы можете использовать функцию qmake для повторного использования:
# Copies the given files to the destination directory
defineTest(copyToDestdir) {
files = $$1
for(FILE, files) {
DDIR = $$DESTDIR
# Replace slashes in paths with backslashes for Windows
win32:FILE ~= s,/,\\,g
win32:DDIR ~= s,/,\\,g
QMAKE_POST_LINK += $$QMAKE_COPY $$quote($$FILE) $$quote($$DDIR) $$escape_expand(\\n\\t)
}
export(QMAKE_POST_LINK)
}
то используйте его следующим образом:
copyToDestdir($$OTHER_FILES) # a variable containing multiple paths
copyToDestdir(run.sh) # a single filename
copyToDestdir(run.sh README) # multiple files
Если вы используете make install, вы можете использовать переменную INSTALLS в qmake. Вот пример:
images.path = $${DESTDIR}/images
images.files += images/splashscreen.png
images.files += images/logo.png
INSTALLS += images
затем выполните make install
.
Я нашел, что мне пришлось изменить ответ, полученный sje397. для Qt5 Beta1 вместе с QtCreator 2.5.2. Я использую этот script для копирования qml файлов в целевой каталог как шаг добавления после завершения сборки.
Мой .pro файл имеет следующий код
OTHER_FILES += \
Application.qml
# Copy qml files post build
win32 {
DESTDIR_WIN = $${DESTDIR}
DESTDIR_WIN ~= s,/,\\,g
PWD_WIN = $${PWD}
PWD_WIN ~= s,/,\\,g
for(FILE, OTHER_FILES){
QMAKE_POST_LINK += $$quote(cmd /c copy /y $${PWD_WIN}\\$${FILE} $${DESTDIR_WIN}$$escape_expand(\\n\\t))
}
}
unix {
for(FILE, OTHER_FILES){
QMAKE_POST_LINK += $$quote(cp $${PWD}/$${FILE} $${DESTDIR}$$escape_expand(\\n\\t))
}
}
Обратите внимание, что я использую $$ PWD_WIN для подачи полного пути к исходному файлу в команду копирования.
Создайте файл copy_files.prf
в одном из путей, которые qmake использует для функций конфигурации. Файл должен выглядеть следующим образом:
QMAKE_EXTRA_COMPILERS += copy_files
copy_files.name = COPY
copy_files.input = COPY_FILES
copy_files.CONFIG = no_link
copy_files.output_function = fileCopyDestination
defineReplace(fileCopyDestination) {
return($$shadowed($$1))
}
win32:isEmpty(MINGW_IN_SHELL) {
# Windows shell
copy_files.commands = copy /y ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
TOUCH = copy /y nul
}
else {
# Unix shell
copy_files.commands = mkdir -p `dirname ${QMAKE_FILE_OUT}` && cp ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
TOUCH = touch
}
QMAKE_EXTRA_TARGETS += copy_files_cookie
copy_files_cookie.target = copy_files.cookie
copy_files_cookie.depends = compiler_copy_files_make_all
win32:!mingw {
# NMake/MSBuild
copy_files_cookie.commands = $$TOUCH $** && $$TOUCH [email protected]
}
else {
# GNU Make
copy_files_cookie.commands = $$TOUCH $< && $$TOUCH [email protected]
}
PRE_TARGETDEPS += $${copy_files_cookie.target}
Как это работает
Первая часть определяет дополнительный компилятор , который будет читать входные имена файлов из переменной COPY_FILES
. Следующая часть определяет функцию, которую он будет использовать для синтеза имени выходного файла, соответствующего каждому входу. Затем мы определяем команды, используемые для вызова этого "компилятора", в зависимости от того, в какой оболочке мы находимся.
Затем мы определяем дополнительный файл makefile copy_files.cookie
, который зависит от цели compiler_copy_files_make_all
. Последний - это имя цели, которую qmake генерирует для дополнительного компилятора, который мы определили на первом этапе. Это означает, что когда цель copy_files.cookie
построена, она будет вызывать дополнительный компилятор для копирования файлов.
Мы указываем команду, которая будет выполняться этой целью, которая будет touch
файлами copy_files.cookie
и compiler_copy_files_make_all
. Прикоснувшись к этим файлам, мы гарантируем, что make
не будет пытаться копировать файлы снова, если их временные метки не являются более поздними, чем затронутые файлы. Наконец, мы добавим copy_files.cookie
в список зависимостей цели make all
.
Как использовать его
В вашем .pro
файле добавьте COPY_FILES
в переменную CONFIG
:
CONFIG += copy_files
Затем добавьте файлы в переменную COPY_FILES
:
COPY_FILES += docs/*.txt
Qt 5.6 добавил это как недокументированную особенность:
CONFIG += file_copies
Придумайте имя, чтобы описать файлы, которые вы хотите скопировать:
COPIES += myDocumentation
Перечислите файлы, которые вы хотите скопировать, в .files
:
myDocumentation.files = $$files(text/docs/*.txt)
Укажите целевой путь в .path
:
myDocumentation.path = $$OUT_PWD/documentation
При желании укажите базовый путь, который нужно обрезать из исходных путей:
myDocumentation.base = $$PWD/text/docs
Это в основном работает, делая то же самое, что и многие другие ответы здесь. Смотрите file_copies.prf для подробностей.
Интерфейс очень похож на интерфейс INSTALLS
.
Как дополнение к Jake answer и @Phlucious comment, можно использовать функцию qmake defineReplace
, которая лучше подходит для этого варианта использования. После использования приведенного примера я столкнулся с проблемой, когда qmake пропустил последнее действие ссылки ссылки, которое я добавил. Это может быть проблемой при экспорте переменной, хотя контент выглядел довольно хорошо все время. Короче говоря, здесь есть модифицированный код
defineReplace(copyToDir) {
files = $$1
DIR = $$2
LINK =
for(FILE, files) {
LINK += $$QMAKE_COPY $$shell_path($$FILE) $$shell_path($$DIR) $$escape_expand(\\n\\t)
}
return($$LINK)
}
Эта общая функция копирования может использоваться некоторыми удобными функциями, такими как
defineReplace(copyToBuilddir) {
return($$copyToDir($$1, $$OUT_PWD))
}
Второй принимает только один аргумент (один или несколько файлов) и предоставляет фиксированный путь. В значительной степени то же, что и в ответах на ссылки.
Но теперь обратите внимание на разницу в вызове
QMAKE_POST_LINK += $$copyToBuilddir(deploy.bat)
Как вы можете видеть, вы можете присоединить возвращенную команду к QMAKE_PRE_LINK для еще большей гибкости.
Во-первых, определите где-нибудь ниже (из среды XD
), например, в файле functions.prf
:
# --------------------------------------
# This file defines few useful functions
# --------------------------------------
#copyDir(source, destination)
# using "shell_path()" to correct path depending on platform
# escaping quotes and backslashes for file paths
defineTest(copyDir) {
#append copy command
!isEmpty(xd_copydir.commands): xd_copydir.commands += && \\$$escape_expand(\n\t)
xd_copydir.commands += ( $(COPY_DIR) \"$$shell_path($$1)\" \"$$shell_path($$2)\" || echo \"copy failed\" )
#the qmake generated MakeFile contains "first" and we depend that on "xd_copydir"
first.depends *= xd_copydir
QMAKE_EXTRA_TARGETS *= first xd_copydir
export(first.depends)
export(xd_copydir.commands)
export(QMAKE_EXTRA_TARGETS)
}
#copy(source, destination) (i.e. the name "copyFile" was reserved)
defineTest(copyFile) {
#append copy command
!isEmpty(xd_copyfile.commands): xd_copyfile.commands += && \\$$escape_expand(\n\t)
xd_copyfile.commands += ( $(COPY_FILE) \"$$shell_path($$1)\" \"$$shell_path($$2)\" || echo \"copy failed\" )
#the qmake generated MakeFile contains "first" and we depend that on "xd_copyfile"
first.depends *= xd_copyfile
QMAKE_EXTRA_TARGETS *= first xd_copyfile
export(first.depends)
export(xd_copyfile.commands)
export(QMAKE_EXTRA_TARGETS)
}
и использовать его в своем проекте, как:
include($$PWD/functions.prf) #optional
copyFile($$PWD/myfile1.txt, $$DESTDIR/myfile1.txt)
copyFile($$PWD/README.txt, $$DESTDIR/README.txt)
copyFile($$PWD/LICENSE, $$DESTDIR/LICENSE)
copyDir($$PWD/redist, $$DESTDIR/redist) #copy "redist" folder to "$$DESTDIR"
Обратите внимание, что все файлы будут скопированы до того, как будет выполнена операция связывания (что может быть полезно).
xd_functions.prf
Но когда вам нужно что-то вроде copyFileLater(source, destination)
, чтобы копировать файлы только после завершения сборки, тогда рассмотрите возможность использования приведенного ниже кода (который XD
из фреймворка XD
под Apache 2.0
):
# --------------------------------------
# This file defines few useful functions
# --------------------------------------
xd_command_count = 0
#xd_prebuild(prefix, command)
defineTest(xd_prebuild) {
#generate target name with number
xd_command_count = $$num_add($$xd_command_count, 1)
name = $$1$$xd_command_count
#append command
eval( $${name}.commands += ( \$\$2 ) );
#the qmake generated "MakeFile" should contain "first"
# and we depend that on new command
!contains( first.depends, $$name ) {
!isEmpty(first.depends): first.depends += \\$$escape_expand(\\n)
first.depends += $$name
}
QMAKE_EXTRA_TARGETS *= first $$name
export(xd_command_count)
export($${name}.commands)
export(first.depends)
export(QMAKE_EXTRA_TARGETS)
#eval( warning(xd_push_command: $${name}.commands += \$\${$${name}.commands}) )
}
#xd_postbuild(command)
defineTest(xd_postbuild) {
!isEmpty(QMAKE_POST_LINK): QMAKE_POST_LINK = $$QMAKE_POST_LINK$$escape_expand(\\n\\t)
QMAKE_POST_LINK = $${QMAKE_POST_LINK}$$quote(-$$1)
export(QMAKE_POST_LINK)
}
#xd_escape(path)
# resolves path like built-in functions (i.e. counts input relative to $$PWD)
defineReplace(xd_escape) {
1 = $$absolute_path($$1)
#using "shell_path()" to correct path depending on platform
# escaping quotes and backslashes for file paths
1 = $$shell_path($$1)
return($$quote($$1))
}
#copyFile(source, destination)
# this will both copy and rename "source" to "destination", However like "copy_file()":
# if "destination" is path to existing directory or ends with slash (i.e. "/" or "\\"),
# will just copy to existing "destination" directory without any rename
#
# note: this is executed before build, but after qmake did exit
# so use "copy_file(...)" instead if the output file is required in qmake script
# like for example if "write_file(...)" is called on the output...
defineTest(copyFile) {
#note that "$(COPY_FILE)" is generated by qmake from "$$QMAKE_COPY_FILE"
xd_prebuild(xd_copyfile, $(COPY_FILE) $$xd_escape($$1) $$xd_escape($$2) || echo copyFile-failed)
}
#copyFileLater(source, destination = $(DESTDIR))
# note: this is executed after build is done, hence the name copy-later
defineTest(copyFileLater) {
destDir = $$2
isEmpty(destDir): destDir = $(DESTDIR)
#append copy command
xd_postbuild($(COPY_FILE) $$xd_escape($$1) $$xd_escape($$destDir) || echo copyFileLater-failed)
#!build_pass:warning(copyFile: $$1 to: $$destDir)
}
#copyDir(source, destination)
defineTest(copyDir) {
xd_prebuild(xd_copydir, $(COPY_DIR) $$xd_escape($$1) $$xd_escape($$2) || echo copyDir-failed)
}
#copyDirLater(source, destination = $(DESTDIR))
# note: this is executed after build is done, hence the name copy-later
defineTest(copyDirLater) {
destDir = $$2
isEmpty(destDir): destDir = $(DESTDIR)
#append copy command
xd_postbuild($(COPY_DIR) $$xd_escape($$1) $$xd_escape($$destDir) || echo copyDirLater-failed)
#!build_pass:warning(copyFile: $$1 to: $$destDir)
}
#makeDir(destination)
defineTest(makeDir) {
xd_prebuild(xd_makedir, $(MKDIR) $$xd_escape($$1) || echo makeDir-failed: \"$$1\")
}
defineTest(makeDirLater) {
xd_postbuild( $(MKDIR) $$xd_escape($$1) || echo makeDirLater-failed )
#!build_pass:warning(makeDirLater: $$1)
}
defineTest(deleteFile) {
xd_prebuild(xd_delfile, $(DEL_FILE) $$xd_escape($$1) || echo deleteFile-failed)
}
defineTest(deleteFileLater) {
xd_postbuild( $(DEL_FILE) $$xd_escape($$1) || echo deleteFileLater-failed )
#!build_pass:warning(deleteFileLater: $$1)
}
defineTest(deleteDir) {
xd_prebuild(xd_delfile, $(DEL_DIR) $$xd_escape($$1) || echo deleteDir-failed)
}
defineTest(deleteDirLater) {
xd_postbuild( $(DEL_DIR) $$xd_escape($$1) || echo deleteDirLater-failed )
#!build_pass:warning(deleteFileLater: $$1)
}
#qmakeLater(qmake-script-file-path-to-run)
# note that inside the script runned by this method
# $$OUT_PWD will be same as original $$OUT_PWD of qmakeLater(...) caller project
# since there is the "Makefile" that executes our custom qmake
defineTest(qmakeRun) {
xd_postbuild( $(QMAKE) $$xd_escape($$1) -r -spec \"$$shell_path($$QMAKESPEC)\" )
#!build_pass:warning(qmakeLater: $$1)
}
defineTest(qmakeLater) {
xd_postbuild( $(QMAKE) $$xd_escape($$1) -r -spec \"$$shell_path($$QMAKESPEC)\" )
#!build_pass:warning(qmakeLater: $$1)
}
Во-первых, определите следующие две функции для поддержки Windows/Unix.
defineReplace(nativePath) {
OUT_NATIVE_PATH = $$1
# Replace slashes in paths with backslashes for Windows
win32:OUT_NATIVE_PATH ~= s,/,\\,g
return($$OUT_NATIVE_PATH)
}
# Copies the given files to the destination directory
defineReplace(copyToDestDirCommands) {
variable_files = $$1
files = $$eval($$variable_files)
DDIR = $$nativePath($$2)
win32:DDIR ~= s,/,\\,g
POST_LINK = echo "Copying files to $$DDIR" $$escape_expand(\\n\\t)
win32 {
POST_LINK += $$QMAKE_MKDIR $$quote($$DDIR) 2>&1 & set errorlevel=0 $$escape_expand(\\n\\t)
}
!win32 {
POST_LINK += $$QMAKE_MKDIR -p $$quote($$DDIR) $$escape_expand(\\n\\t)
}
for(ORIGINAL_FILE, files) {
FILE = $$nativePath($$ORIGINAL_FILE)
POST_LINK += $$QMAKE_COPY $$quote($$FILE) $$quote($$DDIR) $$escape_expand(\\n\\t)
}
return ($$POST_LINK)
}
Затем вы можете использовать следующий код для вызова функций, которые были определены ранее, для копирования файлов в определенную папку, а также для создания каталога при необходимости. Это проверено под Win32, тесты Linux приветствуются.
BATOS_FILES = \
$$BATOS_BIN_ROOT/batos-core.dll \
$$BATOS_BIN_ROOT/batos-pfw.dll \
$$BATOS_BIN_ROOT/dre.dll \
$$BATOS_BIN_ROOT/log4qt.dll
QMAKE_POST_LINK += $$copyToDestDirCommands(BATOS_FILES, $$DESTDIR)
BATOS_PLUGINS_FILES = \
$$BATOS_BIN_ROOT/plugins/com.xaf.plugin-manager.dll \
$$BATOS_BIN_ROOT/plugins/org.commontk.eventadmin.dll
QMAKE_POST_LINK += $$copyToDestDirCommands(BATOS_PLUGINS_FILES, $$DESTDIR/plugins)