Каковы значения ERRORLEVEL, установленные внутренними командами cmd.exe?

ERRORLEVEL - это значение, возвращаемое большинством команд cmd.exe, когда они заканчивают это изменение в зависимости от ряда условий, поэтому знание значения, возвращаемого командами, является ценной информацией, которая может помочь лучше писать пакетные файлы. Все внешние.exe-программы меняют ERRORLEVEL, когда они заканчиваются (это неотъемлемый механизм функций API ExitProcess и TerminateProcess Win-32), и обычно такие значения документируются, но значения, возвращаемые внутренними командами cmd.exe, не полностью документированы в другом месте,

В этом вопросе появляется таблица с частичными значениями ERRORLEVEL, но только для внутренних команд, которые устанавливают ERRORLEVEL = 0 "после успеха". Я предложил ОП такого вопроса изменить его, чтобы также включить значения, возвращаемые "неуспешными командами", но он отказался и предложил мне опубликовать свой собственный вопрос/ответ, так что вот оно! Вы должны заметить, что значение ERRORLEVEL, отличное от нуля, не обязательно означает, что команда не удалась! Есть некоторые команды, которые заканчиваются без ошибок и возвращают значение больше нуля, чтобы указать разные "статус выхода", включая внутренние команды (например, SET/P).

Чтобы лучше использовать встроенные команды cmd.exe в Batch файлах, нам нужно знать значения ERRORLEVEL, которые они возвращают, и механизмы, задействованные в этом управлении. Итак, вопрос в том, какие внутренние команды cmd.exe устанавливают ERRORLEVEL для любого значения (включая ноль)?

Ответ 1

В этом ответе описываются значения ERRORLEVEL, возвращаемые всеми внутренними командами cmd.exe; они сгруппированы по способу изменения стоимости и представлены в виде кратких справочных таблиц. Я просмотрел другие подобные таблицы, чтобы собрать этот, но заполнил недостающие значения с помощью тестов, выполненных на компьютере под управлением Windows 8.1. Я приложил все усилия, чтобы эти таблицы были полными и точными, но я не тестировал каждый из приведенных здесь значений, поэтому это могут быть тонкие несоответствия.

Таблица 1 - Команды, которые не изменяют предыдущее значение ERRORLEVEL

BREAK
ECHO
ENDLOCAL
FOR      Not change the ERRORLEVEL by itself. See "Exit Code" below.
IF       Not change the ERRORLEVEL by itself.
PAUSE
RD       Not change the ERRORLEVEL on errors, but the "Exit Code". See below.
REM
RMDIR    Same as RD.
SET      Plain SET command (no arguments). See "Table 3" below.
TITLE

Таблица 2 - Команды, которые устанавливают ERRORLEVEL в 0 или 1 в зависимости от результата

Command │ Set ERRORLEVEL = 0 when       │ Set ERRORLEVEL = 1 when
────────┼───────────────────────────────┼─────────────────────────────────────────────────────────────
CD      │Current directory was changed. │Directory not exists or is not accessible.
CHDIR   │Same as CD.                    │
COLOR   │Color was changed.             │Background and foreground colors are the same.
COPY    │File(s) was processed.         │File not found or bad parameters given.
DATE    │Date was changed or not given. │User has no admin privileges.
DEL     │Almost always, excepting when: │Bad or no parameters given.
DIR     │Same as COPY.                  │
ERASE   │Same as DEL.                   │
MD      │Directory was created.         │Directory could not be created.
MKDIR   │Same as MD.                    │
MKLINK  │Link was created.              │Link could not be created or bad parameters given.
MOVE    │File(s) was moved/renamed.     │File not found, could not be moved/renamed or bad parameters.
PUSHD   │Same as CD.                    │+ Bad switch given.
REN     │Same as MOVE.                  │
RENAME  │Same as MOVE.                  │
SETLOCAL│New environment was created.   │Bad parameters given.
TIME    │Time was changed or not given. │User has no admin privileges.
TYPE    │Same as COPY.                  │
VERIFY  │Right or no parameters given.  │Bad parameters given.
VOL     │Volume label was displayed.    │Drive not found or bad parameters given.

Таблица 3 - Команды, которые устанавливают ошибку ERRORLEVEL; в противном случае не меняйте его

