Как добавить точки останова Debug в строки, отображаемые в окне "Найти результаты" в Visual Studio

Ответ 1

Вы можете сделать это довольно легко с помощью макроса Visual Studio. В Visual Studio нажмите Alt-F11, чтобы открыть Macro IDE и добавить новый модуль, щелкнув правой кнопкой мыши на MyMacros и выбрав Add | Add Module...

Вставьте в редактор исходного кода следующее:

Imports System
Imports System.IO
Imports System.Text.RegularExpressions
Imports EnvDTE
Imports EnvDTE80
Imports EnvDTE90
Imports System.Diagnostics

Public Module CustomMacros
    Sub BreakpointFindResults()
        Dim findResultsWindow As Window = DTE.Windows.Item(Constants.vsWindowKindFindResults1)

        Dim selection As TextSelection
        selection = findResultsWindow.Selection
        selection.SelectAll()

        Dim findResultsReader As New StringReader(selection.Text)
        Dim findResult As String = findResultsReader.ReadLine()

        Dim findResultRegex As New Regex("(?<Path>.*?)\((?<LineNumber>\d+)\):")

        While Not findResult Is Nothing
            Dim findResultMatch As Match = findResultRegex.Match(findResult)

            If findResultMatch.Success Then
                Dim path As String = findResultMatch.Groups.Item("Path").Value
                Dim lineNumber As Integer = Integer.Parse(findResultMatch.Groups.Item("LineNumber").Value)

                Try
                    DTE.Debugger.Breakpoints.Add("", path, lineNumber)
                Catch ex As Exception
                    ' breakpoints can't be added everywhere
                End Try
            End If

            findResult = findResultsReader.ReadLine()
        End While
    End Sub
End Module

В этом примере используются результаты в окне "Найти результаты 1"; вам может понадобиться создать индивидуальный ярлык для каждого окна результатов.

Вы можете создать комбинацию клавиш, перейдя в Инструменты | Параметры... и выбрав Клавиатура в разделе Среда в навигации слева. Выберите свой макрос и назначьте любой ярлык, который вам нравится.

Вы также можете добавить свой макрос в меню или панель инструментов, перейдя в Инструменты | Настроить... и выбрав раздел Макросы в навигации слева. После того, как вы найдете свой макрос в списке, его можно перетащить в любое меню или на панели инструментов, где его текст или значок можно настроить по своему желанию.

Ответ 2

Если вы можете искать слово точно, вы можете использовать пару быстрых клавиш для быстрого выполнения.

Инструменты → Параметры → Окружающая среда → Клавиатура

• Edit.GoToFindResults1NextLocation
• EditorContextMenus.CodeWindow.Breakpoint.InsertBreakpoint

Назначьте их Control + Alt + F11 и F10, и вы можете очень быстро пройти все результаты. Однако я не нашел ярлыка для перехода к следующей ссылке.

Ответ 3

Мне нужно что-то подобное, чтобы отключить все точки останова и поместить точку останова на каждом "Catch ex as Exception". Тем не менее, я немного расширил его, чтобы он оставил точку останова при каждом появлении выбранной строки. Все, что вам нужно сделать, это выделить строку, в которой вы хотите включить точку останова, и запустить макрос.

 Sub BreakPointAtString()

    Try
        DTE.ExecuteCommand("Debug.DisableAllBreakpoints")
    Catch ex As Exception

    End Try

    Dim tsSelection As String = DTE.ActiveDocument.Selection.text
    DTE.ActiveDocument.Selection.selectall()
    Dim AllText As String = DTE.ActiveDocument.Selection.Text

    Dim findResultsReader As New StringReader(AllText)
    Dim findResult As String = findResultsReader.ReadLine()
    Dim lineNum As Integer = 1

    Do Until findResultsReader.Peek = -1
        lineNum += 1
        findResult = findResultsReader.ReadLine()
        If Trim(findResult) = Trim(tsSelection) Then
            DTE.ActiveDocument.Selection.GotoLine(lineNum)
            DTE.ExecuteCommand("Debug.ToggleBreakpoint")
        End If
    Loop

End Sub

Надеюсь, это сработает для вас:)

Ответ 4

Пол, спасибо большое, но у меня есть следующая ошибка (окно сообщения), может быть, мне нужно перезагрузить компьютер:

Error
---------------------------
Error HRESULT E_FAIL has been returned from a call to a COM component.
---------------------------
OK   
---------------------------

Я бы предложил следующее решение, очень простое, но оно работает для меня

Sub BreakPointsFromSearch()
    Dim n As Integer = InputBox("Enter the number of search results")

    For i = 1 To n
        DTE.ExecuteCommand("Edit.GoToNextLocation")
        DTE.ExecuteCommand("Debug.ToggleBreakpoint")            
    Next
End Sub