Подтвердить что ты не робот

С# и F # casting - в частности, ключевое слово 'as'

В С# я могу сделать:

var castValue = inputValue as Type1

В F # я могу сделать:

let staticValue = inputValue :> Type1
let dynamicValue = inputValue :?> Type1

Но ни один из них не является эквивалентом С# как

Я думаю, мне нужно выполнить выражение соответствия для эквивалента в F #

match inputValue with
| :? Type1 as type1Value -> type1Value
| _ -> null

Правильно ли это?

4b9b3361

ОТВЕТЫ

Ответ 1

Насколько я знаю, F # не имеет встроенного оператора, эквивалентного С# as, поэтому вам нужно написать более сложное выражение. В качестве альтернативы вашему коду с помощью match вы также можете использовать if, потому что оператор :? может использоваться так же, как is в С#:

let res = if (inputValue :? Type1) then inputValue :?> Type1 else null

Конечно, вы можете написать функцию, чтобы инкапсулировать это поведение (написав простую общую функцию, которая принимает Object и передает ее указанному параметру общего типа):

let castAs<'T when 'T : null> (o:obj) = 
  match o with
  | :? 'T as res -> res
  | _ -> null

Эта реализация возвращает null, поэтому требуется, чтобы параметр типа null был правильным значением (в качестве альтернативы вы могли бы использовать Unchecked.defaultof<'T>, что эквивалентно default(T) в С#). Теперь вы можете просто написать:

let res = castAs<Type1>(inputValue)

Ответ 2

Я бы использовал активный шаблон. Вот тот, который я использую:

let (|As|_|) (p:'T) : 'U option =
    let p = p :> obj
    if p :? 'U then Some (p :?> 'U) else None

Вот пример использования As:

let handleType x = 
    match x with
    | As (x:int) -> printfn "is integer: %d" x
    | As (s:string) -> printfn "is string: %s" s
    | _ -> printfn "Is neither integer nor string"

// test 'handleType'
handleType 1
handleType "tahir"
handleType 2.
let stringAsObj = "tahir" :> obj
handleType stringAsObj

Ответ 3

Для этого вы можете создать своего оператора. Это практически идентично примеру Томаса, но показывает несколько иной способ его вызова. Вот пример:

let (~~) (x:obj) = 
  match x with
  | :? 't as t -> t //'
  | _ -> null

let o1 = "test"
let o2 = 2
let s1 = (~~o1 : string)  // s1 = "test"
let s2 = (~~o2 : string) // s2 = null