Ответ 1

Прежде всего, это не имеет ничего общего с дженериками, но гораздо чаще проявляется при использовании дженериков. Оказывается, ошибка переполнения буфера в TControl.CreateParams. Если вы посмотрите на код, вы заметите, что он заполняет структуру TCreateParams, и особенно важно, он заполняет TCreateParams.WinClassName именем текущего класса (ClassName). К сожалению, WinClassName - буфер фиксированной длины только 64 char, но для этого нужно включить NULL-терминатор; так что 64 char long ClassName будет переполнять этот буфер!

Он может быть протестирован с помощью этого кода:

TLongWinControlClassName4567890123456789012345678901234567891234 = class(TWinControl)
end;

procedure TForm3.Button1Click(Sender: TObject);
begin
  with TLongWinControlClassName4567890123456789012345678901234567891234.Create(Self) do
  begin
    Parent := Self;
  end;
end;

Это имя класса составляет ровно 64 символа. Сделайте его одним символом короче и ошибка исчезнет!

Это намного чаще происходит при использовании дженериков из-за того, как Delphi создает ClassName: он включает имя единицы, где объявлен тип параметра, а также точку, а затем имя типа параметра. Например, класс TWinControl<TWinControl, TWinControl, TWinControl> имеет следующее ClassName:

TWinControl<Controls.TWinControl,Controls.TWinControl,Controls.TWinControl>

Этот символ 75 длинный, над пределом 63.

Обход

Я принял простое сообщение об ошибке из потенциально-генерирующего ошибки класса. Что-то вроде этого, от конструктора:

constructor TWinControl<T, K, W>.Create(aOwner: TComponent);
begin
  {$IFOPT D+}
  if Length(ClassName) > 63 then raise Exception.Create('The resulting ClassName is too    long: ' + ClassName);
  {$ENDIF}
  inherited;
end;

По крайней мере, это показывает достойное сообщение об ошибке, на которое можно немедленно действовать.

Позднее Edit, True Обходное решение

Предыдущее решение (повышение ошибки) отлично работает для не-универсального класса, который имеет очень длинное имя; Вероятно, можно было бы укоротить его, сделать его 63 символами или меньше. Это не относится к родовым типам: я столкнулся с этой проблемой с потомком TWinControl, который взял 2 типа параметров, поэтому он имел форму:

TMyControlName<Type1, Type2>

Gnerate ClassName для конкретного типа, основанного на этом родовом типе, имеет вид:

TMyControlName<UnitName1.Type1,UnitName2.Type2>

поэтому он включает в себя 5 идентификаторов (идентификатор 2-х идентификаторов + 3x-типа) + 5 символов (<.,.>); Средняя длина этих 5 идентификаторов должна быть меньше 12 символов каждый, или общая длина превышает 63: 5x12 + 5 = 65. Использование только 11-12 символов для идентификатора очень мало и идет вразрез с лучшими практиками (то есть: используйте длинные описательные имена, потому что нажатия клавиш бесплатны!). Опять же, в моем случае, я просто не мог сделать мои идентификаторы короткими.

Учитывая, что сокращение ClassName не всегда возможно, я решил, что попытаюсь устранить причину проблемы (переполнение буфера). К сожалению, это очень сложно, потому что ошибка исходит из TWinControl.CreateParams, в нижней части иерархии CreateParams. Мы не можем вызывать inherited, потому что CreateParams используется по цепочке наследования для создания параметров создания окна. Не вызывая этого, потребуется дублировать весь код в базе TWinControl.CreateParams PLUS весь код в промежуточных классах; Это также не было бы очень переносимым, поскольку любой из этих кодов мог бы измениться с будущими версиями VCL (или будущей версией сторонних элементов управления, которые мы могли бы подклассифицировать).

Следующее решение не останавливает TWinControl.CreateParams от переполнения буфера, но делает его безвредным, а затем (когда возвращается вызов inherited) устраняет проблему. Я использую новую запись (поэтому у меня есть контроль над макетом), который включает в себя оригинальный TCreateParams, но накладывает на него много места для TWinControl.CreateParams для переполнения. TWinControl.CreateParams переполняет все, что он хочет, затем я читаю полный текст и делаю так, чтобы он соответствовал исходным границам записи, также убедившись, что получившееся сокращенное имя будет уникальным. Я включаю HASH исходного ClassName в WndName, чтобы помочь с проблемой уникальности:

type
  TWrappedCreateParamsRecord = record
    Orignial: TCreateParams;
    SpaceForCreateParamsToSafelyOverflow: array[0..2047] of Char;
  end;

procedure TExtraExtraLongWinControlDescendantClassName_0123456789_0123456789_0123456789_0123456789.CreateParams(var Params: TCreateParams);
var Wrapp: TWrappedCreateParamsRecord;
    Hashcode: Integer;
    HashStr: string;
begin
  // Do I need to take special care?
  if Length(ClassName) >= Length(Params.WinClassName) then
    begin
      // Letting the code go through will cause an Access Violation because of the
      // Buffer Overflow in TWinControl.CreateParams; Yet we do need to let the
      // inherited call go through, or else parent classes don't get the chance
      // to manipulate the Params structure. Since we can't fix the root cause (we
      // can't stop TWinControl.CreateParams from overflowing), let make sure the
      // overflow will be harmless.
      ZeroMemory(@Wrapp, SizeOf(Wrapp));
      Move(Params, Wrapp.Orignial, SizeOf(TCreateParams));
      // Call the original CreateParams; It'll still overflow, but it'll probably be hurmless since we just
      // padded the orginal data structure with a substantial ammount of space.
      inherited CreateParams(Wrapp.Orignial);
      // The data needs to move back into the "Params" structure, but before we can do that
      // we should FIX the overflown buffer. We can't simply trunc it to 64, and we don't want
      // the overhead of keeping track of all the variants of this class we might encounter.
      // Note: Think of GENERIC classes, where you write this code once, but there might
      // be many-many different ClassNames at runtime!
      //
      // My idea is to FIX this by keeping as much of the original name as possible, but
      // including the HASH value of the full name into the window name; If the HASH function
      // is any good then the resulting name as a very high probability of being Unique. We'll
      // use the default Hash function used for Delphi generics.
      HashCode := TEqualityComparer<string>.Default.GetHashCode(PChar(@Wrapp.Orignial.WinClassName));
      HashStr := IntToHex(HashCode, 8);
      Move(HashStr[1], Wrapp.Orignial.WinClassName[High(Wrapp.Orignial.WinClassName)-8], 8*SizeOf(Char));
      Wrapp.Orignial.WinClassName[High(Wrapp.Orignial.WinClassName)] := #0;
      // Move the TCreateParams record back were we've got it from
      Move(Wrapp.Orignial, Params, SizeOf(TCreateParams));
    end
  else
    inherited;
end;