Задержки времени в VBA

Ответ 1

Я использую эту небольшую функцию для VBA.

Public Function Pause(NumberOfSeconds As Variant)
    On Error GoTo Error_GoTo

    Dim PauseTime As Variant
    Dim Start As Variant
    Dim Elapsed As Variant

    PauseTime = NumberOfSeconds
    Start = Timer
    Elapsed = 0
    Do While Timer < Start + PauseTime
        Elapsed = Elapsed + 1
        If Timer = 0 Then
            ' Crossing midnight
            PauseTime = PauseTime - Elapsed
            Start = 0
            Elapsed = 0
        End If
        DoEvents
    Loop

Exit_GoTo:
    On Error GoTo 0
    Exit Function
Error_GoTo:
    Debug.Print Err.Number, Err.Description, Erl
    GoTo Exit_GoTo
End Function

Ответ 2

Если вы находитесь в Excel VBA, вы можете использовать следующее.

Application.Wait(Now + TimeValue("0:00:01"))

(Строка времени должна выглядеть так: H: MM: SS.)

Ответ 3

Вы можете скопировать это в модуль:

Sub WaitFor(NumOfSeconds As Long)
Dim SngSec as Long
SngSec=Timer + NumOfSeconds

Do while timer < sngsec
DoEvents
Loop

End sub

и всякий раз, когда вы хотите применить паузу, напишите:

Call WaitFor(1)

Я надеюсь, что это поможет!

Ответ 4

Вы пытались использовать Sleep?

Вот пример ЗДЕСЬ (скопировано ниже):

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Private Sub Form_Activate()    

frmSplash.Show
DoEvents
Sleep 1000
Unload Me
frmProfiles.Show

End Sub

Обратите внимание, что это может заморозить приложение в течение выбранного времени.

Ответ 5

Доступ всегда может использовать процедуру Excel, если в проекте есть объект Microsoft Excel XX.X ссылка включена:

Call Excel.Application.Wait(DateAdd("s",10,Now()))

Ответ 6

Другой вариант ответа Стива Мэллориеса, я специально нуждался в превосходстве, чтобы убежать и делать что-то в ожидании, а 1 секунда слишком длинная.

'Wait for the specified number of milliseconds while processing the message pump
'This allows excel to catch up on background operations
Sub WaitFor(milliseconds As Single)

    Dim finish As Single
    Dim days As Integer

    'Timer is the number of seconds since midnight (as a single)
    finish = Timer + (milliseconds / 1000)
    'If we are near midnight (or specify a very long time!) then finish could be
    'greater than the maximum possible value of timer. Bring it down to sensible
    'levels and count the number of midnights
    While finish >= 86400
        finish = finish - 86400
        days = days + 1
    Wend

    Dim lastTime As Single
    lastTime = Timer

    'When we are on the correct day and the time is after the finish we can leave
    While days >= 0 And Timer < finish
        DoEvents
        'Timer should be always increasing except when it rolls over midnight
        'if it shrunk we've gone back in time or we're on a new day
        If Timer < lastTime Then
            days = days - 1
        End If
        lastTime = Timer
    Wend

End Sub

Ответ 7

Функция Таймер также применяется к Access 2007, Access 2010, Access 2013, Access 2016, Access 2007 Developer, Access 2010 Developer, Access 2013 Developer. Вставьте этот код в паузу на определенное количество секунд.

T0 = Timer
Do
    Delay = Timer - T0
Loop Until Delay = 1 'Change this value to pause time in second

Ответ 8

В вашем коде создается время без даты. Если ваше предположение верно, когда он запускает приложение. Подождите, сколько времени уже достигнуто в это время, он будет ждать 24 часа точно. Я также немного беспокоюсь о вызове now() несколько раз (может быть другим?) Я бы изменил код на

 application.wait DateAdd("s", 1, Now)

Ответ 9

Я использовал ответ Стива Мэллори, но я боюсь, что таймер никогда или, по крайней мере, иногда не идет на 86400 и 0 (ноль) резко (MS Access 2013). Поэтому я изменил код. Я изменил условие полуночи на "If Timer >= 86399 Then" и добавил разрыв цикла "Exit Do" следующим образом:

Public Function Pause(NumberOfSeconds As Variant)
    On Error GoTo Error_GoTo

    Dim PauseTime As Variant
    Dim Start As Variant
    Dim Elapsed As Variant

    PauseTime = NumberOfSeconds
    Start = Timer
    Elapsed = 0
    Do While Timer < Start + PauseTime
        Elapsed = Elapsed + 1
        If Timer >= 86399
            ' Crossing midnight
            ' PauseTime = PauseTime - Elapsed
            ' Start = 0
            ' Elapsed = 0
            Exit Do
        End If
        DoEvents
    Loop

Exit_GoTo:
    On Error GoTo 0
    Exit Function
Error_GoTo:
    Debug.Print Err.Number, Err.Description, Erl
    GoTo Exit_GoTo
End Function

Ответ 10

В Windows таймер возвращает сотые доли секунды... Большинство людей просто используют секунды, потому что на таймере платформы Macintosh возвращается целые числа.

Ответ 11

С заслуженными кредитами и благодарностью Стива Маллруа.

У меня были проблемы с полночью в Word, и код ниже работал у меня

Public Function Pause(NumberOfSeconds As Variant)
 '   On Error GoTo Error_GoTo

    Dim PauseTime, Start
    Dim objWord As Word.Document

    'PauseTime = 10 ' Set duration in seconds
    PauseTime = NumberOfSeconds
    Start = Timer ' Set start time.

    If Start + PauseTime > 86399 Then 'playing safe hence 86399

    Start = 0

    Do While Timer > 1
        DoEvents ' Yield to other processes.
    Loop

    End If

    Do While Timer < Start + PauseTime
        DoEvents ' Yield to other processes.
    Loop

End Function

Ответ 12

Для MS Access: Запустите скрытую форму с помощью набора Me.TimerInterval и обработчика события Form_Timer. Поместите ваш код с задержкой в процедуру Form_Timer - выйдите из процедуры после каждого выполнения.

Например:

Private Sub Form_Load()
    Me.TimerInterval = 30000 ' 30 sec
End Sub

Private Sub Form_Timer()

    Dim lngTimerInterval  As Long: lngTimerInterval = Me.TimerInterval

    Me.TimerInterval = 0

    '<Your Code goes here>

    Me.TimerInterval = lngTimerInterval
End Sub

"Ваш код идет здесь" будет исполнен через 30 секунд после открытия формы и через 30 секунд после каждого последующего выполнения.

Закройте скрытую форму, когда закончите.