Я хотел бы узнать, какую версию исполняемого файла использует оболочка CMD. В любой оболочке unix я бы использовал which
, чтобы найти ее.
Есть ли эквивалентная команда в одной из оболочек Windows?
Я хотел бы узнать, какую версию исполняемого файла использует оболочка CMD. В любой оболочке unix я бы использовал which
, чтобы найти ее.
Есть ли эквивалентная команда в одной из оболочек Windows?
разн.
where
является прямым эквивалентом:
C:\Users\Joey>where cmd
C:\Windows\System32\cmd.exe
Обратите внимание, что в PowerShell where
сам по себе является псевдонимом для Where-Object
, поэтому вам нужно использовать where.exe
в PowerShell.
В cmd
вы также можете использовать for
:
C:\Users\Joey>for %x in (powershell.exe) do @echo %~$PATH:x
C:\Windows\System32\WindowsPowerShell\v1.0\powershell.exe
В PowerShell у вас есть Get-Command
и его псевдоним gcm
, который делает то же самое, если вы передаете аргумент (но также работает для псевдонимов, командлетов и функций в PowerShell):
PS C:\Users\Joey> Get-Command where
CommandType Name Definition
----------- ---- ----------
Alias where Where-Object
Application where.exe C:\Windows\system32\where.exe
Первая возвращенная команда - это та, которая будет выполнена.
Команда WHERE
не совсем такая же, как unix which
, потому что в ней перечислены все совпадающие файлы, найденные в текущем каталоге или PATH. Как говорит Джоуи, первый из них - тот, который выполняется. Просто создать пакет script, который вернет только первый найденный.
@echo off
for /f "delims=" %%F in ('where %1') do (
echo %%F
exit /b
)
Но WHERE
относительно медленный.
Ниже WHICH.BAT script работает быстрее и делает немного больше. Он использует обширное замедленное расширение, потому что: 1) Расширение% PATH% является ненадежным, если есть некотируемые специальные символы. 2) Расширение переменных FOR при замедленном расширении позволяет развращать значения, содержащие !
.
::WHICH.BAT CommandName [ReturnVar]
::
:: Determines the full path of the file that would execute if
:: CommandName were executed.
::
:: The result is stored in variable ReturnVar, or else it is
:: echoed to stdout if ReturnVar is not specified.
::
:: If no file is found, then an error message is echoed to stderr.
::
:: The ERRORLEVEL is set to one of the following values
:: 0 - Success: A matching file was found
:: 1 - CommandName is an internal command
:: 2 - No file was found and CommandName is not an internal command
:: 3 - Improper syntax - no CommandName specified
::
@echo off
setlocal disableDelayedExpansion
set "file=%~1"
setlocal enableDelayedExpansion
if not defined file (
>&2 echo Syntax error: No CommandName specified
exit /b 3
)
:: test for internal command
echo(!file!|findstr /i "[^abcdefghijklmnopqrstuvwxyz]" >nul || (
set "empty=!temp!\emptyFolder"
md "!empty!" 2>nul
del /q "!empty!\*" 2>nul >nul
setlocal
pushd "!empty!"
set path=
(call )
!file! /? >nul 2>nul
if not errorlevel 9009 (
>&2 echo "!file!" is an internal command
popd
exit /b 1
)
popd
endlocal
)
:: test for external command
set "noExt="
if "%~x1" neq "" if "!PATHEXT:%~x1=!" neq "!PATHEXT!" set noExt="";
set "modpath=.\;!PATH!"
@for %%E in (%noExt%%PATHEXT%) do @for %%F in ("!file!%%~E") do (
setlocal disableDelayedExpansion
if not "%%~$modpath:F"=="" if not exist "%%~$modpath:F\" (
endlocal & endlocal & endlocal
if "%~2"=="" (echo %%~$modpath:F) else set "%~2=%%~$modpath:F"
exit /b 0
)
endlocal
)
endlocal
>&2 echo "%~1" is not a valid command
exit /b 2
UPDATE
Мне пришлось значительно изменить приведенный выше script, потому что было неверно отображать внутреннюю команду как внешнюю, если там существовал exe файл с тем же корневым именем где-то в PATH.