Как я могу использовать File:: Find в Perl?

Ответ 1

Лично я предпочитаю File::Find::Rule, так как вам не нужно создавать процедуры обратного вызова.

use strict;
use Data::Dumper;
use File::Find::Rule;

my $dir = shift;
my $level = shift // 2;

my @files = File::Find::Rule->file()
                            ->name("*.txt")
                            ->maxdepth($level)
                            ->in($dir);

print Dumper(\@files);

Или, альтернативно, создайте итератор:

my $ffr_obj = File::Find::Rule->file()
                              ->name("*.txt")
                              ->maxdepth($level)
                              ->start($dir);

while (my $file = $ffr_obj->match())
{
    print "$file\n"
}

Ответ 2

Я думаю, что просто использую glob, так как вам действительно не нужны все файлы обхода каталога:

 my @files = glob( '*.txt */*.txt' );

Я сделал File:: Find:: Closures, чтобы упростить создание обратных вызовов, которые вы передаете find:

 use File::Find::Closures qw( find_by_regex );
 use File::Find qw( find );

 my( $wanted, $reporter ) = File::Find::Closures::find_by_regex( qr/\.txt\z/ );

 find( $wanted, @dirs );

 my @files = $reporter->();

Обычно вы можете включить команду find (1) в программу Perl с помощью find2perl (удалено в v5.20, но в CPAN):

% find2perl my_dir -d 2  -name "*.txt"

Но, видимо, find2perl не понимает -maxdepth, поэтому вы можете оставить это:

% find2perl my_dir -name "*.txt"
#! /usr/local/perls/perl-5.13.5/bin/perl5.13.5 -w
    eval 'exec /usr/local/perls/perl-5.13.5/bin/perl5.13.5 -S $0 ${1+"[email protected]"}'
        if 0; #$running_under_some_shell

use strict;
use File::Find ();

# Set the variable $File::Find::dont_use_nlink if you're using AFS,
# since AFS cheats.

# for the convenience of &wanted calls, including -eval statements:
use vars qw/*name *dir *prune/;
*name   = *File::Find::name;
*dir    = *File::Find::dir;
*prune  = *File::Find::prune;

sub wanted;



# Traverse desired filesystems
File::Find::find({wanted => \&wanted}, 'my_dir');
exit;


sub wanted {
    /^.*\.txt\z/s
    && print("$name\n");
}

Теперь, когда у вас есть начальное программирование, вы можете подключить все, что вам нужно, включая шаг preprocess для обрезки дерева.

Ответ 3

use File::Find ; 
use Cwd ; 

my $currentWorkingDir = getcwd;

my @filesToRun = ();
my $filePattern = '*.cmd' ; 
#add only files of type filePattern recursively from the $currentWorkingDir
find( sub { push @filesToRun, $File::Find::name  
                                    if ( m/^(.*)$filePattern$/ ) }, $currentWorkingDir) ;

foreach  my $file ( @filesToRun  ) 
{
    print "$file\n" ;   
} 

Ответ 4

Там также удобная утилита find2perl. Используйте его вместо команды поиска Unix с теми же аргументами командной строки, что и "find", и он будет генерировать соответствующий код Perl, который использует File:: Find.

$ find2perl my_dir -maxdepth 2 -name "*.txt"