Как читать содержимое каталога в Perl?

Ответ 1

opendir(D, "/path/to/directory") || die "Can't open directory: $!\n";
while (my $f = readdir(D)) {
    print "\$f = $f\n";
}
closedir(D);

EDIT: О, извините, пропустил часть "в массив":

my $d = shift;

opendir(D, "$d") || die "Can't open directory $d: $!\n";
my @list = readdir(D);
closedir(D);

foreach my $f (@list) {
    print "\$f = $f\n";
}

EDIT2: Большинство других ответов действительно, но я хотел бы прокомментировать этот ответ, в котором предлагается это решение:

opendir(DIR, $somedir) || die "Can't open directory $somedir: $!";
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR);
closedir DIR;

Во-первых, для документирования того, что он делает после того, как плакат не выполнил: он передал возвращаемый список из readdir() через grep(), который возвращает только те значения, которые являются файлами (в отличие от каталогов, устройств, именованных каналов и т.д.) и которые не начинаются с точки ( что делает имя списка @dots вводящим в заблуждение, но из-за изменения, которое он сделал при копировании из документации readdir()). Поскольку он ограничивает содержимое возвращаемого каталога, я не думаю, что это технически правильный ответ на этот вопрос, но он иллюстрирует общую идиому, используемую для фильтрации имен файлов в Perl, и я подумал, что было бы полезно документировать. Еще один пример:

@list = grep !/^\.\.?$/, readdir(D);

Этот фрагмент читает все содержимое из дескриптора каталога D кроме '.' и "..", поскольку они очень редко желательны для использования в листинге.

Ответ 2

Быстрое и грязное решение - использовать glob

@files = glob ('/path/to/dir/*');

Ответ 3

IO:: Dir хорош и предоставляет связанный хэш-интерфейс.

Из perldoc:

use IO::Dir;
$d = IO::Dir->new(".");
if (defined $d) {
    while (defined($_ = $d->read)) { something($_); }
    $d->rewind;
    while (defined($_ = $d->read)) { something_else($_); }
    undef $d;
}

tie %dir, 'IO::Dir', ".";
foreach (keys %dir) {
    print $_, " " , $dir{$_}->size,"\n";
}

Итак, вы можете сделать что-то вроде:

tie %dir, 'IO::Dir', $directory_name;
my @dirs = keys %dir;

Ответ 4

Это будет сделано в одной строке (обратите внимание на подстановочный знак '*' в конце)

@files = </path/to/directory/*>;
# To demonstrate:
print join(", ", @files);

Ответ 5

Вы можете использовать DirHandle:

use DirHandle;
$d = new DirHandle ".";
if (defined $d)
{
    while (defined($_ = $d->read)) { something($_); }
    $d->rewind;
    while (defined($_ = $d->read)) { something_else($_); }
    undef $d;
}

DirHandle предоставляет альтернативный, более чистый интерфейс для функций opendir(), closedir(), readdir() и rewinddir().

Ответ 6

Вот пример рекурсии через структуру каталогов и копирование файлов из резервной копии script. Я написал.

sub copy_directory {
my ($source, $dest) = @_;
my $start = time;

# get the contents of the directory.
opendir(D, $source);
my @f = readdir(D);
closedir(D);

# recurse through the directory structure and copy files.
foreach my $file (@f) {
    # Setup the full path to the source and dest files.
    my $filename = $source . "\\" . $file;
    my $destfile = $dest . "\\" . $file;

    # get the file info for the 2 files.
    my $sourceInfo = stat( $filename );
    my $destInfo = stat( $destfile );

    # make sure the destinatin directory exists.
    mkdir( $dest, 0777 );

    if ($file eq '.' || $file eq '..') {
    } elsif (-d $filename) { # if it a directory then recurse into it.
        #print "entering $filename\n";
        copy_directory($filename, $destfile); 
    } else { 
        # Only backup the file if it has been created/modified since the last backup 
        if( (not -e $destfile) || ($sourceInfo->mtime > $destInfo->mtime ) ) {
            #print $filename . " -> " . $destfile . "\n";
            copy( $filename, $destfile ) or print "Error copying $filename: $!\n";
        } 
    } 
}

print "$source copied in " . (time - $start) . " seconds.\n";       
}

Ответ 7

Как и выше, но я думаю, что лучшая версия (слегка измененная) от "perldoc -f readdir":

opendir(DIR, $somedir) || die "can't opendir $somedir: $!";
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR);
closedir DIR;

Ответ 8

from: http://perlmeme.org/faqs/file_io/directory_listing.html

#!/usr/bin/perl
use strict;
use warnings;

my $directory = '/tmp';

opendir (DIR, $directory) or die $!;

while (my $file = readdir(DIR)) {
    next if ($file =~ m/^\./);
    print "$file\n";
}

Следующий пример (на основе образца кода из perldoc -f readdir) получает все файлы (не каталоги), начинающиеся с периода из открытого каталога. Имена файлов находятся в массиве @dots.

#!/usr/bin/perl

use strict;
use warnings;

my $dir = '/tmp';

opendir(DIR, $dir) or die $!;

my @dots 
    = grep { 
        /^\./             # Begins with a period
    && -f "$dir/$_"   # and is a file
} readdir(DIR);

# Loop through the array printing out the filenames
foreach my $file (@dots) {
    print "$file\n";
}

closedir(DIR);
exit 0;


closedir(DIR);
exit 0;