Проверьте, существует ли запись в коллекции VB6?

Я унаследовал большое приложение VB6 на моем текущем рабочем месте. Я немного изучаю VB6 на работе, и у меня есть ряд проблем. Основная проблема на данный момент - я не могу понять, как проверить, существует ли ключ в объекте Collection. Может ли кто-нибудь помочь?

Ответ 1

Моя стандартная функция очень проста. Это будет работать независимо от типа элемента, поскольку он не удостаивается каких-либо назначений, он просто выполняет свойство коллекции get.

Public Function Exists(ByVal oCol As Collection, ByVal vKey As Variant) As Boolean

    On Error Resume Next
    oCol.Item vKey
    Exists = (Err.Number = 0)
    Err.Clear

End Function

Ответ 2

@Mark Biek Ваш ключExists соответствует моей стандартной функции Exists(). Чтобы сделать класс более полезным для коллекций с открытым доступом и проверять числовые индексы, я бы рекомендовал изменить sKey и myCollection, чтобы их не вводить. Если функция будет использоваться с коллекцией объектов, требуется "set" (в строке, где установлен val).

EDIT: меня раздражало, что я никогда не замечал различных требований к объектной и основанной на значении функциям Exists(). Я очень редко использую коллекции для не-объектов, но это казалось таким прекрасным узким местом для ошибки, которую было бы так сложно отследить, когда мне нужно было проверить существование. Поскольку обработка ошибок завершится неудачно, если обработчик ошибок уже активен, для получения новой области ошибок требуются две функции. Только функция Exists() должна быть вызвана:

Public Function Exists(col, index) As Boolean
On Error GoTo ExistsTryNonObject
    Dim o As Object

    Set o = col(index)
    Exists = True
    Exit Function

ExistsTryNonObject:
    Exists = ExistsNonObject(col, index)
End Function

Private Function ExistsNonObject(col, index) As Boolean
On Error GoTo ExistsNonObjectErrorHandler
    Dim v As Variant

    v = col(index)
    ExistsNonObject = True
    Exit Function

ExistsNonObjectErrorHandler:
    ExistsNonObject = False
End Function

И чтобы проверить функциональность:

Public Sub TestExists()
    Dim c As New Collection

    Dim b As New Class1

    c.Add "a string", "a"
    c.Add b, "b"

    Debug.Print "a", Exists(c, "a") ' True '
    Debug.Print "b", Exists(c, "b") ' True '
    Debug.Print "c", Exists(c, "c") ' False '
    Debug.Print 1, Exists(c, 1) ' True '
    Debug.Print 2, Exists(c, 2) ' True '
    Debug.Print 3, Exists(c, 3) ' False '
End Sub

Ответ 3

Я всегда делал это с помощью такой функции:

public function keyExists(myCollection as collection, sKey as string) as Boolean
  on error goto handleerror:

  dim val as variant

  val = myCollection(sKey)
  keyExists = true
  exit sub
handleerror:
  keyExists = false
end function

Ответ 4

Как указано Томасом, вам нужно установить объект вместо Let. Вот общая функция из моей библиотеки, которая работает для значений и типов объектов:

Public Function Exists(ByVal key As Variant, ByRef col As Collection) As Boolean

'Returns True if item with key exists in collection

On Error Resume Next

Const ERR_OBJECT_TYPE As Long = 438
Dim item As Variant

'Try reach item by key
item = col.item(key)

'If no error occurred, key exists
If Err.Number = 0 Then
    Exists = True

'In cases where error 438 is thrown, it is likely that
'the item does exist, but is an object that cannot be Let
ElseIf Err.Number = ERR_OBJECT_TYPE Then

    'Try reach object by key
    Set item = col.item(key)

    'If an object was found, the key exists
    If Not item Is Nothing Then
        Exists = True
    End If

End If

Err.Clear

End Function

Как также советует Томас, вы можете изменить тип коллекции на объект, чтобы обобщить это. Синтаксис .Item(key) используется большинством классов коллекций, поэтому это может быть полезно.

РЕДАКТИРОВАТЬ Похоже, я сам был избит до самого Томаса. Однако для более простого повторного использования я лично предпочитаю одну функцию без личных зависимостей.

Ответ 5

Использование обработчика ошибок для обнаружения случаев, когда ключ не существует в коллекции, может сделать отладку с опцией "break on all errors" довольно раздражающей. Чтобы избежать нежелательных ошибок, я довольно часто создаю класс, который хранит объекты в коллекции и все ключи в словаре. Словарь существует (ключ) -функция, поэтому я могу вызвать это, прежде чем пытаться получить объект из коллекции. Вы можете хранить строки только в словаре, поэтому коллекция необходима, если вам нужно хранить объекты.

