Как позволить вкладке отображать только имя файла, а не полный путь в vim

Если полный путь к файлу очень длинный, вы не можете определить, какой файл находится на данной вкладке. поэтому мне интересно, есть ли способ, чтобы вкладка ограничивала только имя файла, а не полный путь файла, может быть удобным в некоторых случаях. вам нужно помочь, спасибо заранее.

Ответ 1

Try

:set guitablabel=%t

Для формата возможных параметров см.

: help 'statusline'

Ответ 2

В моем vimrc есть следующее:

set guitablabel=\[%N\]\ %t\ %M

который выводит: [Number] Имя файла и знак +, если файл изменен ([4] foo.html +). Номер очень полезен для немедленного переключения на выбранную вкладку с помощью команды [Number] gt ( 4gt, если я хочу перейти к файлу на вкладке 4)

Ответ 3

Я использую это решение вместо Habi, поскольку он по-прежнему сохраняет функции по умолчанию, помещая символ "+" на вкладке, чтобы указать файлы, которые были изменены, а также количество номеров окон на вкладке. Таким образом, он в основном работает так же, как и пометка по умолчанию, но просто использует имена файлов, а не полные пути.

" Tab headings
function GuiTabLabel()
    let label = ''
    let bufnrlist = tabpagebuflist(v:lnum)

    " Add '+' if one of the buffers in the tab page is modified
    for bufnr in bufnrlist
        if getbufvar(bufnr, "&modified")
            let label = '+'
            break
        endif
    endfor

    " Append the number of windows in the tab page if more than one
    let wincount = tabpagewinnr(v:lnum, '$')
    if wincount > 1
        let label .= wincount
    endif
    if label != ''
        let label .= ' '
    endif

    " Append the buffer name (not full path)
    return label . "%t"
endfunction

set guitablabel=%!GuiTabLabel()