Unwrapping datatypes в Haskell без постороннего кода

Скажем, у меня

x = Just 2

Есть ли способ (предпочтительнее встроенный механизм/функция) использовать x в одном утверждении, так что если это Just, то 2 автоматически распаковывается и используется, а если это Nothing, возникает исключение?

То есть

(f x) + 2 == 4, если x == Just 2, и вызывает исключение, если x == Nothing.

Ответ 1

Data.Maybe.fromJust уже упоминался другими ответами:

fromJust :: Maybe a -> a
fromJust Nothing  = error "Maybe.fromJust: Nothing"
fromJust (Just x) = x

Здесь также maybe (найденный как в Prelude, так и Data.Maybe):

maybe :: b -> (a -> b) -> Maybe a -> b
maybe n _ Nothing  = n
maybe _ f (Just x) = f x

fromJust можно записать с помощью maybe:

fromJust = maybe (error "Maybe.fromJust: Nothing") id

Как вы можете видеть, maybe позволяет вам гибко управлять обоими случаями, не требуя сопоставления шаблонов:

\x -> maybe 0 (+ 2) x  -- Nothing -> 0, Just 2 -> 4

Аналогично, Prelude и Data.Either имеют either :: (a -> c) -> (b -> c) -> Either a b -> c:

\x -> either (subtract 1) (* 2) x  -- Left 5 -> 4, Right 3 -> 6

Если вы определяете тип данных

data MyDataType
  = TypeA { foo :: Int, bar :: String }
  | TypeB { foo :: Int,                baz :: () }
  | TypeC {             bar :: String, baz :: () }

например, вы получаете частичные функции для аксессуаров.

foo :: MyDataType -> Int
bar :: MyDataType -> String
baz :: MyDataType -> ()

Они называются частичными функциями, в отличие от полных функций, потому что они возвращают результаты только для подмножества их входов.

foo (TypeA { foo = 15, bar = "hello!" })  -- 15
bar (TypeB { foo = 12345679, baz = () })  -- error

Ответ 2

В этом конкретном случае fromJust. В общем

let Just k = x in f k + 2 == 4

Этот трюк работает с любым конструктором типа данных и очень часто используется с (:) для непустых списков.

Ответ 3

fromJust должен делать то, что вы хотите.