Как обновить данные как первую букву с командой t-sql?

У меня есть таблица в моей базе данных. Имя моей таблицы - "Компания". Я хочу изменить данные "company_name" как первую букву верхнего регистра. Например:

"ABC COMPANY"

"DEF PLASTICITY"

"Компания Abc"

"Деформировать пластичность"

Я знаю, что я должен использовать команду "UPDATE". Но как? Спасибо за вашу помощь!

(CONCAT не работает)

Ответ 1

SQL Server Не имеет функции Initcap, такой как oracle.

Вы можете создать UDF для Initcap.

CREATE FUNCTION [dbo].[InitCap] ( @InputString varchar(4000) ) 
RETURNS VARCHAR(4000)
AS
BEGIN

DECLARE @Index          INT
DECLARE @Char           CHAR(1)
DECLARE @PrevChar       CHAR(1)
DECLARE @OutputString   VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 1

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char     = SUBSTRING(@InputString, @Index, 1)
    SET @PrevChar = CASE WHEN @Index = 1 THEN ' '
                         ELSE SUBSTRING(@InputString, @Index - 1, 1)
                    END

    IF @PrevChar IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(')
    BEGIN
        IF @PrevChar != '''' OR UPPER(@Char) != 'S'
            SET @OutputString = STUFF(@OutputString, @Index, 1, UPPER(@Char))
    END

    SET @Index = @Index + 1
END

RETURN @OutputString

END
GO

Проверка работы UDF

select [dbo].[InitCap] ('stackoverflow com');

Stackoverflow Com

вы можете обновить таблицу таким образом

update table
set column=[dbo].[InitCap](column);

Ответ 2

update  YourTable
set     company_name = upper(substring(company_name,1,1)) + 
            lower(substring(company_name, 2, len(company_name)-1))
where   len(company_name) > 0

Живой пример в SQL Fiddle.

Ответ 3

С небольшой помощью функции split, такой как этот.

Попробуйте это, замените YourTable на любое имя вашей таблицы:

update T
set Name = P.Name
from YourTable as T
  cross apply (select (select upper(left(X.s, 1))+lower(stuff(X.s, 1, 1, ''))+' '
                       from dbo.split(' ', Name) as X
                       for xml path(''), type).value('.', 'varchar(50)')
              ) as P(Name)

Ответ 4

С задолженностью к вышеуказанному сообщению эта функция заглаживает первую букву каждого слова, кроме тех, которые меньше определенной длины символа, которые считаются акронимами. Если это не проблема, вы устанавливаете второй аргумент в 0.

CREATE function [dbo].[f_camel_exc_short_words] (@InputString varchar(4000),@AcronymMaxLen INT )
RETURNS VARCHAR(4000)
AS
BEGIN

DECLARE @Index          INT
DECLARE @Char           CHAR(1)
DECLARE @PrevChar       CHAR(1)
DECLARE @Word           VARCHAR(255)
DECLARE @WordChar       CHAR(1)
DECLARE @OutputString   VARCHAR(255)
DECLARE @WordIndex      INT

SET @Word = ''
SET @OutputString = '' 
SET @Index = 1

WHILE @Index <= LEN(@InputString)+1
BEGIN
    SET @Char     = SUBSTRING(@InputString, @Index, 1)
    SET @PrevChar = CASE WHEN @Index = 1 THEN   ' '   ELSE   SUBSTRING(@InputString, @Index - 1, 1)  END

    --IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(')
    --    SET @OutputString = @OutputString + @Char

    IF @PrevChar IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(','0','1','2','3','4','5','6','7','8','9') or @Index = LEN(@InputString)+1
    BEGIN
         SET @WordIndex = 1
        IF LEN(@Word) > @AcronymMaxLen 
        BEGIN
            WHILE @WordIndex <= LEN(@Word)
            BEGIN
                SET @WordChar = SUBSTRING(@Word,@WordIndex,1)
                if @WordIndex = 1  begin
                    SET @Word = STUFF(@Word,@WordIndex,1,UPPER(@WordChar))    end
                else    begin
                    SET @Word = STUFF(@Word,@WordIndex,1,LOWER(@WordChar))    end
                SET @WordIndex = @WordIndex + 1
            END
        END
        ELSE BEGIN
            SET @Word = UPPER(@Word)
        END
        set @OutputString = @OutputString + @Word
        SET @Word = ''
    END
    SET @Word = @Word + @Char
    SET @Index = @Index + 1
END  

return @OutputString

end
GO

код >

Итак, PRINT dbo.f_camel_exc_short_words ('PIONEER EURO BOND FUND CLASS C (NON-DIST) (EUR) (OFFSHORE) ISIN LU0119429891',4) возвращает Pioneer EURO BOND FUND Класс C (Не-Dist) (EUR) (оффшор) ISIN LU0119429891

Надеюсь, что это поможет.

Ответ 5

Попробуйте следующее:

declare @word as nvarchar (50)
set @word = 'ABC COMPANY'
select upper(left(@word, 1)) + lower(SUBSTRING(@word,2,charindex(' ', @word)-2)) + ' ' + 
upper(left(substring(@word,charindex(' ', @word)+1,len(@word)-1),1)) 
+ lower(SUBSTRING(@word,charindex(' ', @word)+2, len(@word)))

Ответ 6

Другая модификация обрабатывает собственники (s) и слова, начинающиеся с Mc

if ' ' + @OutputString like '% Mc%'
set @OutputString = ' ' + @OutputString
set @index = CHARINDEX ( ' Mc', @OutputString)
while @Index > 0
begin
    set @OutputString = SUBSTRING(@outputString, 1, @index + 2) + UPPER(SUBSTRING(@outputString, @index + 3, 1)) + SUBSTRING(@outputString, @index + 4, len(@outputString))
    set @index = CHARINDEX ( ' Mc', @OutputString, @Index + 4)
end
set @outputstring = ltrim(rtrim(@outputstring))

if @OutputString + ' ' like '%' %' 
set @OutputString = ltrim(rtrim(REPLACE(@outputstring + ' ', '' ', '' ')))

разместить прямо перед возвратом

Ответ 7

CREATE FUNCTION Initcap
( @mystring varchar(50) )
RETURNS VARCHAR(50)
AS
BEGIN
   DECLARE @val VARCHAR(50);
   SET @val = (select upper(left(@mystring,1)) +  lower(substring(@mystring,2,datalength(@mystring)-1)) )
   RETURN @val;
END;