Как объединить монады в Haskell?

Ответ 1

Я предполагаю, что вы хотите использовать монаду Maybe для раннего завершения (например, break или return в C).

В этом случае вы должны использовать MaybeT из пакета MaybeT (cabal install MaybeT).

main = do
  runMaybeT . forever $ do
    liftIO $ putStrLn "I won't stop until you type pretty please"
    line <- liftIO getLine
    when ("pretty please" == line) mzero
  return ()

MaybeT - версия трансформатора монады, возможно, монады.

Монадные трансформаторы "добавляют функциональность" в другие монады.

Ответ 2

Вы точно не говорите, как хотите объединить IO и Maybe, но я предполагаю, что у вас есть много функций, которые возвращают IO (Maybe a), которые вы хотите легко комбинировать. В основном вы хотите рассматривать IO (Maybe a) как отдельный тип с его собственным экземпляром Monad:

newtype IOMaybe a = IOM (IO (Maybe a))

-- "unpack" a value of the new type
runIOMaybe :: IOMaybe a -> IO (Maybe a)
runIOMaybe (IOM a) = a

instance Monad IOMaybe where
   -- bind operator
   (IOM ioa) >>= f = IOM $ do
      a <- ioa
      case a of
         Nothing -> return Nothing
         Just v  -> runIOMaybe (f v)

   -- return
   return a = IOM (return (Just a))

-- maybe also some convenience functions
returnIO :: IO a -> IOMaybe a
returnIO ioa = IOM $ do
   v <- ioa
   return (Just v)

returnMaybe :: Maybe a -> IOMaybe a
returnMaybe ma = IOM (return ma)

С этим вы можете использовать do -Notation для объединения функций, возвращающих IO (Maybe a), IO a или Maybe a:

f1 :: Int -> IO (Maybe Int)
f1 0 = return Nothing
f1 a = return (Just a)

main = runIOMaybe $ do
   returnIO $ putStrLn "Hello"
   a <- returnMaybe $ Just 2
   IOM $ f1 a
   return ()

В общем, что-то, что сочетает и изменяет такие монады, называется monad transformer, а GHC поставляется с package, который включает в себя монадные трансформаторы для обычных случаев. Если в этой библиотеке трансформатора монады есть что-то, что соответствует вашему сценарию, зависит от того, как именно вы хотите комбинировать Maybe и IO.

Ответ 3

В каком смысле вы хотите объединить монады?

f :: Int -> IO (Maybe Int)
f x = do
    putStrLn "Hello world!"
    return $ if x == 0 then Nothing else Just x

Можно оценить:

[1 of 1] Compiling Main             ( maybe-io.hs, interpreted )
Ok, modules loaded: Main.
*Main> f 0
Hello world!
Nothing
*Main> f 3
Hello world!
Just 3