Groovy встроенный клиент REST/HTTP?

Ответ 1

Если ваши потребности просты и вы хотите избежать добавления дополнительных зависимостей, вы можете использовать методы getText(), которые Groovy добавляет к классу java.net.URL:

new URL("http://stackoverflow.com").getText()

// or

new URL("http://stackoverflow.com")
        .getText(connectTimeout: 5000, 
                readTimeout: 10000, 
                useCaches: true, 
                allowUserInteraction: false, 
                requestProperties: ['Connection': 'close'])

Если вы ожидаете возвращения двоичных данных, существует также аналогичная функциональность, предоставляемая методами newInputStream().

Ответ 2

Самый простой из них:

def html = "http://google.com".toURL().text

Ответ 3

Нативный Groovy GET и POST

// GET
def get = new URL("https://httpbin.org/get").openConnection();
def getRC = get.getResponseCode();
println(getRC);
if(getRC.equals(200)) {
    println(get.getInputStream().getText());
}

// POST
def post = new URL("https://httpbin.org/post").openConnection();
def message = '{"message":"this is a message"}'
post.setRequestMethod("POST")
post.setDoOutput(true)
post.setRequestProperty("Content-Type", "application/json")
post.getOutputStream().write(message.getBytes("UTF-8"));
def postRC = post.getResponseCode();
println(postRC);
if(postRC.equals(200)) {
    println(post.getInputStream().getText());
}

Ответ 4

HTTPBuilder. Очень прост в использовании.

import groovyx.net.http.HTTPBuilder

def http = new HTTPBuilder('https://google.com')
def html = http.get(path : '/search', query : [q:'waffles'])

Это особенно полезно, если вам нужна обработка ошибок и, как правило, больше функциональности, чем просто выборка контента с помощью GET.

Ответ 5

Я не думаю, что http-builder является модулем Groovy, а скорее внешним API поверх apache http-client поэтому вам нужно импортировать классы и загружать кучу API. Вам лучше использовать Gradle или @Grab для загрузки флага и зависимостей:

@Grab(group='org.codehaus.groovy.modules.http-builder', module='http-builder', version='0.7.1' )
import groovyx.net.http.*
import static groovyx.net.http.ContentType.*
import static groovyx.net.http.Method.*

Примечание. Поскольку сайт CodeHaus опустился, вы можете найти JAR в (https://mvnrepository.com/artifact/org.codehaus.groovy.modules.http-builder/http-builder)

Ответ 6

import groovyx.net.http.HTTPBuilder;

public class HttpclassgetrRoles {
     static void main(String[] args){
         def baseUrl = new URL('http://test.city.com/api/Cirtxyz/GetUser')

         HttpURLConnection connection = (HttpURLConnection) baseUrl.openConnection();
         connection.addRequestProperty("Accept", "application/json")
         connection.with {
           doOutput = true
           requestMethod = 'GET'
           println content.text
         }

     }
}

Ответ 7

Вы можете использовать функции Groovy, такие как(), улучшения в URLConnection и упрощенные геттеры/сеттеры:

GET

String getResult = new URL('http://mytestsite/bloop').text

POST

String postResult
((HttpURLConnection)new URL('http://mytestsite/bloop').openConnection()).with({
    requestMethod = 'POST'
    doOutput = true
    setRequestProperty('Content-Type', '...') // Set your content type.
    outputStream.withPrintWriter({printWriter ->
        printWriter.write('...') // Your post data. Could also use withWriter() if you don't want to write a String.
    })
    // Can check 'responseCode' here if you like.
    postResult = inputStream.text // Using 'inputStream.text' because 'content' will throw an exception when empty.
})

Примечание. POST начнется, когда вы попытаетесь прочитать значение из HttpURLConnection, например responseCode, inputStream.text или getHeaderField('...').