Command      │E│ Set ERRORLEVEL to = when
─────────────┼─┼────────────────────────────────────────────────────────────────────────
ASSOC        │*│1 = Extension associations could not be changed.
CLS          │ │1 = Bad switch given.
DPATH        │*│1 = Data path could not be established.
FTYPE        │*│1 = File type associations could not be changed.
GOTO label   │ │1 = Label not exist *in a subroutine* (equivalent to: EXIT /B 1).
KEYS         │ │1 = Bad switch given.
PATH         │*│1 = Path could not be changed.
POPD         │ │1 = Bad switch given.
PROMPT       |*│1 = Prompt could not be changed.
SET var      │*│1 = No variable with such name exists.
SET var=value│*│1 = Variable name start with "/" not enclosed in quotes.
SET /P       │*│1 = Read an empty line or at end of file.
SET /A       │*│1073750988 = Unbalanced parentheses, 1073750989 = Missing operand, 
             │ │1073750990 = Syntax error, 1073750991 = Invalid number,
             │ │1073750992 = Number larger than 32-bits, 1073750993 = Division by zero.
SHIFT        │ │1 = Bad switch given.

В столбце "E" в таблице 3 указаны команды, которые изменяют свое поведение соответственно статусу "Расширения", как описано в соответствующей документации. Когда расширения включены (по умолчанию), и эти команды помещаются в файл с расширением .CMD вместо .BAT one, эти команды устанавливают SETERRORLEVEL = 0, когда они заканчиваются без ошибок, то есть когда условия, описанные в таблице 3 нет.

Таблица 4 - Особые случаи

CALL Table1     │If the called command is anyone of Table 1 (excepting FOR and IF): set ERRORLEVEL = 0.
CALL subroutine │If the subroutine is called, not change prior ERRORLEVEL value;
                │otherwise (subroutine not exists): set ERRORLEVEL = 1.
EXIT /B, EXIT   │Not change prior ERRORLEVEL value.
EXIT /B number  │Set ERRORLEVEL to given number.
EXIT number     │Ends cmd.exe and set its returning ERRORLEVEL value to given number.
START command   │If command is started, not change ERRORLEVEL; otherwise, set ERRORLEVEL = 9059.
START /WAIT bat |When the started Batch file end, set ERRORLEVEL = value from 'EXIT number' commmand.
notExist        │If a non-existent command is entered for execution, set ERRORLEVEL = 9009.
VER             │Set ERRORLEVEL = 0 almost always. If /? parameter is given, not change ERRORLEVEL.

Управление кодом выхода

Существует два способа проверить значение ERRORLEVEL: через команду IF ERRORLEVEL / IF %ERRORLEVEL% или с помощью конструкции command && thenCmd when ERRORLEVEL is 0 || elseCmd when ERRORLEVEL is not 0. Однако некоторые определенные команды и ошибки перенаправления возвращают значение, которое работает только во втором случае и не отражается в ERRORLEVEL; мы можем назвать это "Код выхода". Если этот код выхода не равен нулю, его можно передать на ERRORLEVEL, выполнив любую команду в таблице 1 в части elseCmd. Вы можете прочитать дополнительную информацию по этому вопросу в этом сообщении.

Таблица 5 - Команды или функции, которые устанавливают код выхода

Feature      │ Set Exit Code to = when
─────────────┼─────────────────────────────────────────────────────────────────────────
command      │1 = Command not exist (when ERRORLEVEL = 9009).
redirection  │1 = File not exists in "<", path not exists or access denied in ">" ">>".
drive:       |1 = Drive unit not exists.
POPD         |1 = No matching PUSHD was previously executed.
RD           │1 = Bad switch given, 2 = Directory not found, 5 = Access denied,
             │32 = Directory in use, 145 = Directory not empty.
FOR /F       │1 = No data was processed.

Например, чтобы проверить, произошла ли ошибка перенаправления, используйте это:

command > C:\Path\that\does\not\exist\file.txt || rem
if errorlevel 1 echo Previous redirection failed

В этом примере команда rem используется для копирования кода выхода в ERRORLEVEL, но может использоваться любая другая внутренняя команда, которая сохраняет ERRORLEVEL (кроме FOR и IF).

Проверить, существует ли накопитель:

U: || rem
if errorlevel 1 echo Previous set current drive to U: unit failed

Другие примеры:

rd c:\Some\directory 2> NUL || rem
if %errorlevel% equ 0 (
   echo Directory deleted
) else if %errorlevel% equ 2 (
   echo Directory not found
) else if %errorlevel% equ 5 (
   echo Can not access the directory, check rights
) else if %errorlevel% equ 32 (
   echo Can not delete current directory
) else if %errorlevel% equ 145 (
   echo Directory is not empty, use /S switch
)


(for /F "options" %%a in (input.txt) do echo %%a) || rem
if errorlevel 1 echo Previous FOR didn't processed any value