Вложенная партия для циклов

Следующие вложенные for-loop приводят меня в бешенство (в Windows 7):

@echo off
SetLocal EnableDelayedExpansion

set TESTDIRS=fast mid slow
set TD=src\test\resources\testsuite

for %%d in (%TESTDIRS%) do (
    set CTD=%TD%\%%d
    echo CTD: !CTD!
        REM Echos the expected path
    echo CTD: %CTD%
        REM Echos nothing -- understandable

    for /R !CTD! %%f in (*.fs) do (echo %%f)
        REM Echos nothing -- why?
    for /R src\test\resources\testsuite\fast %%f in (*.fs) do (echo %%f)
        REM Echos expected files
)

Я пробовал различные решения, связанные с отключением DelayedExpansion, call-statements и еще чего-то, но я никогда не получал работу внутреннего цикла. Я знаю, что я мог бы заменить внутренний цикл на вызов подпрограммы, но там должен быть способ заставить его работать с вложенными циклами.

Ответ 1

Что делать, если вы использовали pushd !CTD! и popd, и пусть FOR /R по умолчанию используется текущий каталог?

Ответ 2

Просто чтобы привести пример вложенного цикла, который работает:

@echo off
SetLocal

set B=alpha beta gamma
set A=eins zwo

FOR %%b in (%B%) do (
  FOR %%a in (%A% %%b) DO (
    echo %%b -^> %%a
  )
)

Выход (по крайней мере, на Windows 7)

alpha -> eins
alpha -> zwo
alpha -> alpha
beta -> eins
beta -> zwo
beta -> beta
gamma -> eins
gamma -> zwo
gamma -> gamma

Это поддерживает наблюдение jeb, что переменное расширение в циклах работает, если они встречаются внутри скобок (даже без задержки расширения).

Ответ 3

Поскольку никто не упомянул об этом, вот решение, использующее пакетные подпрограммы и команду CALL.

@echo off

set TESTDIRS=fast mid slow
set TD=src\test\resources\testsuite

for %%d in (%TESTDIRS%) do call :process_testdir %%d
goto :eof

:process_testdir
set CTD=%TD%\%1
echo CTD: %CTD%
    REM Echos the expected path

for /R %CTD% %%f in (*.fs) do (echo %%f)
    REM Echos as expected

goto :eof

Я знаю, что GOTO не очень популярен, но пакетные файлы изначально были предназначены для использования меток для потока управления. Синтаксис стробированной структуры управления был добавлен позже, и этот вопрос является примером того, где он разбивается. Проблема хорошо подходит для пакетных подпрограмм.

Ответ 4

Это не очевидно! Это специальный синтаксический анализ FOR!
Команда FOR анализируется непосредственно после этапа escape/special character (для обнаружения скобки), но в результате вы не можете использовать отложенное или %% var расширение в качестве параметров.

FOR %%a in (%%%%B) do (
  FOR %%a in (1) DO ( <<< this %%a will not replaced with %%B
      echo %%a - shows 1, because %%a is the name of the inner variable
      echo %%B - doesn't work
  )
)

А также это не может работать:

set chars=abc
FOR /F "delims=!chars!" %%N in (bla) DO ....

не устанавливает a, b и c как делимы, но !, c, h, a и r.

EDIT:. В круглых скобках замедленное расширение работает как ожидалось:

set var=C:\temp
For %%a in (!var!) DO echo %%a

Я бы ожидал, что вам придется использовать функцию для решения вашей проблемы.