Переопределение GetHashCode в VB без проверки/непроверенной поддержки ключевых слов?

Ответ 1

Используйте Long, чтобы избежать переполнения:

Dim hash As Long = 17
'' etc..
Return CInt(hash And &H7fffffffL)

Оператор AND гарантирует, что исключение переполнения не будет выбрано. Это, однако, потеряет один бит "точности" в вычисленном хеш-коде, результат всегда положительный. VB.NET не имеет встроенной функции, чтобы избежать этого, но вы можете использовать трюк:

Imports System.Runtime.InteropServices

Module NoOverflows
    Public Function LongToInteger(ByVal value As Long) As Integer
        Dim cast As Caster
        cast.LongValue = value
        Return cast.IntValue
    End Function

    <StructLayout(LayoutKind.Explicit)> _
    Private Structure Caster
        <FieldOffset(0)> Public LongValue As Long
        <FieldOffset(0)> Public IntValue As Integer
    End Structure
End Module

Теперь вы можете написать:

Dim hash As Long = 17
'' etc..
Return NoOverflows.LongToInteger(hash)

Ответ 2

Вот реализация, сочетающая ответ Hans Passant и ответ Jon Skeet.

Он работает даже для миллионов свойств (т.е. исключений целых переполнений) и очень быстро (менее 20 мс для генерации хеш-кода для класса с 1 000 000 полей и едва измеримого для класса с только 100 полями).

Вот структура обработки переполнений:

<StructLayout(LayoutKind.Explicit)>
Private Structure HashCodeNoOverflow
    <FieldOffset(0)> Public Int64 As Int64
    <FieldOffset(0)> Public Int32 As Int32
End Structure

И простая функция GetHashCode:

Public Overrides Function GetHashCode() As Integer

    Dim hashCode As HashCodeNoOverflow

    hashCode.Int64 = 17

    hashCode.Int64 = CLng(hashCode.Int32) * 23 + Field1.GetHashCode
    hashCode.Int64 = CLng(hashCode.Int32) * 23 + Field2.GetHashCode
    hashCode.Int64 = CLng(hashCode.Int32) * 23 + Field3.GetHashCode

    Return hashCode.Int32

End Function

Или, если вы предпочитаете:

Public Overrides Function GetHashCode() As Integer

    Dim hashCode = New HashCodeNoOverflow With {.Int32 = 17}

    For Each field In Fields
        hashCode.Int64 = CLng(hashCode.Int32) * 23 + field.GetHashCode
    Next

    Return hashCode.Int32

End Function

Ответ 3

У меня была такая же проблема с внедрением решения г-на Скита в vb.net. Я закончил тем, что использовал оператора Mod, чтобы туда добраться. Каждый Mod от Integer.MaxValue должен возвращать только наименее значимый компонент до этой точки и всегда будет находиться внутри Integer.MaxValue и Integer.MinValue - который должен иметь тот же эффект, что и unchecked. Вы, вероятно, не должны так часто меняться (это только когда есть шанс получить больше, чем длинный (что означало бы объединение LOT хэш-кодов), а затем один раз в конце), но вариант этого работает для меня (и позволяет играть с использованием гораздо больших простых чисел, таких как некоторые другие хэш-функции, не беспокоясь).

Public Overrides Function GetHashCode() As Int32
    Dim hash as Int64 = 17
    hash = (hash * 23 + _Name.GetHashCode()) Mod Integer.MaxValue
    hash = (hash * 23 + _Value) Mod Integer.MaxValue
    hash = (hash * 23 + _Type.GetHashCode()) Mod Integer.MaxValue
    Return Convert.ToInt32(hash)
End Function

Ответ 4

Вы можете реализовать подходящий хеш-хэш в отдельной сборке либо с использованием С#, и с ключевым словом unchecked, либо путем проверки переполнения для всего проекта (возможно как в проектах VB.NET, так и в С#). Если вы хотите, вы можете использовать ilmerge для объединения этой сборки в свою основную сборку.

Ответ 5

Улучшенный ответ Переопределение GetHashCode в VB без проверки ключевого слова без проверки/непроверки?

Public Overrides Function GetHashCode() as Integer
  Dim hashCode as Long = 0
  If myReplacePattern IsNot Nothing Then _
    hashCode = ((hashCode*397) Xor myField.GetHashCode()) And &HffffffffL
  If myPattern IsNot Nothing Then _
    hashCode = ((hashCode*397) Xor myOtherField.GetHashCode()) And &HffffffffL
  Return CInt(hashCode)
End Function

После каждого умножения происходит обрезка. И букваль явно определяется как Long, потому что оператор And с аргументом Integer не обнуляет верхние байты.

Ответ 6

После исследования того, что VB не дал нам ничего подобного unchecked и бушует для бит (С# dev теперь делает vb), я внедрил решение, близкое к тому, которое отправил Hans Passant. Я потерпел неудачу. Ужасная работа. Это, безусловно, было связано с моей реализацией, а не с решением, которое Ханс написал. Я мог бы вернуться и более точно скопировать его решение.

Однако я решил проблему с другим решением. Сообщение, жалующееся на отсутствие unchecked на странице запросов функций языка VB, дало мне идею использовать хэш-алгоритм уже в рамках. В моей проблеме у меня были String и Guid, которые я хотел использовать для словарного ключа. Я решил, что Tupple(Of Guid, String) будет хорошим внутренним хранилищем данных.

Оригинальная плохая версия

Public Structure HypnoKey
  Public Sub New(name As String, areaId As Guid)
    _resourceKey = New Tuple(Of Guid, String)(resourceAreaId, key)
  End Sub

  Private ReadOnly _name As String
  Private ReadOnly _areaId As Guid

  Public ReadOnly Property Name As String
    Get
      Return _name 
    End Get
  End Property

  Public ReadOnly Property AreaId As Guid
    Get
      Return _areaId 
    End Get
  End Property

  Public Overrides Function GetHashCode() As Integer
    'OMFG SO BAD
    'TODO Fail less hard
  End Function

End Structure

Улучшенная версия

Public Structure HypnoKey
  Public Sub New(name As String, areaId As Guid)
    _innerKey = New Tuple(Of Guid, String)(areaId , key)
  End Sub

  Private ReadOnly _innerKey As Tuple(Of Guid, String)

  Public ReadOnly Property Name As String
    Get
      Return _innerKey.Item2
    End Get
  End Property

  Public ReadOnly Property AreaId As Guid
    Get
      Return _innerKey.Item1
    End Get
  End Property

  Public Overrides Function GetHashCode() As Integer
    Return _innerKey.GetHashCode() 'wow! such fast (enuf)
  End Function

End Structure

Итак, хотя я ожидаю, что есть гораздо лучшие решения, чем это, я очень доволен. Моя работа хорошая. Кроме того, неприятный код полезности исчез. Надеюсь, это полезно для некоторых других бедных разработчиков, вынужденных писать VB, который сталкивается с этим сообщением.

Приветствия

Ответ 7

Я также обнаружил, что свойство RemoveIntegerChecks MsBuild влияет на /removeintchecks Компилятор VB свойство, которое мешает компилятору испускать проверки выполнения:

  <PropertyGroup>
    <RemoveIntegerChecks>true</RemoveIntegerChecks>   
  </PropertyGroup>