Получение ошибки Код ошибки транспорта был 0x80040217 при отправке электронной почты в Asp.Net

Ответ 1

Обнаружено, что вы также можете получить эту ошибку, если параметры безопасности Gmail не позволяют отправлять сообщения с адреса, который вы собираетесь использовать. Мне нужно было разрешить доступ для менее безопасных приложений для моей учетной записи:

• Вход в адрес, который вы хотите использовать для отправки электронной почты из Excel.
• Посетите страницу https://www.google.com/settings/security/lesssecureapps
• Нажмите "Включить менее безопасные приложения".
• Нажмите "Готово".

Ответ 2

Это вызвано неправильным именем пользователя или паролем для SMTP-сервера и обычно означает, что сервер отключил вашу учетную запись для рассылки спама i вы отправили 1500 писем

Ответ 3

Спасибо за ваши ответы, это сработало! это потому, что у меня не было этой опции: https://www.google.com/settings/security/lesssecureapps Если кому-то это понадобится, это код VBScript, который я использую в Qlikview:

SUB SendMail
    Dim objEmail

    Const cdoSendUsingPort = 2  ' Send the message using SMTP
    Const cdoBasicAuth = 1      ' Clear-text authentication
    Const cdoTimeout = 60       ' Timeout for SMTP in seconds

     mailServer = "smtp.gmail.com"
     SMTPport = 465     '25 'SMTPport = 465
     mailusername = "marcos.esgu**@gmail.com"
     mailpassword = "Ki***"

     mailto = "marcos.esgu**@*****" 
     mailSubject = "my test-deleteme" 
     mailBody = "This is the email body" 

    Set objEmail = CreateObject("CDO.Message")
    Set objConf = objEmail.Configuration
    Set objFlds = objConf.Fields

    With objFlds
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = mailServer
    .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = SMTPport
    .Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = cdoTimeout
    .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasicAuth
    .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = mailusername
    .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = mailpassword
        .Update
    End With

    objEmail.To = mailto
    objEmail.From = mailusername
    objEmail.Subject = mailSubject
    objEmail.TextBody = mailBody
    'objEmail.AddAttachment "C:\report.pdf"
    objEmail.Send

    Set objFlds = Nothing
    Set objConf = Nothing
    Set objEmail = Nothing
END SUB