Как я могу подделать STDIN в Perl?

Я тестирую модуль, который требует ввода пользователя. Как сообщить Test::More использовать какой-либо ввод, который я предопределил, чтобы мне не нужно вводить его вручную?

Это то, что у меня есть сейчас:

use strict;
use warnings;
use Test::More;
use TestClass;

    *STDIN = "1\n";
    foreach my $file (@files)
    {

#this constructor asks for user input if it cannot find the file (1 is ignore);
    my $test = TestClass->new( file=> @files );

    isa_ok( $test, 'TestClass');
    }


done_testing;

Этот код нажимает enter, но функция извлекает 0, а не 1;

Ответ 1

Кажется, что работает следующая минимальная script:

#!/usr/bin/perl

package TestClass;
use strict;
use warnings;

sub new {
    my $class = shift;
    return unless <STDIN> eq "1\n";
    bless {} => $class;
}

package main;

use strict;
use warnings;

use Test::More tests => 1;

{
    open my $stdin, '<', \ "1\n"
        or die "Cannot open STDIN to read from string: $!";
    local *STDIN = $stdin;
    my $test = TestClass->new;
    isa_ok( $test, 'TestClass');
}

Вывод:

C:\Temp> t
1..1
ok 1 - The object isa TestClass

Ответ 2

Если программа читает с STDIN, просто установите STDIN как открытую дескриптор файла, в которой вы хотите:

#!perl

use strict;
use warnings;

use Test::More;

*STDIN = *DATA;

my @a = <STDIN>;

is_deeply \@a, ["foo\n", "bar\n", "baz\n"], "can read from the DATA section";

my $fakefile = "1\n2\n3\n";

open my $fh, "<", \$fakefile
    or die "could not open fake file: $!";

*STDIN = $fh;

my @b = <STDIN>;

is_deeply \@b, ["1\n", "2\n", "3\n"], "can read from a fake file";

done_testing; 

__DATA__;
foo
bar
baz

Вы можете больше узнать о typeglobs в perldoc perldata и многое другое о превращении строк в поддельные файлы в документацию для open (ищите "Поскольку v5.8.0, perl имеет построенный с использованием PerlIO по умолчанию." ) в perldoc perlfunc.