Создание карты JSON для саморегуляции Ecto-модели

У меня есть модель Ecto как таковая:

defmodule Project.Category do
  use Project.Web, :model

  schema "categories" do
    field :name, :string
    field :list_order, :integer
    field :parent_id, :integer
    belongs_to :menu, Project.Menu
    has_many :subcategories, Project.Category, foreign_key: :parent_id
    timestamps
  end

  @required_fields ~w(name list_order)
  @optional_fields ~w(menu_id parent_id)

  def changeset(model, params \\ :empty) do
    model
    |> cast(params, @required_fields, @optional_fields)
  end
end

Как вы можете видеть, модель категории может ссылаться на себя через атом подкатегорий.

Вот представление, связанное с этой моделью:

defmodule Project.CategoryView do
  use Project.Web, :view

  def render("show.json", %{category: category}) do
    json = %{
      id: category.id,
      name: category.name,
      list_order: category.list_order
      parent_id: category.parent_id
    }
    if is_list(category.subcategories) do
      children = render_many(category.subcategories, Project.CategoryView, "show.json")
      Map.put(json, :subcategories, children)
    else
      json
    end
  end
end

У меня есть условие if в подкатегориях, чтобы я мог хорошо играть с Poison, когда они не были предварительно загружены.

Наконец, вот мои 2 функции контроллера, которые вызывают это представление:

defmodule Project.CategoryController do
  use Project.Web, :controller

  alias Project.Category

  def show(conn, %{"id" => id}) do
    category = Repo.get!(Category, id)
    render conn, "show.json", category: category
  end

  def showWithChildren(conn, %{"id" => id}) do
    category = Repo.get!(Category, id)
               |> Repo.preload [:subcategories, subcategories: :subcategories]
    render conn, "show.json", category: category
  end
end

Функция show работает нормально:

{
  "parent_id": null,
  "name": "a",
  "list_order": 4,
  "id": 7
}

Однако моя функция showWithChildren ограничена двумя уровнями вложенности из-за того, как я использую предварительную загрузку:

{
  "subcategories": [
    {
      "subcategories": [
        {
          "parent_id": 10,
          "name": "d",
          "list_order": 4,
          "id": 11
        }
      ],
      "parent_id": 7,
      "name": "c",
      "list_order": 4,
      "id": 10
    },
    {
      "subcategories": [],
      "parent_id": 7,
      "name": "b",
      "list_order": 9,
      "id": 13
    }
  ],
  "parent_id": null,
  "name": "a",
  "list_order": 4,
  "id": 7
}

Например, элемент 11 категории выше также имеет подкатегории, но я не могу их достичь. Эти подкатегории могут также иметь подкатегории, поэтому потенциальная глубина иерархии равна n.

Я знаю, что мне нужна рекурсивная магия, но, поскольку я новичок в функциональном программировании и Elixir, я не могу обернуть вокруг себя. Любая помощь приветствуется.

Ответ 1

Вы можете рассмотреть возможность предварительной загрузки в представлении, поэтому он работает рекурсивно:

def render("show.json", %{category: category}) do
  %{id: category.id,
    name: category.name,
    list_order: category.list_order
    parent_id: category.parent_id}
  |> add_subcategories(category)
end

defp add_subcategories(json, %{subcategories: subcategories}) when is_list(subcategories) do
  children =
    subcategories
    |> Repo.preload(:subcategories)
    |> render_many(Project.CategoryView, "show.json")
  Map.put(json, :subcategories, children)
end

defp add_subcategories(json, _category) do
  json
end

Имейте в виду, что это не идеально по двум причинам:

В идеале вы не хотите делать запросы в представлениях (но это рекурсивно, так что проще рисовать в рендеринге)
Вы собираетесь испустить несколько запросов для второго уровня подкатегорий

Существует книга под названием SQL Antipatterns, и, если я не ошибаюсь, она описывает, как писать древовидные структуры. Ваш пример раскрывается как антипаттерн в одной из бесплатных глав. Это отличная книга, и они исследуют решения для всех антипаттернов.

PS: вы хотите show_with_children, а не showWithChildren.