Вектор обработки карт в Clojure

Я не нашел много документов или примеров кодирования для манипуляций с векторами карт. Например, если у меня есть

(def student-grades 
 [{:name "Billy" :test1 74 :test2 93 :test3 89} 
  {:name "Miguel" :test1 57 :test2 79 :test3 85}
  {:name "Sandy" :test1 86 :test2 97 :test3 99}
  {:name "Dhruv" :test1 84 :test2 89 :test3 94}])

и я хочу добавить или связать новую пару ключевых значений для тестовых сред, какие функции мне следует читать? Также, если кто-либо знает какие-либо ссылки/ресурсы для векторов карт в Clojure, пожалуйста, поделитесь! Большое спасибо!

Ответ 1

В этом случае вы хотите отобразить функцию над коллекцией (которая просто является вектором); для каждого элемента в коллекции (который, случается, представляет собой карту - неудачное столкновение имен), вы хотите создать новую карту, в которой есть все пары ключевого значения старой карты, плюс новый ключ, скажем: avg.

например.

(into [] ; optional -- places the answer into another vector
  (map   ; apply the given function to every element in the collection
    (fn [sg] ; the function takes a student-grade
      (assoc sg ; and with this student-grade, creates a new mapping
        :avg    ; with an added key called :avg
        (/ (+ (:test1 sg) (:test2 sg) (:test3 sg)) 3.0)))
    student-grades  ; and the function is applied to your student-grades vector
))

ps вы можете использовать (doc fn-name) для получения документации по нему; если вы новичок в Clojure, я бы посоветовал пообщаться с дружелюбными людьми на irc.freenode.net # clojure и прочитать книгу - мой любимый в настоящее время Программирование Clojure, но я жду предстоящую книгу O'Reilly Clojure с замиранием сердца.

Ответ 2

Hircus уже дал хороший ответ, но здесь другая реализация для сравнения:

(defn average [nums]
  (double (/ (apply + nums) (count nums))))

(map 
  #(assoc % :avg (average ((juxt :test1 :test2 :test3) %)))
  student-grades)

=> ({:avg 85.33333333333333, :name "Billy", :test1 74, :test2 93, :test3 89} etc....)

Комментарии к примечанию:

Обычно стоит выделить общие функции, такие как "средний", в отдельную, хорошо названную функцию
juxt - довольно полезная функция, чтобы извлечь конкретный список значений компонентов из карты