Подтвердить что ты не робот

Как функция с "varargs" извлекает содержимое стека?

Обычно в Delphi объявляется функция с переменным числом аргументов с использованием метода "array of const". Однако для совместимости с кодом, написанным на C, существует очень неизвестная директива "varargs", которая может быть добавлена ​​в объявление функции (я узнал об этом при чтении Rudy excellent " Ловушки конвертирования.)

В качестве примера можно было бы иметь функцию в C, объявленную следующим образом:

void printf(const char *fmt, ...)

В Delphi это станет следующим:

procedure printf(const fmt: PChar); varargs;

Мой вопрос: как я могу добраться до содержимого стека при реализации метода, который определяется директивой 'varargs'?

Я ожидал бы, что для этого существует какая-то оснастка, такая как Dephi-переводы функций va_start(), va_arg() и va_end(), но я ничего не могу найти.

Пожалуйста, помогите!

PS: Пожалуйста, не дрейфовать в дискуссиях о "почему" или альтернативе "array of const" - мне нужно это, чтобы писать C-подобные исправления для функций внутри игр Xbox (см. проект эмулятора Delphi Xbox "Dxbx 'on sourceforge для деталей).

4b9b3361

ОТВЕТЫ

Ответ 1

Хорошо, я вижу, что разъяснение в вашем вопросе означает, что вам нужно реализовать импорт C в Delphi. В этом случае вам необходимо реализовать varargs самостоятельно.

Основными знаниями, необходимыми, является соглашение C-вызова на x86: стек растет вниз, а C толкает аргументы справа налево. Таким образом, указатель на последний объявленный аргумент после того, как он будет увеличен на размер последнего объявленного аргумента, укажет на список аргументов хвоста. С тех пор это просто вопрос чтения аргумента и увеличения указателя на соответствующий размер, чтобы глубже проникнуть в стек. Стол x86 в 32-битном режиме обычно выравнивается по 4 байт, и это также означает, что байты и слова передаются как 32-битные целые числа.

Во всяком случае, здесь содержится вспомогательная запись в демонстрационной программе, которая показывает, как считывать данные. Обратите внимание, что Delphi, по-видимому, передает расширенные типы очень странным образом; однако вам, вероятно, не придется беспокоиться об этом, поскольку 10-байтовые поплавки обычно не широко используются в C и даже не реализованы в последней версии MS C, IIRC.

{$apptype console}

type  
  TArgPtr = record
  private
    FArgPtr: PByte;
    class function Align(Ptr: Pointer; Align: Integer): Pointer; static;
  public
    constructor Create(LastArg: Pointer; Size: Integer);
    // Read bytes, signed words etc. using Int32
    // Make an unsigned version if necessary.
    function ReadInt32: Integer;
    // Exact floating-point semantics depend on C compiler.
    // Delphi compiler passes Extended as 10-byte float; most C
    // compilers pass all floating-point values as 8-byte floats.
    function ReadDouble: Double;
    function ReadExtended: Extended;
    function ReadPChar: PChar;
    procedure ReadArg(var Arg; Size: Integer);
  end;

constructor TArgPtr.Create(LastArg: Pointer; Size: Integer);
begin
  FArgPtr := LastArg;
  // 32-bit x86 stack is generally 4-byte aligned
  FArgPtr := Align(FArgPtr + Size, 4);
end;

class function TArgPtr.Align(Ptr: Pointer; Align: Integer): Pointer;
begin
  Integer(Result) := (Integer(Ptr) + Align - 1) and not (Align - 1);
end;

function TArgPtr.ReadInt32: Integer;
begin
  ReadArg(Result, SizeOf(Integer));
end;

function TArgPtr.ReadDouble: Double;
begin
  ReadArg(Result, SizeOf(Double));
end;

function TArgPtr.ReadExtended: Extended;
begin
  ReadArg(Result, SizeOf(Extended));
end;

function TArgPtr.ReadPChar: PChar;
begin
  ReadArg(Result, SizeOf(PChar));
end;

procedure TArgPtr.ReadArg(var Arg; Size: Integer);
begin
  Move(FArgPtr^, Arg, Size);
  FArgPtr := Align(FArgPtr + Size, 4);
end;

procedure Dump(const types: string); cdecl;
var
  ap: TArgPtr;
  cp: PChar;
begin
  cp := PChar(types);
  ap := TArgPtr.Create(@types, SizeOf(string));
  while True do
  begin
    case cp^ of
      #0: 
      begin
        Writeln;
        Exit;
      end;

      'i': Write(ap.ReadInt32, ' ');
      'd': Write(ap.ReadDouble, ' ');
      'e': Write(ap.ReadExtended, ' ');
      's': Write(ap.ReadPChar, ' ');
    else
      Writeln('Unknown format');
      Exit;
    end;
    Inc(cp);
  end;
end;

type
  PDump = procedure(const types: string) cdecl varargs;
var
  MyDump: PDump;

function AsDouble(e: Extended): Double;
begin
  Result := e;
end;

function AsSingle(e: Extended): Single;
begin
  Result := e;
end;

procedure Go;
begin
  MyDump := @Dump;

  MyDump('iii', 10, 20, 30);
  MyDump('sss', 'foo', 'bar', 'baz');

  // Looks like Delphi passes Extended in byte-aligned
  // stack offset, very strange; thus this doesn't work.
  MyDump('e', 2.0);
  // These two are more reliable.
  MyDump('d', AsDouble(2));
  // Singles passed as 8-byte floats.
  MyDump('d', AsSingle(2));
end;

begin
  Go;
end.

Ответ 2

Я нашел этот (от парень, который мы знаем:))

Чтобы правильно писать этот материал, вам нужно использовать BASM, встроенный Delphi ассемблер и код последовательности вызовов в asm. Надеюсь, у вас есть хорошая идея того, что вам нужно делать. Возможно, сообщение в группе .basm поможет, если вы застряли.

Ответ 3

Delphi не позволяет вам выполнять процедуру varargs. Он работает только для импорта внешних функций cdecl, которые используют это.

Поскольку varargs основано на соглашении о вызове cdecl, вам в основном нужно переопределить его самостоятельно в Delphi, используя сборку и/или различные виды манипуляций с указателями.