только начал использовать log4j в одном из моих домашних проектов, и я как раз собирался вырвать мышь и вырезать-вставить (trace (str "entering: " function-name))
в каждую функцию большого модуля. тогда голос разума догнал и сказал: "там просто должен быть лучший способ"... Я могу думать о создании макроса, который обертывает целый блок функций и добавляет следы к ним или что-то в этом роде? Любые советы от мудрых переполняющих штанов-клоуриев?
Clojure: добавление трассировки отладки для каждой функции в пространстве имен?
Ответ 1
Нет необходимости в макросе:
(defn trace-ns
"ns should be a namespace object or a symbol."
[ns]
(doseq [s (keys (ns-interns ns))
:let [v (ns-resolve ns s)]
:when (and (ifn? @v) (-> v meta :macro not))]
(intern ns
(with-meta s {:traced true :untraced @v})
(let [f @v] (fn [& args]
(clojure.contrib.trace/trace (str "entering: " s))
(apply f args))))))
(defn untrace-ns [ns]
(doseq [s (keys (ns-interns ns))
:let [v (ns-resolve ns s)]
:when (:traced (meta v))]
(alter-meta! (intern ns s (:untraced (meta v)))
#(dissoc % :traced :untraced))))
... или что-то подобное. Наиболее вероятным дополнительным требованием было бы использовать filter
, чтобы не называть trace
на вещи, которые не являются ifn?
s. Обновление: отредактировано в решении этого вопроса (также для обработки макросов). Обновление 2: исправлены некоторые основные ошибки. Обновление 4: добавлена функциональность untrace.
Обновление 3: Здесь приведен пример из моего REPL:
user> (ns foo)
nil
foo> (defn foo [x] x)
#'foo/foo
foo> (defmacro bar [x] x)
#'foo/bar
foo> (ns user)
nil
user> (trace-ns 'foo)
nil
user> (foo/foo :foo)
TRACE: "entering: foo"
:foo
user> (foo/bar :foo)
:foo
user> (untrace-ns 'foo)
nil
user> (foo/foo :foo)
:foo