Почему CharInSet быстрее, чем оператор Case?

Ответ 1

AQTime - инструмент для профилирования. Инструментальные профилографы часто не подходят для измерения времени кода, особенно в микрообъектах, подобных вашим, поскольку стоимость инструментария часто перевешивает стоимость измеряемой вещи. Инструментальные профилирующие устройства, с другой стороны, преуспевают в профилировании памяти и других ресурсах.

Пробоотборники пробоотбора, которые периодически проверяют местоположение ЦП, обычно лучше для измерения времени кода.

В любом случае, здесь еще один микрообъект, который действительно показывает, что оператор case работает быстрее, чем CharInSet. Однако обратите внимание, что проверка набора еще может использоваться с типом, чтобы исключить предупреждение об усечении (на самом деле это единственная причина, по которой CharInSet существует):

{$apptype console}

uses Windows, SysUtils;

const
  SampleString = 'foo bar baz blah de;blah de blah.';

procedure P1;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while not CharInSet(cp^, [#0, ';', '.']) do
    Inc(cp);
end;

procedure P2;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while True do
    case cp^ of
      '.', #0, ';':
        Break;
    else
      Inc(cp);
    end;
end;

procedure P3;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while not (AnsiChar(cp^) in [#0, ';', '.']) do
    Inc(cp);
end;

procedure Time(const Title: string; Proc: TProc);
var
  i: Integer;
  start, finish, freq: Int64;
begin
  QueryPerformanceCounter(start);
  for i := 1 to 1000000 do
    Proc;
  QueryPerformanceCounter(finish);
  QueryPerformanceFrequency(freq);
  Writeln(Format('%20s: %.3f seconds', [Title, (finish - start) / freq]));
end;

begin
  Time('CharInSet', P1);
  Time('case stmt', P2);
  Time('set test', P3);
end.

Его вывод на моем ноутбуке:

CharInSet: 0.261 seconds
case stmt: 0.077 seconds
 set test: 0.060 seconds

Ответ 2

Барри, я хотел бы указать, что ваш тест не отражает фактическую производительность различных методов, потому что структура реализаций отличается. Вместо этого все методы должны использовать конструкцию "while True do", чтобы лучше отражать влияние различных способов выполнения проверки char -in-set.

Здесь замена тестовых методов (P2 не изменилась, P1 и P3 теперь используют конструкцию "while True do" ):

procedure P1;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while True do
    if CharInSet(cp^, [#0, ';', '.']) then
      Break
    else
      Inc(cp);
end;

procedure P2;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while True do
    case cp^ of
      '.', #0, ';':
        Break;
    else
      Inc(cp);
    end;
end;

procedure P3;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while True do
    if AnsiChar(cp^) in [#0, ';', '.'] then
      Break
    else
      Inc(cp);
end;

Моя рабочая станция дает:

CharInSet: 0.099 seconds
case stmt: 0.043 seconds
 set test: 0.043 seconds

Что лучше соответствует ожидаемым результатам. Мне кажется, что использование конструкции "case in" на самом деле не помогает. Извините, Марко!

Ответ 3

Здесь можно найти бесплатный пробоотборник для Delphi:

https://forums.codegear.com/thread.jspa?messageID=18506

Помимо вопроса о некорректном измерении времени инструментальных профилографов, следует отметить, что ускорение будет также зависеть от того, насколько предсказуемы ветки "случая". Если тесты в "случае" имеют сходную вероятность столкновения, производительность "case" может оказаться ниже, чем у CharInSet.

Ответ 4

Код в функции "CharInSet" быстрее, чем "случай", время тратится на "вызов", использование  а не (cp ^ в [..]), то

вы увидите, что это голодание.

Ответ 5

Как я знаю, вызов принимает такое же количество операций процессора, как и переход, если они оба используют короткие указатели. С длинными указателями могут быть разные. Вызов в ассемблере по умолчанию не использует стек. Если имеется достаточно свободных регистров, используйте регистр. Таким образом, операции стека также занимают нулевое время. Это просто реестры, которые очень быстры.

В отличие от варианта варианта, как я вижу, используются дополнительные и вспомогательные операции, которые довольно медленны и, вероятно, добавляют большую часть extratime.