Подтвердить что ты не робот

Запись в файл в Perl

Рассмотрим:

#!/usr/local/bin/perl
$files = "C:\\Users\\A\\workspace\\CCoverage\\backup.txt";
unlink ($files);
open (OUTFILE, '>>$files');
print OUTFILE "Something\n";
close (OUTFILE);

Выше была простая подпрограмма, которую я написал в Perl, но она не работает. Как я могу заставить его работать?

Ответ 1

Переменные интерполируются только в строках, используя двойные кавычки ". Если вы используете одинарные кавычки ', $ будет интерпретироваться как доллар.

Попробуйте ">>$files" вместо '>>$files'

Всегда используйте

use strict;
use warnings;

Это поможет получить еще несколько предупреждений.

В любом случае также объявлять переменные

my $files = "...";

Вы также должны проверить возвращаемое значение open:

open OUTFILE, ">>$files"
  or die "Error opening $files: $!";

Изменить. Как указано в комментариях, версия с тремя открытыми аргументами и несколько других возможных улучшений

#!/usr/bin/perl

use strict;
use warnings;

# warn user (from perspective of caller)
use Carp;

# use nice English (or awk) names for ugly punctuation variables
use English qw(-no_match_vars);

# declare variables
my $files = 'example.txt';

# check if the file exists
if (-f $files) {
    unlink $files
        or croak "Cannot delete $files: $!";
}

# use a variable for the file handle
my $OUTFILE;

# use the three arguments version of open
# and check for errors
open $OUTFILE, '>>', $files
    or croak "Cannot open $files: $OS_ERROR";

# you can check for errors (e.g., if after opening the disk gets full)
print { $OUTFILE } "Something\n"
    or croak "Cannot write to $files: $OS_ERROR";

# check for errors
close $OUTFILE
    or croak "Cannot close $files: $OS_ERROR";