Разница между * и node() в XSLT

Ответ 1

<xsl:template match="node()">

является аббревиатурой для:

<xsl:template match="child::node()">

Соответствует любому типу node, который можно выбрать с помощью оси the child:::

• Элемент

• Текст- node

• инструкция обработки (PI) node

• комментарий node.

С другой стороны:

<xsl:template match="*">

является аббревиатурой для:

<xsl:template match="child::*">

Соответствует любому элементу.

выражение XPath: someAxis:: * соответствует любому node основного node -типа для данной оси.

Для оси child:: основным node -типом является элемент.

Ответ 2

Просто, чтобы проиллюстрировать одно из отличий, а именно, что * не соответствует text:

Учитывая xml:

<A>
    Text1
    <B/>
    Text2
</A>

Соответствие на node()

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

    <!--Suppress unmatched text-->
    <xsl:template match="text()" />

    <xsl:template match="/">
        <root>
            <xsl:apply-templates />
        </root>
    </xsl:template>

    <xsl:template match="node()">
        <node>
            <xsl:copy />
        </node>
        <xsl:apply-templates />
    </xsl:template>
</xsl:stylesheet>

дает:

<root>
    <node>
        <A />
    </node>
    <node>
        Text1
    </node>
    <node>
        <B />
    </node>
    <node>
        Text2
    </node>
</root>

Если соответствие *:

<xsl:template match="*">
    <star>
        <xsl:copy />
    </star>
    <xsl:apply-templates />
</xsl:template>

Не соответствует текстовым узлам.

<root>
  <star>
    <A />
  </star>
  <star>
    <B />
  </star>
</root>

Ответ 3

Также см. XSL xsl: template match = "/" для других шаблонов соответствия.