Конвертировать std: vector в NSArray

Ответ 1

Если у вас есть вектор объектов, вы можете сделать следующее:

NSArray *myArray = [NSArray arrayWithObjects:&vector[0] count:vector.size()];

Однако, если ваш вектор содержит примитивные типы, такие как NSInteger, int, float и т.д., вам придется вручную закодировать значения в векторе и сначала преобразовать их в NSNumber.

Ответ 2

Да, вы можете создать NSArray из NSInteger из std::vector<NSInteger>, используя следующий подход:

// thrown together as a quick demo. this could be improved.
NSArray * NSIntegerVectorToNSArrayOfNSIntegers(const std::vector<NSInteger>& vec) {

  struct MONCallback {
    static const void* retain(CFAllocatorRef allocator, const void* value) {
      /* nothing to do */
      return value;
    }

    static void release(CFAllocatorRef allocator, const void* value) {
      /* nothing to do */
    }

    static CFStringRef copyDescription(const void* value) {
      const NSInteger i(*(NSInteger*)&value);
      return CFStringCreateWithFormat(0, 0, CFSTR("MON - %d"), i);
    }

    static Boolean equal(const void* value1, const void* value2) {
      const NSInteger a(*(NSInteger*)&value1);
      const NSInteger b(*(NSInteger*)&value2);
      return a == b;
    }
  };

  const CFArrayCallBacks callbacks = {
    .version = 0,
    .retain = MONCallback::retain,
    .release = MONCallback::release,
    .copyDescription = MONCallback::copyDescription,
    .equal = MONCallback::equal
  };

  const void** p((const void**)&vec.front());
  NSArray * result((NSArray*)CFArrayCreate(0, p, vec.size(), &callbacks));
  return [result autorelease];  
}

void vec_demo() {
  static_assert(sizeof(NSInteger) == sizeof(NSInteger*), "you can only use pointer-sized values in a CFArray");

  std::vector<NSInteger> vec;
  for (NSInteger i(0); i < 117; ++i) {
    vec.push_back(i);
  }
  CFShow(NSIntegerVectorToNSArrayOfNSIntegers(vec));
}

Однако вам нужно быть очень осторожным в отношении использования этой коллекции. Фонд ожидает, что элементы будут NSObject s. Если вы передадите его во внешний API, который ожидает массив из NSObject s, он, вероятно, вызовет ошибку (читайте: EXC_BAD_ACCESS в objc_msgSend).

Обычно их можно преобразовать в NSNumber. Я бы использовал этот NSArray из NSInteger в моей программе только в том случае, если ему нужен другой другой API (у Apple есть несколько). Они просто не очень хорошо сочетаются.