У меня проблема с использованием стороннего компонента в Delphi 2006 (также Delphi 7), в котором я получаю "Unspecified Error" при выполнении вызова функции этому компоненту. У вас есть пример кода, который использует GetLastError и FormatMessage в Delphi, что позволит мне получить дополнительную информацию об ошибке? TIA:)
Какое правильное использование GetLastError и FormatMessage в Delphi?
Ответ 1
В Delphi имеется встроенная вспомогательная функция: SysErrorMessage
. Это, по сути, обертка FormatMessage
, но гораздо проще в вашем случае. Просто укажите код ошибки, для которого требуется текстовое описание.
Например, вы можете использовать это для отображения последней ошибки:
ShowMessage(SysErrorMessage(GetLastError))
Если вы хотите создать исключение с этим сообщением, это еще проще:
RaiseLastOSError;
Важно. Убедитесь, что между функцией отказа и вызовом GetLastError
нет дополнительного вызова API, в противном случае последняя ошибка будет reset.
Ответ 2
В то время как DR является правильным, существует проблема с этим подходом: он не позволяет указать контекст, в котором произошла ошибка. Когда-либо видела ошибку "Ошибка функции API". без какой-либо мудрее, какая функция была и где это произошло?
Вот почему я написал функции RaiseLastOsErrorEx и Win32CheckEx:
procedure RaiseLastOsErrorEx(const _Format: string);
begin
RaiseLastOsErrorEx(GetLastError, _Format);
end;
procedure RaiseLastOsErrorEx(_ErrorCode: integer; _Format: string); overload;
var
Error: EOSError;
begin
if _ErrorCode <> ERROR_SUCCESS then
Error := EOSError.CreateFmt(_Format, [_ErrorCode, SysErrorMessage(_ErrorCode)])
else
Error := EOsError.CreateFmt(_Format, [_ErrorCode, _('unknown OS error')]);
Error.ErrorCode := _ErrorCode;
raise Error;
end;
function GetLastOsError(out _Error: string; const _Format: string = ''): DWORD;
begin
Result := GetLastOsError(GetLastError, _Error, _Format);
end;
function GetLastOsError(_ErrCode: integer; out _Error: string; const _Format: string = ''): DWORD;
var
s: string;
begin
Result := _ErrCode;
if Result <> ERROR_SUCCESS then
s := SysErrorMessage(Result)
else
s := _('unknown OS error');
if _Format <> '' then
try
_Error := Format(_Format, [Result, s])
except
_Error := s;
end else
_Error := s;
end;
function Win32CheckEx(_RetVal: BOOL; out _ErrorCode: DWORD; out _Error: string;
const _Format: string = ''): BOOL;
begin
Result := _RetVal;
if not Result then
_ErrorCode := GetLastOsError(_Error, _Format);
end;
(Они являются частью единицы u_dzMiscUtils из моей библиотеки dzLib, доступной здесь: https://sourceforge.net/p/dzlib/code/HEAD/tree/dzlib/trunk/src/u_dzOsUtils.pas