Можно ли обеспечить соблюдение того, что запись относится к некоторым инвариантам?

Предположим, я хотел создать тип записи, который представляет допустимые границы min/max:

type Bounds = { Min: float; Max: float }

Есть ли способ обеспечить, чтобы Min < Максимум? Легко написать функцию validateBounds, мне просто интересно, есть ли лучший способ сделать это.

Edit: я понял, что для этого конкретного примера я мог бы, возможно, уйти с раскрытием двух свойств и переупорядочить аргументы, поэтому, допустим, мы пытались сделать

type Person = { Name: string }

и имя должно иметь хотя бы один символ.

Ответ 1

Здесь другое решение, основанное на уровнях защиты:

module MyModule =
    type Bounds = private { _min: float; _max: float } with
        // define accessors, a bit overhead
        member public this.Min = this._min
        member public this.Max = this._max
        static member public Make(min, max) =
            if min > max then raise (ArgumentException("bad values"))
            {_min=min; _max=max}

    // The following line compiles fine,
    // e.g. within your module you can do "unsafe" initialization
    let myBadBounds = {_min=10.0; _max=5.0}

open MyModule
let b1 = Bounds.Make(10.0, 20.0) // compiles fine
let b1Min = b1.Min
let b2 = Bounds.Make(10.0, 5.0) // throws an exception
// The following line does not compile: the union cases of the type 'Bounds'
// are not accessible from this code location
let b3 = {_min=10.0; _max=20.0}
// The following line takes the "bad" value from the module
let b4 = MyModule.myBadBounds

Ответ 2

Я думаю, что ваш лучший выбор - статический член:

type Bounds = { Min: float; Max: float }
    with
        static member Create(min: float, max:float) =
            if min >= max then
                invalidArg "min" "min must be less than max"

            {Min=min; Max=max}

и используйте его как

> Bounds.Create(3.1, 2.1);;
System.ArgumentException: min must be less than max
Parameter name: min
   at FSI_0003.Bounds.Create(Double min, Double max) in C:\Users\Stephen\Documents\Visual Studio 2010\Projects\FsOverflow\FsOverflow\Script2.fsx:line 5
   at <StartupCode$FSI_0005>[email protected]()
Stopped due to error
> Bounds.Create(1.1, 2.1);;
val it : Bounds = {Min = 1.1;
                   Max = 2.1;}

Однако, как вы указываете, большая сторона этого подхода заключается в том, что нет ничего, что препятствовало бы построению "неверной" записи напрямую. Если это является серьезной проблемой, рассмотрите возможность использования типа класса для гарантии ваших инвариантов:

type Bounds(min:float, max:float) = 
    do
        if min >= max then
            invalidArg "min" "min must be less than max"

    with
        member __.Min = min
        member __.Max = max

вместе с активным шаблоном для удобства, аналогичным тому, что вы получаете с записями (особенно в отношении соответствия шаблонов):

let (|Bounds|) (x:Bounds) =
    (x.Min, x.Max)

все вместе:

> let bounds = Bounds(2.3, 1.3);;
System.ArgumentException: min must be less than max
Parameter name: min
   at FSI_0002.Bounds..ctor(Double min, Double max) in C:\Users\Stephen\Documents\Visual Studio 2010\Projects\FsOverflow\FsOverflow\Script2.fsx:line 4
   at <StartupCode$FSI_0003>[email protected]()
Stopped due to error
> let bounds = Bounds(1.3, 2.3);;

val bounds : Bounds

> let isMatch = match bounds with Bounds(1.3, 2.3) -> "yes!" | _ -> "no";;

val isMatch : string = "yes!"

> let isMatch = match bounds with Bounds(0.3, 2.3) -> "yes!" | _ -> "no";;

val isMatch : string = "no"

Ответ 3

Извращенное решение для примера строки - используйте DU

type cleverstring = |S of char * string

Это заставит строку иметь хотя бы один символ. Затем вы можете просто использовать cleverstring вместо string в своей записи, хотя вы, вероятно, захотите написать некоторые функции-обертки, чтобы они выглядели как строка.