Подтвердить что ты не робот

Несколько каталогов под cmake

В настоящее время я использую рекурсивный make и autotools, и я хочу перейти на CMake для проекта, который выглядит примерно так:

lx/ (project root)
    src/
        lx.c (contains main method)
        conf.c
        util/
            str.c
            str.h
            etc.c
            etc.h
        server/
            server.c
            server.h
            request.c
            request.h
        js/
            js.c
            js.h
            interp.c
            interp.h
    bin/
        lx (executable)

Как мне это сделать?

Ответ 1

Если никогда не существует источника, превышающего каталог lx/src, тогда нет необходимости в файле lx/CMakeLists.txt. Если есть, он должен выглядеть примерно так:

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(lx)

add_subdirectory(src)
add_subdirectory(dir1)
add_subdirectory(dir2)

# And possibly other commands dealing with things
# directly in the "lx" directory

... где подкаталоги добавляются в порядок зависимостей библиотеки. Сначала должны быть добавлены библиотеки, которые не зависят ни от чего другого, а затем от библиотек, которые зависят от них, и т.д.

лк /SRC/CMakeLists.txt

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(lx_exe)

add_subdirectory(util)
add_subdirectory(js)
add_subdirectory(server)

set(lx_source_files conf.c lx.c)
add_executable(lx ${lx_source_files})

target_link_libraries(lx server)
  # also transitively gets the "js" and "util" dependencies

лк /SRC/Util/CMakeLists.txt

set(util_source_files
  etc.c
  etc.h
  str.c
  str.h
)
add_library(util ${util_source_files})

лк /SRC/JS/CMakeLists.txt

set(js_source_files
  interp.c
  interp.h
  js.c
  js.h
)
add_library(js ${js_source_files})

target_link_libraries(js util)

лк/SRC/сервер/CMakeLists.txt

set(server_source_files
  request.c
  request.h
  server.c
  server.h
)
add_library(server ${server_source_files})

target_link_libraries(server js)
  # also transitively gets the "util" dependency

Затем в командной строке:

mkdir lx/bin
cd lx/bin

cmake ..
  # or "cmake ../src" if the top level
  # CMakeLists.txt is in lx/src

make

По умолчанию исполняемый файл lx окажется в каталоге "lx/bin/src", используя этот точный макет. Вы можете управлять тем каталогом, в котором он находится, используя свойство цели RUNTIME_OUTPUT_DIRECTORY и команду set_property.

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#prop_tgt:RUNTIME_OUTPUT_DIRECTORY

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#command:set_property

Обратитесь к файлам target_link_libraries либо с помощью целевого имени CMake, если lib построен как цель CMake через add_library, либо в противном случае полный путь к файлу библиотеки.

См. также вывод "cmake -help-command target_link_libraries" или любую другую команду cmake и полную онлайн-документацию для команд cmake, найденных здесь:

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#section_Commands

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#command:target_link_libraries