Сохранение журнала установки NSIS

Какой самый простой способ сохранить журнал установки, отображаемый в NSIS? Кажется, я кое-что запомнил, что вы можете перекомпилировать код NSIS со специальным флагом, чтобы он мог сохранить журнал. Есть ли более простой способ?

Ответ 1

Попробуйте плагин NSISLog.

Там также LogEx.

Ответ 2

В попытке ограничить размер файлов, по умолчанию установка компилятора NSIS не создает файлы журналов. Загрузите Special Build и скопируйте его в приложение makensis.exe (и Stub), чтобы исправить его, чтобы иметь поддержку ведения журнала.

Как только вы это сделаете, просто добавьте следующее в свой script:

 LogSet on

Никаких других изменений не требуется. Я понятия не имею, почему это не является дефолтом, как в моих случаях, он добавляет только 48 байтов в размер файла!

Ответ 3

Здесь прямое решение с сайта NSIS

StrCpy $0 "$EXEDIR\install.log"
Push $0
Call DumpLog



!define LVM_GETITEMCOUNT 0x1004
!define LVM_GETITEMTEXT 0x102D

Function DumpLog
  Exch $5
  Push $0
  Push $1
  Push $2
  Push $3
  Push $4
  Push $6

  FindWindow $0 "#32770" "" $HWNDPARENT
  GetDlgItem $0 $0 1016
  StrCmp $0 0 exit
  FileOpen $5 $5 "w"
  StrCmp $5 "" exit
    SendMessage $0 ${LVM_GETITEMCOUNT} 0 0 $6
    System::Alloc ${NSIS_MAX_STRLEN}
    Pop $3
    StrCpy $2 0
    System::Call "*(i, i, i, i, i, i, i, i, i) i \
      (0, 0, 0, 0, 0, r3, ${NSIS_MAX_STRLEN}) .r1"
    loop: StrCmp $2 $6 done
      System::Call "User32::SendMessageA(i, i, i, i) i \
        ($0, ${LVM_GETITEMTEXT}, $2, r1)"
      System::Call "*$3(&t${NSIS_MAX_STRLEN} .r4)"
      FileWrite $5 "$4$\r$\n"
      IntOp $2 $2 + 1
      Goto loop
    done:
      FileClose $5
      System::Free $1
      System::Free $3
  exit:
    Pop $6
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Pop $0
    Exch $5
FunctionEnd