Подтвердить что ты не робот

Удаление элементов и/или атрибутов по имени для параметров XSL

Далее выполняется удаление ненужных элементов и атрибутов по имени ( "removeMe" в этом примере) из файла XML:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node() | @*" name="identity">
  <xsl:copy>
   <xsl:apply-templates select="node() | @*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="removeMe"/>
</xsl:stylesheet>

Проблемы в том, что он не различает элементы и атрибуты, имя жестко закодировано и может принимать только одно имя. Как это можно переписать, чтобы использовать пару входных параметров, как показано ниже, для удаления одного или нескольких конкретных элементов и/или атрибутов?

<xsl:param name="removeElementsNamed"/>
<xsl:param name="removeAttributesNamed"/>

Желаемый результат - это способность удалять один или несколько элементов и/или один или несколько атрибутов , сохраняя при этом различия между элементами и атрибутами (другими словами, должно быть возможно удалить все "временные" элементы без, также удалив все атрибуты "время" ).

Пока мне нужен XSLT 1.0 в этом раунде, решения XSLT 2.0 в принятых и других ответах могут быть полезны для других.

4b9b3361

ОТВЕТЫ

Ответ 1

Это преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="removeElementsNamed" select="'x'"/>

 <xsl:template match="node()|@*" name="identity">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="*">
  <xsl:if test="not(name() = $removeElementsNamed)">
   <xsl:call-template name="identity"/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

при применении к любому XML-документу, скажем,:

<t>
    <a>
        <b/>
        <x/>
    </a>
    <c/>
    <x/>
    <d/>
</t>

создает желаемый правильный результат - копию исходного XML-документа, в котором любое событие элемента, имеющего имя, которое является значением параметра $removeElementsNamed, удаляется:

<t>
   <a>
      <b/>
   </a>
   <c/>
   <d/>
</t>

Обратите внимание: В XSLT 1.0 синтаксически запрещено иметь переменную или ссылку на параметр внутри шаблона соответствия шаблону. Вот почему решения @Jan Thomä и @treeMonkey вызывают ошибку с любым процессором, совместимым с XSLT 1.0.

Обновление. Это более сложное решение, которое позволяет удалить список имен элементов, разделенных по трубам, для передачи в преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="removeElementsNamed" select="'|x|c|'"/>

 <xsl:template match="node()|@*" name="identity">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="*">
  <xsl:if test=
   "not(contains($removeElementsNamed,
                 concat('|',name(),'|' )
                 )
        )
   ">
   <xsl:call-template name="identity"/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

При применении к тому же XML-документу (выше), преобразование снова выводит желаемый корректный вывод - исходный XML-документ со всеми элементами, имя которых указано в параметре $removeElementsNamed - удалено:

<t>
   <a>
      <b/>
   </a>
   <d/>
</t>

Update2: та же трансформация, что и в Update1, но написанная в XSLT 2.0:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="removeElementsNamed" select="'|x|c|'"/>

 <xsl:template match="node()|@*" name="identity">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match=
 "*[name() = tokenize($removeElementsNamed, '\|')]"/>
</xsl:stylesheet>

Обновить: OP добавил требование также иметь возможность удалять все атрибуты с определенным именем.

Вот слегка модифицированное преобразование для размещения этого нового требования:

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:param name="removeElementsNamed" select="'x'"/>
     <xsl:param name="removeAttributesNamed" select="'n'"/>

     <xsl:template match="node()|@*" name="identity">
      <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
     </xsl:template>

     <xsl:template match="*">
      <xsl:if test="not(name() = $removeElementsNamed)">
       <xsl:call-template name="identity"/>
      </xsl:if>
     </xsl:template>

     <xsl:template match="@*">
      <xsl:if test="not(name() = $removeAttributesNamed)">
       <xsl:call-template name="identity"/>
      </xsl:if>
     </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к XML-документу ниже (тот, который использовался ранее, но с несколькими добавленными атрибутами):

<t>
    <a>
        <b m="1" n="2"/>
        <x/>
    </a>
    <c/>
    <x/>
    <d n="3"/>
</t>

вызывается желаемый, правильный результат (все элементы с именем x и все атрибуты с именем n):

<t>
   <a>
      <b m="1"/>
   </a>
   <c/>
   <d/>
</t>

UPDATE2. Как опять-таки запрошено OP, мы теперь реализуем возможность передавать список имен, разделенных колонками, для удаления элементов с этими именами и, соответственно, список имен, разделенных каналами, для удаление атрибутов с этими именами:

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:param name="removeElementsNamed" select="'|c|x|'"/>
     <xsl:param name="removeAttributesNamed" select="'|n|p|'"/>

     <xsl:template match="node()|@*" name="identity">
      <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
     </xsl:template>

     <xsl:template match="*">
      <xsl:if test=
      "not(contains($removeElementsNamed,
                    concat('|', name(), '|')
                    )
           )
      ">
       <xsl:call-template name="identity"/>
      </xsl:if>
     </xsl:template>

     <xsl:template match="@*">
      <xsl:if test=
      "not(contains($removeAttributesNamed,
                    concat('|', name(), '|')
                    )
           )
       ">
       <xsl:call-template name="identity"/>
      </xsl:if>
     </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к следующему XML-документу:

<t>
    <a p="0">
        <b m="1" n="2"/>
        <x/>
    </a>
    <c/>
    <x/>
    <d n="3"/>
</t>

вызывается желаемый, правильный результат (элементы с именами c и x и атрибуты с именами n и p):

<t>
   <a>
      <b m="1"/>
   </a>
   <d/>
</t>

Ответ 2

Здесь опция XSLT 2.0, если вы можете использовать 2.0. Имена элементов могут передаваться как разделенные запятой, вкладкой, трубой или пространством.

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">  
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:param name="removeElementsNamed" select="'bar,baz'"/>  

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*[name()=tokenize($removeElementsNamed,'[\|, \t]')]"/>  

</xsl:stylesheet>

Ответ 3

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

   <xsl:output omit-xml-declaration="yes" indent="yes"/>
   <xsl:param name="removeMe"/>

   <xsl:template match="node() | @*">
      <xsl:if test="not(name(.)=$removeMe)">
        <xsl:copy>
           <xsl:apply-templates select="node() | @*"/>
        </xsl:copy>
      </xsl:if>
   </xsl:template>   


</xsl:stylesheet>

Ответ 4

Это хаки, но может дать вам общую идею:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:param name="removeElementsNamed"/>

<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[contains($removeElementsNamed, concat(',',name(),','))]"/>

Вам нужно указать имена элементов для удаления в виде списка, разделенного запятыми, начиная с запятой и заканчивая запятой, например. значение ", foo, bar, baz" удалит все элементы с именем foo bar или baz. Если у вас нет элементов, которые являются частичными именами других элементов, вы можете упростить это:

<xsl:template match="*[contains($removeElementsNamed,name())]"/>

Однако, если у вас есть XML, например

<foo>
  <bar>..<bar>
  <barbara>..</barbara>
<foo>

и использовать параметр "bar" в качестве параметра, это приведет к удалению как бара, так и штрих-кода, поэтому первый подход более безопасен.