Groovy загрузить .csv файлы

Ответ 1

Существуют как всегда разные возможности работы с CSV файлами в Groovy.

Поскольку Groovy полностью совместим с Java, вы можете использовать одну из существующих libararies CSV, например. OpenCSV.

В зависимости от сложности используемого CSV файла вы также можете использовать стандартные возможности обработки файлов/строк Groovy:

def sql = Sql.newInstance("jdbc:mysql://localhost:3306/mydb",
  "user", "pswd", "com.mysql.jdbc.Driver")
def people = sql.dataSet("PERSON")
new File("users.csv").splitEachLine(",") {fields ->
  people.add(
    first_name: fields[0],
    last_name: fields[1],
    email: fields[2]
  )
}

EDIT: Келли Робинсон просто написал хорошее сообщение о различных возможностях, доступных для работы с файлами CSV в Groovy.

РЕДАКТИРОВАТЬ № 2: Как недавно Леонард Аксельссон недавно выпустил версию 1.0 своей библиотеки GroovyCVS, я подумал, что обязательно должен добавить это в список параметров.

Ответ 2

Использование xlson GroovyCSV:

@Grab('com.xlson.groovycsv:groovycsv:1.1')
import static com.xlson.groovycsv.CsvParser.parseCsv

for(line in parseCsv(new FileReader('countries.csv'), separator: ';')) {
    println "Country=$line.COUNTRY, Capital=$line.CAPITAL"
}

Имена полей взяты из заголовка файла CSV.
Если файл CSV не имеет заголовка, вы можете указать имена полей программно.

Ответ 3

С Apache Commons-CSV:

@Grab('org.apache.commons:commons-csv:1.2')
import org.apache.commons.csv.CSVParser
import static org.apache.commons.csv.CSVFormat.*

import java.nio.file.Paths

Paths.get('countryInfo.txt').withReader { reader ->
    CSVParser csv = new CSVParser(reader, DEFAULT.withHeader())

    for (record in csv.iterator()) {
        println record.dump()
    }
}

У Commons-CSV есть хороший API, и я рекомендую это.

С GroovyCSV:

@Grab('com.xlson.groovycsv:groovycsv:0.2')
import com.xlson.groovycsv.CsvParser

def csv = '''Name,Lastname
Mark,Andersson
Pete,Hansen'''

def data = new CsvParser().parse(csv)
for(line in data) {
    println "$line.Name $line.Lastname"
}

(Взяты из него образцы)

В крайнем случае: регулярное выражение.

Вот как я проанализировал файл, который может содержать экранированную строку в кавычках в четвертом столбце:

    File detailedStatsFile = new File("stats.csv");
    detailedStatsFile.eachLine { line, number ->
        // Number Of Executions, Total Milliseconds, Milliseconds per execution, "Type"
        def match = line =~ /([^,]*?),\s*([^,]*?),\s*([^,]*?),\s*(?:([^",]+)|(?:"((?:[^\\"]++(?:\\")?)++)"))$/; //"

        if (!match.matches())
            continue;

        def numberOfExecs = Integer.valueOf(match.group(1));
        def totalMillis = Integer.valueOf(match.group(2));
        def detailedStatName = match.group(4);
        if (detailedStatName == null)
            detailedStatName = match.group(5).replaceAll('\\"','"');

Ответ 4

Пример использования opencsv

@Grab('com.opencsv:opencsv:4.0')
import com.opencsv.CSVReader
import com.opencsv.CSVWriter

class TestCsvReader {


    static main(args) {
        def csv = '''"a","b","c"
"d","e","f"
'''
        def Reader csvFileReader = new StringReader(csv)
        def Writer csvFileWriter = new PrintWriter(System.out)
        def CSVReader reader = new CSVReader(csvFileReader)
        def CSVWriter writer = new CSVWriter(csvFileWriter)

        reader.iterator().each { fields ->
            writer.writeNext(fields)
        }
        reader.close()
        writer.close()
    }
}

Ответ 5

Я предпочитаю немного изменить принятый ответ: объединить столбцы и значения вместе, а не индексировать каждый по номеру. В результате код немного короче.

def sql = Sql.newInstance("jdbc:mysql://localhost:3306/mydb", "user", "pswd", "com.mysql.jdbc.Driver")
def people = sql.dataSet("PERSON")
def columns = ['first_name', 'last_name', 'email']
new File("users.csv").splitEachLine(",") {values ->
    people.add([columns, values].transpose().collectEntries())
}