Как я могу создать GUID при вызове Live Template в Delphi?

Ответ 1

Вы можете расширить IDE, создав для этого специальный механизм создания сценариев. (Здесь в статье, написанной Ником Ходжесом, с аналогичным примером, который вставляет текущую дату.)

Я предполагаю, что два разных интерфейса из вашего шаблона примера нуждаются в двух разных ИДИ, поэтому я написал механизм сценариев для загрузки имен точек из "script" (это просто список пар name = value, где имя имя точки и значение должно быть NewGuid, иначе оно игнорируется), поэтому вы можете создавать шаблоны с несколькими точками, каждый из которых получает отдельный новый IID.

Пример шаблона intf.xml:

<?xml version="1.0" encoding="utf-8" ?>
<codetemplate   xmlns="http://schemas.borland.com/Delphi/2005/codetemplates" version="1.0.0">
<template name="iacc" surround="false" invoke="manual">
    <point name="name">
        <text>
            Accessor
        </text>
        <hint>
            Accessors name
        </hint>
    </point>
    <point name="guid1"/>
    <point name="guid2"/>
    <description>
        accessor declaration
    </description>
    <author>
        PMH
    </author>
    <script language="NewGuidScript" onvalidate="true">
        guid1=NewGuid
        guid2=NewGuid
    </script>
    <code language="Delphi" context="any" delimiter="|">    <![CDATA[I|name|Accessors = interface(IInterface)
|*||guid1|
end;

I|name| = interface(I|name|Accessors)
|*||guid2|
end;]]>
    </code>
    </template>
</codetemplate>

NewGuidScriptEngine.pas:

unit NewGuidScriptEngine;

interface

uses
  Classes, SysUtils,
  ToolsApi, CodeTemplateApi, DesignEditors;

type
  TNewGuidScriptEngine = class(TNotifierObject, IOTACodeTemplateScriptEngine)
  public
    procedure Execute(const ATemplate: IOTACodeTemplate; const APoint: IOTACodeTemplatePoint; const ASyncPoints: IOTASyncEditPoints; const AScript: IOTACodeTemplateScript; var Cancel: Boolean);
    function GetIDString: WideString;
    function GetLanguage: WideString;
  end;

procedure Register;

implementation

uses
  ActiveX,
  ComObj;

procedure Register;
begin
  (BorlandIDEServices as IOTACodeTemplateServices).RegisterScriptEngine(TNewGuidScriptEngine.Create);
end;

procedure TNewGuidScriptEngine.Execute(const ATemplate: IOTACodeTemplate; const APoint: IOTACodeTemplatePoint;
  const ASyncPoints: IOTASyncEditPoints; const AScript: IOTACodeTemplateScript; var Cancel: Boolean);
var
  I: Integer;
  Guid: TGUID;
  P: IOTACodeTemplatePoint;
  Points: TStringList;
begin
  Cancel := False;
  if not Assigned(ATemplate) then
    Exit;

  Points := TStringList.Create;
  try
    Points.Text := AScript.Script;
    for I := 0 to Points.Count - 1 do
      Points.Strings[I] := Trim(Points[I]);

    for I := 0 to Points.Count - 1 do
      if Points.ValueFromIndex[I] = 'NewGuid' then
      begin
        P := ATemplate.FindPoint(Points.Names[I]);
        if Assigned(P) then
        begin
          OleCheck(CoCreateGuid(Guid));
          P.Editable := False;
          P.Value := '[''' + GUIDToString(Guid) + ''']';
        end;
      end;
  finally
    Points.Free;
  end;
end;

function TNewGuidScriptEngine.GetIDString: WideString;
begin
  Result := 'OndrejKelle.NewGuidScriptEngine';
end;

function TNewGuidScriptEngine.GetLanguage: WideString;
begin
  Result := 'NewGuidScript';
end;

end.

Поместите вышеуказанный блок в пакет времени только для разработки, добавьте ссылку на designide.dcp в его предложение requires и установите пакет в среде IDE.

Другой полезный, похожий шаблон может выглядеть так:

<?xml version="1.0" encoding="utf-8" ?>
<codetemplate   xmlns="http://schemas.borland.com/Delphi/2005/codetemplates" version="1.0.0">
<template name="iacc" surround="false" invoke="manual">
    <point name="name">
        <text>
        </text>
        <hint>
            Accessors name
        </hint>
    </point>
    <point name="guid1"/>
    <point name="guid2"/>
    <description>
        accessor declaration
    </description>
    <author>
        PMH
    </author>
    <script language="NewGuidScript" onvalidate="true">
        guid1=NewGuid
        guid2=NewGuid
    </script>
    <code language="Delphi" context="any" delimiter="|">    <![CDATA[const
  SIID_I|name|Accessors = |guid1|;
  IID_I|name|Accessors: TGUID = SIID_I|name|Accessors;
  SIID_I|name| = |guid2|;
  IID_I|name|: TGUID = SIID_I|name|;

type
  I|name|Accessors = interface
    [SIID_I|name|Accessors]
  end;

  I|name| = interface(I|name|Accessors)
    [SIID_I|name|]
  end;]]>
    </code>
    </template>
</codetemplate>

Это будет объявлять строку, а также константы TGUID, а также повторно использовать их в объявлениях интерфейса. В этом случае введенные значения GUID не должны быть заключены в квадратные скобки. У вас есть несколько вариантов настройки механизма сценариев, чтобы сделать это:

• изменить код, чтобы просто не использовать квадратные скобки
• ввести отдельную новую функцию NewGuidNoBrackets и использовать ее в шаблоне
• введите некоторый простой синтаксис, например NewGuid (false), который ваш движок может проанализировать и использовать значение параметра, чтобы определить, следует ли использовать квадратные скобки или нет.