Как я могу анализировать даты и преобразовывать часовые пояса в Perl?

Ответ 1

Поскольку интерфейсы Perl, построенные на интерфейсах обработки данных, являются неудобными, и вы обходите около полутора десятков переменных, лучший способ - использовать DateTime или Time::Piece. DateTime - это всепоглощающий, полностью танцующий объект даты Perl, и вы, вероятно, в конце концов захотите его использовать, но Time:: Piece является более простым и вполне адекватным для этой задачи, имеет преимущество доставки с 5.10, и эта техника в основном то же самое для обоих.

Вот простой, гибкий способ использования Time:: Piece и strptime.

#!/usr/bin/perl

use 5.10.0;

use strict;
use warnings;

use Time::Piece;

# Read the date from the command line.
my $date = shift;

# Parse the date using strptime(), which uses strftime() formats.
my $time = Time::Piece->strptime($date, "%Y%m%d %H:%M");

# Here it is, parsed but still in GMT.
say $time->datetime;

# Create a localtime object for the same timestamp.
$time = localtime($time->epoch);

# And here it is localized.
say $time->datetime;

И здесь, наоборот, для контраста.

Поскольку формат фиксирован, регулярное выражение будет прекрасно, но если формат изменится, вам придется подстроить регулярное выражение.

my($year, $mon, $day, $hour, $min) = 
    $date =~ /^(\d{4}) (\d{2}) (\d{2})\ (\d{2}):(\d{2})$/x;

Затем преобразуйте его в эпоху Unix (секунды с 1 января 1970 года)

use Time::Local;
# Note that all the internal Perl date handling functions take month
# from 0 and the year starting at 1900.  Blame C (or blame Larry for
# parroting C).
my $time = timegm(0, $min, $hour, $day, $mon - 1, $year - 1900);

Затем вернитесь в свое местное время.

(undef, $min, $hour, $day, $mon, $year) = localtime($time);

my $local_date = sprintf "%d%02d%02d %02d:%02d\n",
    $year + 1900, $mon + 1, $day, $hour, $min;

Ответ 2

Вот пример, используя DateTime и strptime.

use DateTime;
use DateTime::Format::Strptime;

my $val = "20090103 12:00";

my $format = new DateTime::Format::Strptime(
                pattern => '%Y%m%d %H:%M',
                time_zone => 'GMT',
                );

my $date = $format->parse_datetime($val);

print $date->strftime("%Y%m%d %H:%M %Z")."\n";

$date->set_time_zone("America/New_York");  # or "local"

print $date->strftime("%Y%m%d %H:%M %Z")."\n";

$ perl dates.pl
20090103 12:00 UTC
20090103 07:00 EST

use DateTime;

my @time = (localtime);

my $date = DateTime->new(year => $time[5]+1900, month => $time[4]+1,
                day => $time[3], hour => $time[2], minute => $time[1],
                second => $time[0], time_zone => "America/New_York");

print $date->strftime("%F %r %Z")."\n";

$date->set_time_zone("Europe/Prague");

print $date->strftime("%F %r %Z")."\n";

Ответ 3

Что бы я сделал...

#!/usr/bin/perl
use Date::Parse;
use POSIX;

$orig = "20090103 12:00";

print strftime("%Y%m%d %R", localtime(str2time($orig, 'GMT')));

Вы также можете использовать Time::ParseDate и parsedate() вместо Date::Parse и str2time(). Обратите внимание, что фактический стандарт atm. похоже, DateTime (но вы можете не использовать синтаксис OO для преобразования временной метки).

Ответ 4

Сделайте выбор:

• DateTime:: * (в качестве альтернативы, datetime.perl.org)
• Date::Manip
• Date::Calc (последнее обновление в 2004 году)

Есть миллионы других, без сомнения, но они, вероятно, являются главными соперниками.

Ответ 5

use strict;
use warnings;
my ($sec,$min,$hour,$day,$month,$year)=localtime();
$year+=1900;
$month+=1;
$today_time = sprintf("%02d-%02d-%04d %02d:%02d:%02d",$day,$month,$year,$hour,$min,$sec);
print $today_time;