Согласование шаблонов в начале строки в f #

Я пытаюсь сопоставить начало строк в f #. Не уверен, что я должен рассматривать их как список персонажей или что. Любые предложения будут оценены.

Вот версия кода psuedo того, что я пытаюсь сделать

let text = "The brown fox.."

match text with
| "The"::_ -> true
| "If"::_ -> true
| _ -> false

Итак, я хочу посмотреть начало строки и совпадение. Заметьте, что я не согласен в списке строк, просто написал выше, как идею о сути того, что я пытаюсь сделать.

Ответ 1

Параметрированный активные шаблоны на помощь!

let (|Prefix|_|) (p:string) (s:string) =
    if s.StartsWith(p) then
        Some(s.Substring(p.Length))
    else
        None

match "Hello world" with
| Prefix "The" rest -> printfn "Started with 'The', rest is %s" rest
| Prefix "Hello" rest -> printfn "Started with 'Hello', rest is %s" rest
| _ -> printfn "neither"

Ответ 2

Да, вам нужно рассматривать их как список символов, если вы хотите использовать выражение соответствия.

Просто преобразуйте строку с помощью:

let text = "The brown fox.." |> Seq.toList

Затем вы можете использовать выражение соответствия, но вам нужно будет использовать символы (тип элементов в списке) для каждой буквы:

match text with
| 'T'::'h'::'e'::_ -> true
| 'I'::'f'::_ -> true
| _ -> false

По мере того как Брайан предлагает параметризованные активные шаблоны намного приятнее, здесь есть несколько полезных шаблонов здесь (зайдите в конец страницы).

Ответ 3

Вы также можете использовать охрану в шаблоне:

match text with
| txt when txt.StartsWith("The") -> true
| txt when txt.StartsWith("If") -> true
| _ -> false