Как перечислить членов Enum

Как перечислить членов Enum в коде? У меня есть следующий Enum:

Public Enum TestEnum As int32
    First = 0
    Second = 2
    Third = 4
    Fourth = 6
End Enum

И я пытаюсь перечислить всех членов TestEnum с помощью следующего кода, но это не удалось:

Public Class Form1

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Dim Enum1 As TestEnum

        Dim Members() As String

        Members = System.Enum.GetNames(CType(Enum1, System.Enum))


    End Sub
End Class

Итак, мой вопрос: как составить список членов Enum?

Обновление: решение:

Public Class Form1

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Dim Members() As String
        Members = System.Enum.GetNames(GetType(TestEnum))

        MessageBox.Show(Join(Members, Chr(13) & Chr(10)))

    End Sub
End Class

Ответ 1

Вы можете просто перебирать все значения следующим образом:

Public Enum TestEnum As int32
    First = 0
    Second = 2
    Third = 4
    Fourth = 6
End Enum

For Each tstEnum As TestEnum In System.Enum.GetValues(GetType(TestEnum))

    Response.Write(
        String.Format("Name: {0}  Value: {1}", 
            tstEnum.ToString, 
            CInt(tstEnum).ToString
        )
    )

Next

Ответ 2

Вам нужно передать тип, а не значение, в метод.

Members = System.Enum.GetNames(GetType(TestEnum))

Если у вас есть экземпляр вашего перечисления, вы также можете использовать

Members = System.Enum.GetNames(Enum1.GetType())

Хотя я бы рекомендовал первый подход, если вы знаете нужный тип.

Ответ 3

Вы посмотрели Enum.GetValues?

Изменить: Чтобы уточнить, да, вам нужно передать тип, а не экземпляр перечисления для любого метода.

Enum.GetNames(GetType(TestEnum))

Ответ 4

Я использовал ответ джорджа Филиппакоса, поскольку хотел знать, как перебирать значения Enum.

Я также узнал, что вы можете сделать это, используя Type.GetEnumValues , который был доступен с .NET Framework 4.0.

Вот два способа, которыми вы можете использовать для итерации значений Enum:

Module Module1
    Sub Main()
        For Each tstEnum As TestEnum In System.Enum.GetValues(GetType(TestEnum))
            Console.WriteLine($"Name: {tstEnum.ToString}, Value: {CType(tstEnum, Integer)}")
        Next

        Console.WriteLine(Environment.NewLine)

        For Each tstEnum As TestEnum In GetType(TestEnum).GetEnumValues
            Console.WriteLine($"Name: {tstEnum.ToString}, Value: {CType(tstEnum, Integer)}")
        Next

        Console.ReadKey()
    End Sub

    Public Enum TestEnum
        First = 1
        Second = 2
        Third = 3
    End Enum
End Module

Выход:

Name: First, Value: 1
Name: Second, Value: 2
Name: Third, Value: 3

Name: First, Value: 1
Name: Second, Value: 2
Name: Third, Value: 3