Декодирование и понимание кода сборки

Итак, немного фона. Я новичок с c и ассемблером, у нас есть назначение "бомбы" (написано в c), которое вызывает методы, требующие определенных паролей, но код не отображается, и мне нужно определить правильный пароль, посмотрев на код сборки.

Код указывает, что пароль для этого метода - 6 чисел, который передается как "вход" в фазу метода 2 (я пытаюсь избежать запуска).

Часть, с которой я запуталась, - это прыжок с +64 до +42. Кажется, что это цикл, но я не уверен, как влияет на стек каждый проход. Похоже, что цикл выходит, если последние два числа совпадают, и это имеет какое-то отношение к добавлению и вычитанию 4, но я не уверен, как пройдены адреса. Если кто-то может перевести то, что именно происходит, или мне нужно искать в каких-либо конкретных регистрах/местах, это очень помогло бы. Есть еще четыре фазы, каждая из которых должна быть более сложной, поэтому я хочу получить хорошее представление о том, как подойти к чтению этих данных.

Кроме того, если у кого-то есть хороший ресурс (например, печатная таблица) с ключевыми словами кода сборки, которые также будут полезны, а также, если есть какие-либо различия между 32-битными и 64-разрядными регистрами, мне нужно беспокоиться о других, регистрировать имена.

    82          phase_2(input);
(gdb) disas phase_2
Dump of assembler code for function phase_2:
0x000000000040106b <phase_2+0>: push   %rbp
0x000000000040106c <phase_2+1>: push   %rbx
0x000000000040106d <phase_2+2>: sub    $0x28,%rsp
0x0000000000401071 <phase_2+6>: mov    %rsp,%rsi
0x0000000000401074 <phase_2+9>: callq  0x401457 <read_six_numbers>
0x0000000000401079 <phase_2+14>:        cmpl   $0x0,(%rsp)
0x000000000040107d <phase_2+18>:        jne    0x401086     <phase_2+27>
0x000000000040107f <phase_2+20>:        cmpl   $0x1,0x4(%rsp)
0x0000000000401084 <phase_2+25>:        je     0x40108b <phase_2+32>
0x0000000000401086 <phase_2+27>:        callq  0x401421 <explode_bomb>
0x000000000040108b <phase_2+32>:        lea    0x8(%rsp),%rbx
0x0000000000401090 <phase_2+37>:        lea    0x18(%rsp),%rbp
0x0000000000401095 <phase_2+42>:        mov    -0x8(%rbx),%eax
0x0000000000401098 <phase_2+45>:        add    -0x4(%rbx),%eax
0x000000000040109b <phase_2+48>:        cmp    %eax,(%rbx)
0x000000000040109d <phase_2+50>:        je     0x4010a4 <phase_2+57>
0x000000000040109f <phase_2+52>:        callq  0x401421 <explode_bomb>
0x00000000004010a4 <phase_2+57>:        add    $0x4,%rbx
0x00000000004010a8 <phase_2+61>:        cmp    %rbp,%rbx
0x00000000004010ab <phase_2+64>:        jne    0x401095 <phase_2+42>
0x00000000004010ad <phase_2+66>:        add    $0x28,%rsp
0x00000000004010b1 <phase_2+70>:        pop    %rbx
0x00000000004010b2 <phase_2+71>:        pop    %rbp
0x00000000004010b3 <phase_2+72>:        retq

Ответ 1

Здесь C-эквивалент фазы2:

int t[6];
read_six_numbers (t);
if ((t[0] != 0) || (t[1] != 1)) {
    explode_bomb();
}

for (int i = 2; i < 6; i++) {
        if (t[i] != t[i - 2] + t[i - 1]) {
            explode_bomb();
    }
}

Итак, пароль равен 0, 1, 1, 2, 3, 5.

Как я это сделал? Постепенно заменяя сборку на C.

Вы заметите, что указатель стека (rsp) никогда не изменяется. Стек можно увидеть как массив t из 32-битных чисел. Это каждый раз, когда вы перемещаетесь на 4 байта, вы переходите к следующему элементу. то есть 0 (% rsp), 4 (% rsp),... эквивалентны t [0], t [1],...

Я покажу вам возможную постепенную трансформацию бит, с которым у вас возникают проблемы:

                lea    0x8(%rsp),%rbx
                lea    0x18(%rsp),%rbp
<phase_2+42>:   mov    -0x8(%rbx),%eax
                add    -0x4(%rbx),%eax
                cmp    %eax,(%rbx)
                je     <phase_2+57>
                callq  explode_bomb
<phase_2+57>:   add    $0x4,%rbx
                cmp    %rbp,%rbx
                jne    phase_2+42
------------------------------------------------------
                    rbx = rsp + 8;
                    rbp = rsp + 24;
<phase_2+42>:       eax = [rbx - 8];
                    eax += [rbx - 4];
                    if (eax == [rbx]) goto <phase_2+57>;
                    explode_bomb();
<phase_2+57>:       rbx += 4;
                    if (rbx != rbp) goto phase_2+42;
------------------------------------------------------
rbx = rsp + 8;
rbp = rsp + 24;
do {
    eax = [rbx - 8] + [rbx - 4];
        if (eax != [rbx]) {
        explode_bomb();
    }
        rbx += 4;
} while (rbx != rbp);
------------------------------------------------------
rbx = 8;
do {
    eax = [rsp + rbx - 8] + [rsp + rbx - 4];
        if (eax != [rsp + rbx]) {
        explode_bomb();
    }
        rbx += 4;
} while (rbx < 24);
------------------------------------------------------
i = 2;
do {
    eax = t[i - 2] + t[i - 1];
        if (eax != t[i]) {
        explode_bomb();
    }
        i += 1;
} while (i < 6);
------------------------------------------------------
for (int i = 2; i < 6; i++) {
    if (t[i] != t[i - 2] + t[i - 1]) {
            explode_bomb();
        }
}

Если вы потратите время на понимание этих преобразований, вы сможете трансформировать и понять любую часть сборки.