Как читать файлы свойств и использовать значения в проекте Gradle script?

Ответ 1

Если вы используете файл gradle.properties по умолчанию, вы можете получить доступ к свойствам непосредственно из вашего файла build.gradle:

gradle.properties:

applicationName=Admin
projectName=Hello Cool

build.gradle:

task printProps {
    doFirst {
        println applicationName
        println projectName
    }
}

Если вам нужен доступ к пользовательскому файлу или доступ к свойствам, которые включают . в них (как вам кажется, нужно сделать) вы можете сделать следующее в вашем файле build.gradle:

def props = new Properties()
file("build.properties").withInputStream { props.load(it) }

task printProps {
    doFirst {
        println props.getProperty("application.name")
        println props.getProperty("project.name")
    }
}

Взгляните на этот раздел документации Gradle для получения дополнительной информации.

редактировать

Если вы хотите динамически настроить некоторые из этих свойств (как указано в комментарии ниже), вы можете создать файл properties.gradle (имя не имеет значения) и build.gradle его в своем build.gradle.

properties.gradle:

ext {
    subPath = "some/sub/directory"
    fullPath = "$projectDir/$subPath"
}

build.gradle

apply from: 'properties.gradle'

// prints the full expanded path
println fullPath

Ответ 2

Мы можем использовать отдельный файл (в моем случае config.groovy), чтобы абстрагировать всю конфигурацию.

В этом примере мы используем три среды, а именно

1. dev
2. тест
3. прод

который имеет свойства serverName, serverPort и ресурсы. Здесь мы ожидаем, что ресурсы третьего свойства могут быть одинаковыми в нескольких средах, поэтому мы абстрагировали эту логику и переопределили ее в конкретной среде, где это необходимо:

config.groovy

resources {
    serverName = 'localhost'
    serverPort = '8090'
}

environments {
    dev {
        serverName = 'http://localhost'   
        serverPort = '8080'
    }

    test {
        serverName = 'http://www.testserver.com'
        serverPort = '5211'
        resources {
            serverName = 'resources.testserver.com'
        }
    }

    prod {
        serverName = 'http://www.productionserver.com'
        serverPort = '80'
        resources {
            serverName = 'resources.productionserver.com'
            serverPort = '80'
        }
    }
}

Как только файл свойств будет готов, мы можем использовать следующее в build.gradle для загрузки этих настроек:

build.gradle

loadProperties()

def loadProperties() {
    def environment = hasProperty('env') ? env : 'dev'
    println "Current Environment: " + environment

    def configFile = file('config.groovy')
    def config = new ConfigSlurper(environment).parse(configFile.toURL())
    project.ext.config = config
}

task printProperties {
    println "serverName:  $config.serverName"
    println "serverPort:  $config.serverPort"
    println "resources.serverName:  $config.resources.serverName"
    println "resources.serverPort:  $config.resources.serverPort"
}

Давайте запустим их с другим набором входных данных:

1. gradle -q printProperties

   Current Environment: dev
   serverName:  http://localhost
   serverPort:  8080
   resources.serverName:  localhost
   resources.serverPort:  8090
   

2. gradle -q -Penv=dev printProperties

   Current Environment: dev
   serverName:  http://localhost
   serverPort:  8080
   resources.serverName:  localhost
   resources.serverPort:  8090
   

3. gradle -q -Penv=test printProperties

   Current Environment: test
   serverName:  http://www.testserver.com
   serverPort:  5211
   resources.serverName:  resources.testserver.com
   resources.serverPort:  8090
   

4. gradle -q -Penv=prod printProperties

   Current Environment: prod
   serverName:  http://www.productionserver.com
   serverPort:  80
   resources.serverName:  resources.productionserver.com
   resources.serverPort:  80
   

Ответ 3

Другой способ... в build.gradle:

Добавлять:

classpath 'org.flywaydb:flyway-gradle-plugin:3.1'

И это:

def props = new Properties()
file("src/main/resources/application.properties").withInputStream { props.load(it) }
apply plugin: 'flyway'
flyway {
    url = props.getProperty("spring.datasource.url")
    user = props.getProperty("spring.datasource.username")
    password = props.getProperty("spring.datasource.password")
    schemas = ['db_example']
}