Подтвердить что ты не робот

Генерирование данных изображения на холсте HTML на стороне сервера?

Название этого вопроса может немного вводить в заблуждение, но я не уверен, каким будет лучший заголовок (так как я пока не могу догадаться о решении).

В основном система, которую я разрабатываю, в значительной степени зависит от графиков холста. Эти графики генерируются через javascript и выполняются с использованием данных, вытащенных через ajax с сервера API.

Трудная часть заключается в том, что я хочу, чтобы вы могли отправлять эти графики пользователям этой системы без необходимости вообще переходить на веб-страницу. Поэтому, хотя я знаю, что можно получить значение Base64 изображения, сгенерированного с помощью javascript в браузере, как насчет того, что для запуска этого javascript не существует?

Я хотел бы сохранить графики, созданные в javascript/canvas, вместо того, чтобы делать их в общей серверной графической библиотеке (GD, ImageMagick). Графики Canvas являются динамическими и позволяют взаимодействовать через javascript. Хотя я не хочу использовать эту функцию в уведомлении по электронной почте, я хочу, чтобы они были идентичны в противном случае (по крайней мере, на первый взгляд).

Итак, вопрос в том, как я могу получить эти графики в электронном письме?

На этом этапе я предполагаю, что мне нужно буквально создать веб-сайт, на котором AJAX запрашивает "графики для рендеринга", отображает эти графики и отправляет результаты на сервер. Тогда мне понадобится "сервер", который просто сидит на этой веб-странице и отображает графики. Это единственное решение здесь?

4b9b3361

ОТВЕТЫ

Ответ 1

Я использовал phantomJs (например, node.js, но другой) serveride для выполнения точно того же кода, что и клиентская, и получить тот же результат. все, что вам нужно, - это один единственный exe файл (например, веб-браузер в автономном режиме)

Следующая программа (в Perl, но должна быть осуществима для перевода на ваш любимый язык) принимает некоторые данные, вставляет на веб-страницу (может быть ajax'ed) и либо отправляет эту веб-страницу клиенту, либо сохраняет это как временный файл и запускает PhantomJs на той же странице. Затем попросите PhantomJs сгенерировать jpg, который затем подбирается (и в этом случае sendt к клиенту).

#!/usr/bin/perl

use strict;
use File::Temp;
$|=1;
#this script returns a graph, either as html +js web page to render client side,
#or renders the same page server side, and returns the jpg image.

#files needed:
#.\phantom_srv_client.pl  #this script
#.\phantomjs.exe          #the webkit runtime stand alone file, from http://phantomjs.org/
#.\Scripts\excanvas.min.js #canvas simulator for IE8-
#.\Scripts\jquery.min.js   #jQuery as we know it
#.\Scripts\jquery.jqplot.min.js #graph library on top of jQuery from http://www.jqplot.com/ (Flot or any can be used)


#do we want client side rendering (html + js), or server side rendering (jpg)
#jpg seems to render nicer than png on some pages?
use CGI;
my $show_as_jpg = CGI::param("jpg");

#path to javascript libraries (jQuery etc). 
#Must be absolute file location for server rendering, relative for web
use FindBin;
my $script_path = $show_as_jpg 
    ? $FindBin::Bin."/Scripts" 
    : './Scripts';


#data to send to graph (two sets)
my $data = [[2,5,4], [6,4,5]];

#use json to get this as a javascript text
my $json_data;
eval {require JSON; $json_data=JSON::to_json($data)};
#in case JSON is not installed, get the json/javascript data manually (just for demo)
$json_data ||= "[[2,5,4], [6,4,9]]"; #here 9 at the end to see a difference

#The following is the web page that renders the graph, client or server side 
#(links to scripts must be abolute to work serverside, as temp-files may go anywhere, $script_path keeps track of that)
#$json_data is the Perl data structure converted to JSON (aka javascript, but not)
my $graph_html =qq|
<!DOCTYPE html>
<html>
<head>
    <!--[if lt IE 9]><script language="javascript" type="text/javascript" src="$script_path/excanvas.min.js"></script><![endif]-->
    <script class="include" type="text/javascript" src="$script_path/jquery.min.js"></script>
    <script class="include" type="text/javascript" src="$script_path/jquery.jqplot.min.js"></script>

    <script class="code" type="text/javascript" language="javascript">
        jQuery(document).ready(function(){
            /*data from perl (\$json_data) inserted here */
            var data = $json_data;
            jQuery.jqplot("chart1", data );
        });
    </script>
    </head>
<body>
    <div id="chart1" style="width:600px; height:400px;"></div>
    <a href='?jpg=1'>View as jpg</a>
</body>
</html>
|;


#this is the javascript that tells PhantomJs what to do (ie open a doc and render it to bitmap)
my $phantom_doc_js =qq|
    var system = require('system');
    //read from commandline which files to open, and write to
    var open_doc = system.args[1];
    var return_doc = system.args[2];
    var page = require('webpage').create();
    page.open(open_doc, function () {
        page.render(return_doc);
        phantom.exit();
    });
|;

#see if we shall render this page serverside
if ($show_as_jpg) {
    #get temporary filenames with related file handlers
    #where to put phantomjs script (generic so could be a static file)
    my ($phantom_doc_filehandler, $phantom_doc_filename) = File::Temp::tempfile(  SUFFIX => '.js', TMPDIR => 1);
    #where to put web page with data to render and ref to javascripts etc
    my ($phantom_graph_filehandler, $phantom_graph_filename) = File::Temp::tempfile(SUFFIX => '.html', TMPDIR => 1);
    #also get a filename with no handler, so phantomjs can return the jpg file. Extention must be .jpg!
    my (undef, $image_filename) = File::Temp::tempfile( SUFFIX => '.jpg',TMPDIR => 1, OPEN => 0);

    #store file content and close files
    print $phantom_doc_filehandler $phantom_doc_js; close $phantom_doc_filehandler;
    print $phantom_graph_filehandler $graph_html;   close $phantom_graph_filehandler;

    #now call PhantomJs with filenames to read from and write to.
    #Next version should support piping, which would simplify a lot

    #use absolute path to phantomjs.exe in case web-server does not use current path
    system($FindBin::Bin.'\\phantomjs', $phantom_doc_filename, $phantom_graph_filename, $image_filename) == 0 
        or die "system failed: $?";

    #read the entire image file
    my $img = slurp_file($image_filename);
    print "Content-Type: image/jpeg\nPragma: no-cache\n\n".$img;

    #The temp files are no more needed
    unlink $phantom_doc_filename, $phantom_graph_filename, $image_filename;

} else { # just render client side
    print "Content-Type: text/html\nPragma: no-cache\n\n".$graph_html;
}

#slurp is not always std perl   
sub slurp_file{
  my $filename = shift;
  my $string;
  local $/ = undef;
  open FILE, $filename or die "Couldn't open file: $!";
  binmode FILE;
  $string = <FILE>;
  close FILE;
  return $string;
}