Ответ 6

Утверждение "обработка ошибок завершится неудачно, если обработчик ошибок уже активен" только частично прав.

У вас может быть несколько обработчиков ошибок в вашей рутине.
Таким образом, можно использовать одну и ту же функциональность только в одной функции.
Просто перепишите свой код следующим образом:

Public Function Exists(col, index) As Boolean
Dim v As Variant

TryObject:
    On Error GoTo ExistsTryObject
        Set v = col(index)
        Exists = True
        Exit Function

TryNonObject:
    On Error GoTo ExistsTryNonObject

        v = col(index)
        Exists = True
        Exit Function

ExistsTryObject:
   ' This will reset your Err Handler
   Resume TryNonObject

ExistsTryNonObject:
        Exists = False
End Function

Однако, если бы вы включили только код в разделе TryNonObject подпрограммы, это обеспечило бы ту же информацию.
Он будет выполнен как для объектов, так и для не-объектов. Тем не менее, это ускорит ваш код для не-объектов, поскольку вам нужно будет выполнить только один оператор, чтобы утверждать, что элемент существует в коллекции.

Ответ 7

Лучшим решением было бы написать функцию TryGet. Много времени, когда вы собираетесь проверять, существует, а затем получает элемент. Сэкономьте время, сделав это одновременно.

public Function TryGet(key as string, col as collection) as Variant
  on error goto errhandler
  Set TryGet= col(key)
  exit function
errhandler:
  Set TryGet = nothing  
end function

Ответ 8

см http://www.visualbasic.happycodings.com/Other/code10.html реализация здесь имеет преимущество также необязательно возвращать найденный элемент и работает с объектно-родными типами (согласно комментариям).

воспроизводится здесь, поскольку ссылка больше не доступна:

Определите, существует ли элемент в коллекции

В следующем коде показано, как определить, существует ли элемент в коллекции.

Option Explicit

'Purpose     :  Determines if an item already exists in a collection
'Inputs      :  oCollection         The collection to test for the existance of the item
'               vIndex              The index of the item.
'               [vItem]             See Outputs
'Outputs     :  Returns True if the item already exists in the collection.
'               [vItem] The value of the item, if it exists, else returns "empty".
'Notes       :
'Example     :

Function CollectionItemExists(vIndex As Variant, oCollection As Collection, Optional vItem As Variant) As Boolean
    On Error GoTo ErrNotExist

    'Clear output result
    If IsObject(vItem) Then
        Set vItem = Nothing
    Else
        vItem = Empty
    End If

    If VarType(vIndex) = vbString Then
        'Test if item exists
        If VarType(oCollection.Item(CStr(vIndex))) = vbObject Then
            'Return an object
            Set vItem = oCollection.Item(CStr(vIndex))
        Else
            'Return an standard variable
            vItem = oCollection.Item(CStr(vIndex))
        End If
    Else
        'Test if item exists
        If VarType(oCollection.Item(Int(vIndex))) = vbObject Then
            'Return an object
            Set vItem = oCollection.Item(Int(vIndex))
        Else
            'Return an standard variable
            vItem = oCollection.Item(Int(vIndex))
        End If
    End If
    'Return success
    CollectionItemExists = True
    Exit Function
ErrNotExist:
    CollectionItemExists = False
    On Error GoTo 0
End Function

'Demonstration routine
Sub Test()
    Dim oColl As New Collection, oValue As Variant

    oColl.Add "red1", "KEYA"
    oColl.Add "red2", "KEYB"
    'Return the two items in the collection
    Debug.Print CollectionItemExists("KEYA", oColl, oValue)
    Debug.Print "Returned: " & oValue
    Debug.Print "-----------"
    Debug.Print CollectionItemExists(2, oColl, oValue)
    Debug.Print "Returned: " & oValue
    'Should fail
    Debug.Print CollectionItemExists("KEYC", oColl, oValue)
    Debug.Print "Returned: " & oValue
    Set oColl = Nothing
End Sub

См. больше на: https://web.archive.org/web/20140723190623/http://visualbasic.happycodings.com/other/code10.html#sthash.MlGE42VM.dpuf

Ответ 9

При поиске такой функции я разработал ее как следующую. Это должно работать с объектами и не-объектами без назначения новых переменных.

Public Function Exists(ByRef Col As Collection, ByVal Key) As Boolean
    On Error GoTo KeyError
    If Not Col(Key) Is Nothing Then
        Exists = True
    Else
        Exists = False
    End If

    Exit Function
KeyError:
    Err.Clear
    Exists = False
End Function