Как я могу перечислить TDictionary в алфавитном порядке по ключам в Delphi 2009?

Как я могу использовать TEnumerator для прохождения моего TDictionary в отсортированном порядке по ключу?

У меня есть что-то вроде этого:

  var
    Dic: TDictionary<string, string>;
    Enum: TPair<string, string>;

  begin
    Dic := TDictionary<string, string>.create;
    Dic.Add('Tired', 'I have been working on this too long');
    Dic.Add('Early', 'It is too early in the morning to be working on this');
    Dic.Add('HelpMe', 'I need some help'); 
    Dic.Add('Dumb', 'Yes I know this example is dumb');

   { I want to do the following but do it in sorted order by Enum.Key }
    for Enum in Dic do
      some processing with Enum.Key and Enum.Value;

    Dic.Free;
  end;

Поэтому я хотел бы обработать мой словарь в порядке: Dumb, Early, HelpMe, Tired.

К сожалению, помощь Delphi очень минимальна в описании того, как конкретно перечисляются генераторы и TEnumerator, и не дает никаких примеров, которые я могу найти. В Интернете также мало написано об использовании Enumerators с Generics в Delphi.

И мой пример кода выше даже не использует TEnumerator, поэтому я смущен тем, как все это предназначено для использования.

Спасибо, Барри, за ваш ответ.

Мое предприятие в Generics, так как я задал вопрос, было интересно. Я хотел начать внедрять их в свой код. Проблема "сортировки" была несколько озадачивающей, поскольку, похоже, у Generics есть методы, связанные с сортировкой, но нет хороших примеров или документации о том, как это сделать.

В конце концов я сделал то, что предложил Барри, и построил внешний словарь в словаре. Тем не менее, это не кажется правильным.

Однако у меня был еще один сюрприз: я пытался заменить Gabr GPStringHash с общим TDictionary. Код был немного чище с дженериками. Но суть в том, что TDictionary был в 3 раза медленнее, чем у Gabr's. 1,704,667 звонков в TryGetValue заняли 0,45 секунды, но одна и та же операция с процедурами Gabr заняла 0,12 секунды. Я не уверен, почему, но, возможно, это так же просто, как у Габра, имеющего более быструю функцию Хэша и комбинацию балансировки. Или, может быть, дженерики должны были обобщить для каждого случая, и это по сути замедляет его.

Никогда, возможно, Барри или другие разработчики Delphi должны смотреть на это, потому что 3-кратное ускорение может в конечном итоге принести пользу всем. Я бы скорее использовал то, что было встроено в язык, чем пакет сторонних разработчиков (даже такой же, как и Gabr's), если был предоставлен выбор. Но пока я буду придерживаться GPStringHash.

Ответ 1

В моем случае я использую TDictionary < String, String > . TKeyCollection.

function compareKey(const L, R: String): Integer;
begin
  Result := SysUtils.CompareText(L, R);
end;

function getReverseSortedKeyArray(dictionary: TDictionary<String, String): TArray<String>;
var
  keyArray: TArray<String>;
  keyCollecttion: TDictionary<String, String>.TKeyCollection;
begin
  keyCollecttion:= TDictionary<String, String>.TKeyCollection.Create(dictionary);
  try
    keyArray:= valueCollecttion.ToArray;
    TArray.Sort<String>(keyArray, TComparer<String>.Construct(compareKey));
  finally
    keyCollecttion.Free;
  end;

  Result := keyArray;
end;

Пример использования:

var
  key: String;
  keyArray : TArray<String>;
begin
    keyArray  := getSortedKeyArray (dictionary);
    for key in keyArray  do
    begin
      // ...
    end;
end;

Ответ 2

Словарь - хеш-таблица, поэтому он не хранит элементы в отсортированном порядке. TEnumerator прост - это просто средство повторения элементов.

Чтобы получить элементы в заказе, вам необходимо их отсортировать. Один из способов - разместить их в списке и отсортировать список, например:

var
  list: TList<string>;
begin
  list := TList<string>.Create(Dic.Keys);
  try
    list.Sort;
    // process sorted list of items now
  finally
    list.Free;
  end;
end;

Ответ 3

Вот пример кода, который сортируется через Array<T> или TList<T>. Он сохраняет отношения ключевой стоимости, а также может быть изменен для сортировки по значению вместо ключа. Кроме того, для сортировки используется анонимный метод.

Обязательно включите Generics.Collections и Generics.Defaults в предложение uses. Первый способ сортировки с использованием TArray<T>:

procedure TestSortDictionaryViaArray;
var
  D: TDictionary<string, Integer>;
  A: TArray<TPair<string, Integer>>;
  P: TPair<string, Integer>;
begin
  D := TDictionary<string, Integer>.Create;

  D.Add('Test - 6', 6);
  D.Add('Test - 1', 1);
  D.Add('Test - 0', 0);
  D.Add('Test - 4', 4);
  D.Add('Test - 3', 3);
  D.Add('Test - 5', 0);
  D.Add('Test - 2', 2);

  A := D.ToArray;

  TArray.Sort<TPair<string, Integer>>(A,
    TComparer<TPair<string, Integer>>.Construct(
      function (const L, R: TPair<string, Integer>): Integer
      begin
        Result := CompareStr(L.Key, R.Key);
      end)
  );

  for P in A do
    ShowMessage(P.Key);
  D.Free;
end;

И это использует TList<T>:

procedure TestSortDictionaryViaList;
var
  D: TDictionary<string, Integer>;
  L: TList<TPair<string, Integer>>;
  P: TPair<string, Integer>;
begin
  D := TDictionary<string, Integer>.Create;

  D.Add('Test - 6', 6);
  D.Add('Test - 1', 1);
  D.Add('Test - 0', 0);
  D.Add('Test - 4', 4);
  D.Add('Test - 3', 3);
  D.Add('Test - 5', 0);
  D.Add('Test - 2', 2);

  L := TList<TPair<string, Integer>>.Create(D);

  L.Sort(
    TComparer<TPair<string, Integer>>.Construct(
      function (const L, R: TPair<string, Integer>): Integer
      begin
        Result := CompareStr(L.Key, R.Key);
      end)
  );

  for P in L do
    ShowMessage(P.Key);

  D.Free;
  L.Free;
end;

Дополнительная (и ненужная) информация: Метод TList<T> нуждается в том, чтобы список был освобожден, тогда как TArray<T> не нуждается в освобождении. Внутри TList<T> используется TArray<T> (например, TArray имеет метод класса BinarySearch(), а TList<T> - метод BinarySearch).